build.gradle

group 'com.teambition'
version '1.8.5'

buildscript {
    ext.kotlin_version = '1.3.21'
    // confluent 3.0 -> 0.10.0.0
    // confluent 3.1 -> 0.10.1.0
    // confluent 3.2 -> 0.10.2.0
    // confluent 4.0 -> 1.0.0
    // confluent 4.1 -> 1.1.0
    ext.kafka_version = '1.1.0'

    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlin_version"
    }
}

apply plugin: 'java'
apply plugin: 'kotlin'
apply plugin: 'distribution'
apply plugin: 'application'

sourceCompatibility = 1.8

mainClassName = "com.teambition.kafka.connect.mongo.tools.ApplicationKt"

repositories {
    maven { url 'http://maven.aliyun.com/nexus/content/groups/public/' }
    maven { url 'http://packages.confluent.io/maven/' }
    mavenCentral()
}

defaultTasks 'clean', 'assembleDist'

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib:$kotlin_version"
    compile "org.apache.kafka:connect-api:$kafka_version"
    compile "org.apache.kafka:connect-json:$kafka_version"
    compile 'org.slf4j:slf4j-api:1.7.21'
    compile 'org.slf4j:slf4j-log4j12:1.7.21'
    compile 'org.json:json:20170516'
    compile 'org.apache.directory.studio:org.apache.commons.lang:2.6'
    compile 'org.mongodb:mongodb-driver:3.3.0'
    compile 'org.quartz-scheduler:quartz:2.3.0'
    compile 'org.jetbrains.kotlinx:kotlinx-coroutines-core:1.1.1'
    compile 'com.github.kittinunf.fuel:fuel:1.12.0'
    compile "io.confluent:kafka-schema-registry-client:4.0.0"

    testCompile 'junit:junit:4.12'
    testCompile 'com.google.truth:truth:0.30'
    testCompile 'org.easymock:easymock:3.4'
    testCompile "org.jetbrains.kotlin:kotlin-reflect:$kotlin_version"
    testCompile 'org.powermock:powermock-module-junit4:1.6.5'
    testCompile 'org.powermock:powermock-api-easymock:1.6.5'
    testCompile 'org.powermock:powermock-api-mockito-common:1.6.6'
    testCompile 'org.mockito:mockito-core:2.2.22'
    testCompile('info.batey.kafka:kafka-unit:0.6') {
        exclude module: 'kafka_2.11'
    }
    testCompile "org.apache.kafka:kafka_2.11:$kafka_version"
    testCompile 'de.flapdoodle.embed:de.flapdoodle.embed.mongo:1.50.5'
}

tasks.withType(Tar) {
    compression = Compression.GZIP
}

distributions {
    main {
        contents {
            into('etc') {
                from 'etc/'
            }
            into('lib') {
                from jar
                from project.configurations.runtime
            }
        }
    }
}

kotlin { experimental { coroutines 'enable' } }