-
Notifications
You must be signed in to change notification settings - Fork 2
/
devload.asm
2556 lines (1834 loc) · 77.2 KB
/
devload.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
; .....................PROGRAM HEADER FOR PROJECT BUILDER....................
; TITLE DEVLOAD to load device drivers from command line.
; FORMAT COM
; VERSION 3.25
; CODE 80x86
; BUILD NASM -o devload.com in 3.21/newer ***
; AUTHOR David Woodhouse
; (C) 1992, 1993 David Woodhouse.
; Patches for 3.12 to 3.16, 3.17 - 3.19: 2004 to 2005, 2007 by Eric Auer
; Patch for 3.20: 2007 by Alexey and Eric Auer
; Patch for 3.21: 2008 by Eric Auer
; Devload - a tool to load DOS device drivers from the command line
; Copyright (c) 1992-2011 David Woodhouse and Eric Auer
;
; This program is free software; you can redistribute it and/or modify
; it under the terms of the GNU General Public License as published by
; the Free Software Foundation; either version 2 of the License, or
; (at your option) any later version.
;
; This program is distributed in the hope that it will be useful,
; but WITHOUT ANY WARRANTY; without even the implied warranty of
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
; GNU General Public License for more details.
;
; You should have received a copy of the GNU General Public License along
; with this program; if not, write to the Free Software Foundation, Inc.,
; 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
; EXPLANATION...
; The program first relocates itself to the top of the available memory
; and then loads the driver below itself. If the driver loads happily, it
; is then executed. If it asks for memory to be reserved for it, it is
; linked into the device chains and the program TSRs keeping the required
; amount of memory, otherwise a normal exit occurs.
; ............................ALTERATION LIST................................
; Version 1.0 12/3/92
; Basics, not user-friendly, only supports character devices so far.
; 13/2/92
; Change to using EXEC (4Bh) function to load - now loads .EXE files
; Take length to TSR from device return, not file length.
; Don't TSR if not required.
; Version 1.1 17/3/92
; Complete rewrite of initialisation routine.
; Allows for more than one device per file.
; Help message added.
; EXEC failure now explains error codes, rather than just giving no.
; 19/3/92
; Print error message and exit if version < 4.
; Loads device at PSP+6, not PSP+10h (overlay FCBs and command tail).
; Stack moved down by 8 paras, not truncated to 80h bytes.
; 20/3/92
; Release environment block before TSR.
; Version 2.0 21/3/92
; Use INT 21h, function 53h. Can now load block devices.
; Use segment in break address, don't assume same as driver segment.
; Ask whether to terminate if can't install any blocks.
; Disable ctrl-break.
; 22/3/92
; Check sector size before installing block devices.
; Disable break with INT 1Bh, as well as INT 23h - stops ^C appearing.
; (taken out in v2.1) - causes problems if driver changes it.
; Don't use INT 10h - all output via INT 21h - can be redirected.
; Print drive letter with block header address.
; Print LastDrive message after installing block headers, not before.
; Change program name in arena header to device filename (for MEM.EXE).
; Support for DOS 3 added (now works with at least DOS 3.1 onwards).
; Print driver's load address.
; Version 2.1 24/3/92
; Bug fix - drivers requesting memory offset FFF1 - FFFF now works OK.
; 25/3/92
; Now uses func 60h to expand filename before printing it.
; Bug fix - changing INT 1B lost vector if driver altered it, so don't.
; Display INT vectors changed by driver.
; 26/3/92
; Converts params to upper case before passing to driver, like DOS does.
; Also adds space after filename if no parameters given.
; Change data at end to ?? rather than 00 - smaller .COM file.
; Version 2.2 26/10/92
; When no blocks installed, checks whether INT vectors changed before
; asking whether to terminate. Still not foolproof, but better.
; Cosmetic fix - `$' now comes after CR/LF on `None.' for INT vectors.
; Bug fix - Check all INT vectors (200h words, not 200 words!)
; Version 3.0 11/4/93 - 20/4/93
; Complete rewrite from scratch.
; Only relocate if going to try EXEC - saves losing F3.
; Use path to find driver if not in specified directory.
; Convert to .EXE program.
; Relocate PSP to top of memory as well as code and stack.
; Release environment before requesting memory for driver.
; Don't even attempt to load driver if not enough memory available.
; Use highest memory required return.
; Link drivers in correct order.
; Add /Q (quiet mode) option.
; Disperse comments ad nauseum.
; 21/4/93
; Add /V (verbose mode) option.
; Move lastdrive report to end.
; Move abort request to end.
; Add count of character devices installed.
; Put entry point after LASTBYTE - smaller relocated code.
; Version 3.1 18/2/95
; Bug fix - push AX before fileerr if EXEC fails.
; Check whether found item is directory when looking for driver file.
; Version 3.11 12/2/96
; just add email address prior to uploading.
; Version 3.12 25/3/2004 - patches by Eric Auer
; using COM file format again
; compiles with free Arrowsoft ASM 2.0 now
; use e.g. free Borland Turbo C 2.01 TLINK /t as linker
; added DOS 5+ style memory size info passing to driver
; changed /H from alias-for-/? to load-into-umb, in other words:
; devload can now "devloadhigh" drivers (limited)...
; TODO: should probably do something to help MEM with the program name?
; Version 3.13 12/5/2004 - patches by Eric Auer and Erwin Veermans
; the /Q (quiet) option now has a stronger effect
; Version 3.14 9/7/2005 - patches by Eric Auer
; fixed a bug in block device loading: number of units in the
; driver header is now set to the value returned by init
; ... also changed some message texts to help UPX compression
; Version 3.15 16/7/2005 - patches by Eric Auer
; the /Q flag now suppresses even the "Driver staying resident"
; message and the message which tells whether /H (UMB) worked.
; Inspired by Erwin Veermans' patches.
; Version 3.16 4/11/2005 - contributed patches and some cleaning
; improved TASM compile (normal DEVLOAD compiler is ArrowASM),
; fixed the "UMB needs DOS 5+" version check, improved texts.
; comment style: added spaces after ; where ; starts a comment.
; Added some "short" and "ds:" as suggested by Diego Rodriguez.
; DR DOS version check based on research by Diego Rodriguez.
; Version 3.17 9/5/2007 - Eric: more RAM for DPB if DOS 7+ (FAT32)
; Version 3.18 11/5/2007 - Alexey: use magic CX / DX to build ext DPB
; (int 21.53), use true instead of setver
; version if DOS 5+, provide make.bat file.
; - Eric: Tuned messages to get 3069 byte .com
; (with UPX 2.02d --8086 --best)
; Version 3.19 2/8/2007 - Eric: must also set overlay relocation factor
; otherwise drivers in EXE format will crash
; Also tune error messages, use generic text
; for unlikely messages. Shorten help a bit.
; Version 3.20 13/9/2007 - Alexey: added EDR-DOS support
; (EDR DOS WiP 17.6.2007 and newer ONLY!)
; added fmake.bat & readme.txt
; Version 3.21 25/6/2007 - Eric: Converted to NASM with help of NoMySo
; script by Michael Devore, removed fmake...
; (ASM / NASM pick other direction variant in
; mov/xor/cmp/or/add/sub reg,reg machine code)
; WantedParas handling: check how much RAM/UMB
; driver needs at least. Tuned messages again.
; GNU GPL info (see infradead.org) added here.
; Version 3.22 14/7/2011 - Jeremy: if error testing umb size don't fall
; through and do double allocations, 2nd failing
; Version 3.23 02/8/2011 - Jeremy: don't overwrite CDS in use by non-block
; driver
; Version 3.24 04/8/2011 - Jeremy: improve handling holes in and lack of
; free CDS better, add /D option to specify
; which CDS slot to begin free search from -
; i.e. what drive letter to assign device
; Set exit # (errorlevel) to drive# assigned
; Version 3.25 05/8/2011 - Jeremy: fix bug where initial CDS not checked,
; adjust return codes to account for char devices
CPU 8086 ; ensure only 8086 compatible instructions
; .............................IMPROVEMENT IDEAS.............................
; Load into Upper Memory Blocks (like 'DEVICEHIGH='.)
; *** solved that in 3.12 ***
; Work from batch files like CONFIG.SYS.
; Change size of LASTDRIVE array by reallocating.
; Add support for SETVER.EXE.
; ................................DEFINES....................................
STACKLEN equ 200h ; *** only used in .exe version ***
; SMALLESTDRIVER equ 100h ; alloc. min 4k (100h paras) for driver
QuietFlag equ 80h
VerboseFlag equ 40h
AutoFlag equ 20h
UMBFlag equ 10h ; *** added 2004 ***
; ............................CODE (at last).................................
SEGMENT CSeg ; xxx public ALIGN=1 CLASS=CODE
org 100h ; *** was 0 for .exe version ***
; ............CODE TO BE EXECUTED ONCE RELOCATED TO TOP OF MEMORY............
Main0: jmp Main ; *** get right entry point for .com version ***
; DS:TopCSeg, ES:TopPSPSeg
; Get old PSP segment, store new PSP segment.
relocated: push es
mov es,[PSPSeg]
pop WORD [PSPSeg]
; Push segment of environment.
; DS:TopCSeg, ES:PSPSeg
push word [es:002Ch]
; Release old PSP segment. *** seems to trash DEBUG ***
mov ah,49h
int 21h
jnc relPSPok
; Failed to release PSP - print error.
mov dx,RelPSPErrMsg
call PrintError
mov ah,9
int 21h
mov dx,CrLfMsg
mov ah,9
int 21h
; Release environment segment.
; DS:TopCSeg, ES:CSeg
relPSPok: pop es
mov ah,49h
int 21h
jnc relenvok
; Failed to release environment - print error.
mov dx,RelEnvErrMsg
call PrintError
mov ah,9
int 21h
mov dx,CrLfMsg
mov ah,9
int 21h
relenvok: push cs
pop es
; *** added UMB alloc strategy selection ***
mov ax,5800h ; get current alloc strat
int 21h
mov [OldAllocStrat],ax
mov bp,1 ; default: no special UMB link state
test byte [ModeFlag], UMBFlag
jz lowload
; *** added because of UMB alloc strat ***
mov ax,5801h ; set alloc strat: UMB only
mov bx,40h ; (8xh is try UMB first, low 2nd)
; (4xh is only UMB, 00h is low only)
; (x0h first, x1h best, x2h last fit)
int 21h
jc lowload ; TODO print message, no UMB available
mov ax,5802h ; get UMB link state
int 21h
xor ah, ah
mov bp,ax ; store link state (AL is 1 if linked)
mov ax,5803h ; set UMB link state (!)
mov bx,1 ; make UMBs part of the DOS mem chain!
int 21h
jc lowload ; assume no UMB available
; mov bx,0fffh ; never desire > 64k of UMBs
mov bx,7fffh ; ask unrealistic size UMB
mov ah,48h
int 21h
; this should always fail - add check if it really did here?
; BX now tells us how much we could have gotten - in UMB space
cmp bx,[WantedParas] ; enough UMB free?
ja sizeok ; then get as much as we can
mov ax,5801h ; set new alloc strat: UMB first
mov bx,80h ; (8xh is try UMB first, low 2nd)
int 21h
lowload: ; *** end of added code ***
; Find out how much memory is available by asking for stupid amounts.
mov ah,48h
mov bx,0FFFFh ; ask unrealistic size, 1 MB
int 21h
; In MS-DOS version 6 and below, this will always fail, but check
; the return status just in case it does give what we asked for.
jnc grablowok ; esp. useful for UMB loading!
; BX now holds the maximum amount of memory available.
; Don't install if less than [minimum required] available.
cmp bx,[WantedParas] ; SMALLESTDRIVER
ja sizeok ; enough: get all we can
mov bx,[WantedParas] ; else: get all we need
; (...and expect to fail)
; Attempt to grab memory for driver.
sizeok: mov ah,48h
int 21h
jnc grablowok
; *** added because of UMB alloc strat ***
push ax ; store error code for alloc
mov ax,5801h ; set (here: restore) alloc strat
mov bx,[OldAllocStrat]
mov bh,0 ; sanitize
int 21h
test bp,1 ; UMBs originally part of chain?
jnz keepumbs
mov ax,5803h ; set UMB link state (!)
mov bx,0 ; remove UMBs from chain again
int 21h
pop ax ; restore error code from alloc
keepumbs: ; *** end of added part ***
; Failed to grab memory - print error and exit.
mov dx,GrabLoErrMsg
jmp allocerr
; Store segment of device.
grablowok: mov [DvcSeg],ax
mov WORD [DvcSeg+2],ax ; ALSO adjust relocation! 8/2007
mov [BlockSize],bx
; *** added because of UMB alloc strat ***
mov ax,5801h ; set (here: restore) alloc strat
mov bx,[OldAllocStrat]
mov bh,0 ; sanitize
int 21h
test bp,1 ; UMBs originally part of chain?
jnz keepumbs2
mov ax,5803h ; set UMB link state (!)
mov bx,0 ; remove UMBs from chain again
int 21h
keepumbs2: ; *** end of added part ***
; Disable Ctrl-Break.
mov dx,BreakHandler
mov ax,2523h
int 21h
; Copy interrupt vectors for later comparison.
; DS:TopCSeg, ES:TopCSeg
xor bx,bx
mov ds,bx
; DS:0000, ES:TopCSeg
mov si,bx
mov di,IntVectors
mov cx,200h
rep movsw
; Parse parameters in same way as SYSINIT does.
mov ds,[cs:PSPSeg]
; DS:TopPSPSeg, ES:TopCSeg
; Find end of filename in DI.
mov di,[cs:NamePtr]
add di,[cs:NameLen]
; Find end of command line in BX.
mov bl,byte [80h]
add bx,81h
; Compare them.
cmp bx,di
ja parmsgiven
; If they are the same, no parameters were given, so add a space.
mov byte [di],' '
inc bx
; Append CrLf to line.
parmsgiven: mov word [bx],0A0Dh
; Print 'Filename: ' if not in Quiet Mode.
push cs
pop ds
; test ModeFlag,QuietFlag ; *** phase error! ***
test byte [ModeFlag],QuietFlag ; ***
jnz noprintfname
mov dx,FNameMsg
mov ah,9
int 21h
; Make filename ASCII$ instead of ASCIIZ for printing.
mov di,NameBuffer
mov dx,di
mov cx,80h
xor al,al
repnz scasb
dec di
mov byte [di],'$'
; Print filename.
int 21h
; Restore to ASCIIZ.
mov byte [di],0
; Print CrLf after filename.
mov dx,CrLfMsg
int 21h
; Load driver file into memory.
; DS:TopCSeg, ES:TopCSeg
noprintfname: mov dx,NameBuffer
mov bx,DvcSeg
mov ax,4B03h ; load overlay
int 21h
jnc loadedok
; Print 'EXEC failure'.
mov dx,NotLoadMsg
push ax
; Restore error code.
fileerr: pop ax
; Print error message and number, get offset of cause in DX.
allocerr: call PrintError
; Indicate error (driver not loaded) in exit code
prexit:
mov al,255
; Print final message.
okexit: push ax ; save exit code that is in AL
mov ah,9
int 21h
pop ax
; Exit program.
exit: mov ah,4Ch
int 21h
; ...........................................................................
; DS:TopCSeg, ES:TopCSeg
; Check whether to print load address.
loadedok: test byte [ModeFlag],VerboseFlag ; *** byte ptr ***
jz noprintladdr
; Print 'Load address:'
mov dx,LoadAddrMsg
mov ah,9
int 21h
; Print segment of driver.
mov ax,[DvcSeg]
call PHWord
; Print ':0000'
mov dx,Colon0Msg
mov ah,9
int 21h
; DS:TopCSeg, ES:TopCSeg
; Get pointer to 'invar' (list of lists)
noprintladdr: mov ah,52h
int 21h
; Store for later use.
mov [InvarOfs],bx
mov [InvarSeg],es
; DS:TopCSeg, ES:InvarSeg
; Fetch nBlkDev and LastDrive from 'invar' (list of lists)
mov ax,[es:bx+20h]
mov word [nBlkDev],ax ; *** updates nBlkDev & LastDrive
; Determine 1st free CDS entry
push bx
push es
; Get pointer to LASTDRIVE array (Current Directory Structure - CDS).
les bx,[es:bx+16h]
; Calculate offset in CDS array of next free entry (>= current # of block devices)
mov al,[LastDrUsed] ; [LastDrUsed] init to drive to begin search with
mov ah,[LDrSize]
mul ah
; loop until free entry is found
CDSinuse:
add bx,ax ; update pointer into CDS array
; check that we don't exceed CDS array bounds (> LASTDRIVE)
mov al,[LastDrive]
cmp al,[LastDrUsed]
jbe nofreeCDS
; test flags (CDS[BX].flags) in current CDS entry to see if in use
test byte [es:bx+44h], 0C0h
jz CDSfound
; increment to next CDS entry
inc byte [LastDrUsed]
mov al,[LDrSize]
cbw
jmp CDSinuse
; No more PATH items or no PATH segment, so print error and exit.
nofreeCDS: push cs
pop ds
mov dx,NoFreeCDSMsg
jmp prexit
CDSfound:
pop es
pop bx
; Fetch max. sector size from 'invar' (list of lists)
mov ax,[es:bx+10h]
mov [SecSize],ax
push es
pop ds
; Trace device chain from 'invar'. (list of lists)
; Point DS:DI to first block header.
mov si,bx
; Point to next block header.
notlast: lds si,[si]
; Point to pointer within block header to the next one.
add si,word [cs:NextBlHOfs] ; ASM to NASM: add 'cs:'
; Loop while not at the end of the chain.
cmp word [si],byte -1 ; ASM optimizes 0FFFFh...
jnz notlast
; Point back at beginning of last block header in chain.
sub si,word [cs:NextBlHOfs] ; ASM to NASM...
; Store for later use.
mov [cs:ChainEndOfs],si
mov [cs:ChainEndSeg],ds
; DS:DvcSeg, ES:InvarSeg
; Point ES:BX to device after NUL device.
les bx,[es:bx+22h]
; Point DS:SI to new device (DvcSeg:0000).
mov ds,[cs:DvcSeg]
xor si,si
; DS:DvcSeg, ES:OldDvcSeg
; Install all devices in chain.
anoth_dvc: call InstallDevice
jnz anoth_dvc
; Print LASTDRIVE error message if necessary.
push cs
pop ds
cmp byte [LDrErrMsg],'0'
jz noldrerr
mov dx,LDrErrMsg
mov ah,9
int 21h
; Calculate size of driver to keep.
noldrerr: mov ax,[BlHEndOfs]
add ax,0Fh
rcr ax,1
mov cl,3
shr ax,cl
add ax,[EndSeg]
sub ax,[DvcSeg]
; Store size of driver to keep.
push ax
; Check whether anything installed, offer abortion if not.
mov ax,word [BlocksDone]
or ax,ax
jnz somedone
; Nothing installed - check whether Auto Mode.
test byte [ModeFlag],AutoFlag ; *** byte ptr ***
jnz somedone
; If it didn't want to stay anyway, don't ask.
pop cx
push cx
jcxz somedone
; Check whether any INT vectors changed.
xor di,di
mov es,di
; DS:TopCSeg, ES:0000
mov si,IntVectors
mov cx,200h
rep cmpsw
jnz somedone
; Nothing installed, so give option of aborting.
mov dx,AskEndMsg
mov ah,9
int 21h
; Get response from keyboard.
mov ah,8
badkey: int 21h
; If it's an extended character code, get the second byte and try again.
or al,al
jnz realchar
int 21h
jmp badkey
; If it's valid, act upon it, else loop for another.
realchar: cmp al,'N'
jz nokill
cmp al,'n'
jz nokill
cmp al,'Y'
jz kill
cmp al,'y'
jnz badkey
; Response was yes, so set length required to zero.
kill: pop bx
xor bx,bx
push bx
; mov bx,DvcSeg
; mov EndSeg,bx
; xor bx,bx
; mov BlHEndOfs,bx
; Print the key pressed.
nokill: mov ah,02h
mov dl,al
int 21h
; Print CrLf afterwards.
mov dx,CrLfMsg
mov ah,9
int 21h
; Print Lastdrive and LastDrUsed if blocks done and Verbose Mode.
somedone: push cs
pop ds
test byte [BlocksDone],0FFh ; *** byte ptr ***
jz noprintldrmsg
test byte [ModeFlag],VerboseFlag ; *** byte ptr ***
jz noprintldrmsg
mov al,byte [LastDrUsed]
mov ah,byte [LastDrive]
mov byte [LDMsgA], byte 'A'-1 ; explicit byte 3.16
mov byte [LDMsgB], byte 'A'-1 ; explicit byte 3.16
add byte [LDMsgA],al
add byte [LDMsgB],ah
mov dx,LastDrMsg
mov ah,9
int 21h
; If not Quiet Mode, print number of devices installed.
noprintldrmsg: test byte [ModeFlag],QuietFlag ; *** byte ptr ***
jnz noprintnuminst
; Get driver keep size into CX, don't print installed message if zero.
pop cx
push cx
jcxz noprintnuminst
; Print number of blocks installed, if any.
mov bl,[BlocksDone]
or bl,bl
jz noblocks
add [NumBlInstMsg],bl
mov dx,NumBlInstMsg
mov ah,9
int 21h
mov dx,NumInstMsgA
cmp bl,1
jnz blnoplural
inc dx
blnoplural: int 21h
; Print number of character devices installed, if any.
noblocks: mov bl,[CharsDone]
or bl,bl
jz noprintnuminst
add [NumChInstMsg],bl
mov dx,NumChInstMsg
mov ah,9
int 21h
mov dx,NumInstMsgA
cmp bl,1
jnz chnoplural
inc dx
chnoplural: int 21h
; Insert new nBlkDev into 'invar'. (list of lists)
noprintnuminst: les bx,[Invar]
mov al,[nBlkDev]
mov byte [es:bx+20h],al
; Restore driver size in paragraphs.
pop bx
; Test whether to print driver size.
test byte [ModeFlag],VerboseFlag ; *** byte ptr ***
jz noprintsize
; Print 'Size of driver in paras:'.
mov dx,SizeMsg
mov ah,9
int 21h
mov ax,bx
call PHWord
mov dx,FullStopMsg ; 'h.',cr,lf
mov ah,9
int 21h
noprintsize: or bx,bx
jnz lengthnotzero
; Length of driver is zero, so exit now.
mov dx,NotLoadedMsg
jmp prexit ; ***
; Check whether it fits in the allocated block.
lengthnotzero: cmp bx,[BlockSize] ; *** was cmp ax,... ***
jna drvrfits
mov dx,TooBigMsg
mov ah,9
int 21h
; Change memory allocation on lowest block in memory.
drvrfits: mov es,[DvcSeg]
mov ah,4Ah
int 21h
jnc allocok
; Print 'allocation error'.
mov dx,Reduce2ErrMsg
call PrintError
mov ah,9
int 21h
mov dx,Reduce2ErrMsga
mov ah,9
int 21h
; Check whether to print INT vectors changed.
allocok: test byte [ModeFlag],VerboseFlag ; *** byte ptr ***
jz noprintints
; Print 'Interrupt vectors changed:'
mov dx,IntChangeMsg
mov ah,9
int 21h
; Print all INTs changed.
xor bx,bx
mov es,bx
mov di,bx
mov si,IntVectors
mov cx,200h
; Print no comma before the first INT number.
mov dx,CommaMsg-1
; Compare INT vectors with copy taken earlier.
loopints: rep cmpsw
; If we stopped at the end, leave the loop.
jcxz lastdiff
; Flag that at least one was changed.
or bl,1
; Print 'h, ' between INT numbers.
mov ah,9
int 21h
; Check whether it was offset or segment that was different.
mov ax,di
dec ax
test ax,2
jnz notofs
; If was the offset, so don't bother checking the segment.
add di,byte 2 ; ASM to NASM: explicit byte
add si,byte 2 ; ASM to NASM: explicit byte
dec cx
; Print interrupt number.
notofs: shr ax,1
shr ax,1
call PHByte
; After the first one, print 'h, ' before the rest.
mov dx,CommaMsg
jmp loopints
; Print either full stop or 'None.'
lastdiff: mov dx,FullStopMsg
; Test flag to see whether any were changed.
or bl,bl
jnz notnochanges
; None were changed, so print 'None.' instead of a full stop.
mov dx,NoneMsg
notnochanges: mov ah,9
int 21h
; DS:TopCSeg, ES:0000
; Link from NUL device.
noprintints: les bx,[Invar]
add bx,byte 0022h ; ASM to NASM: explicit byte
mov ax,[NewDrvOfs]
mov [es:bx],ax
mov ax,[NewDrvSeg]
mov [es:bx+2],ax
push cs
pop es
; DS:TopCSeg, ES:TopCSeg
; Find last backslash in filename.
mov di,NameBuffer+80h
mov al,'\'
std
mov cx,0080h
repnz scasb ; NDISASM shows repnz as db 0xf2 here?
cld
add di,byte 2 ; ASM to NASM: explicit byte
; Point to arena header / MCB of driver segment.
mov ax,[DvcSeg]
dec ax
mov es,ax
; Set driver segment to self-ownership.