BuildXmlFiles.sbsl

#required Common/Path.sbsl
#required Common/Zip.sbsl
#required Common/Logger.sbsl

method Script(CliPath: String, ProjectPath: String, DestinationFolder: String = "", ArchiveName: String = "")
    if not Path.Exists(CliPath)
        Logger.e("Couldn't find edt cli executable: %CliPath")
    ;

    if not Path.Exists(ProjectPath)
        Logger.e("Couldn't find project folder: %ProjectPath")
    ;

    if DestinationFolder == ""
        DestinationFolder = new File(ProjectPath).Path
    ;

    if not Path.Exists(DestinationFolder)
        Logger.e("Couldn't find build destination folder: %DestinationFolder")
    ;

    if ArchiveName == ""
        ArchiveName = new File(ProjectPath).Name
    ;
    
    val DataPath = Files.CreateTempDirectory()
    val BuildPath = Files.CreateTempDirectory()

    val Args = [
        "-data",
        DataPath,
        "-command",
        "export",
        "--project",
        ProjectPath,
        "--configuration-files",
        BuildPath
    ]

    val EdtCli = new OsProcess(CliPath, Args, True)
    EdtCli.Start()
    EdtCli.WaitForCompletion()

    val ZipPath = Path.Join(DestinationFolder, "%ArchiveName.zip")
    Zip.CreateFromDirectory(BuildPath.Path, ZipPath)
    
    Logger.i("Zipped project path: ${ZipPath}")
;