build.gradle

buildscript {
    repositories {
        maven {
            url 'https://artifactory.quagilis.de/repo'
            credentials {
                username = "${artifactory_user}"
                password = "${artifactory_password}"
            }
        }

    }
    dependencies {
        classpath(group: 'org.jfrog.buildinfo', name: 'build-info-extractor-gradle', version: '2.0.9')
    }
}

allprojects {
    apply plugin: 'idea'
    apply plugin: 'groovy'
    apply plugin: 'artifactory'
    apply plugin: 'maven'


    group   = 'org.cqrest'
    version = '0.1.2-SNAPSHOT'

    defaultTasks 'clean', 'install'

    install.dependsOn test

    task sourceJar(type: Jar) {
        from sourceSets.main.groovy
        classifier = 'sources'
    }

    artifacts {
        archives sourceJar
    }

    repositories {
        mavenCentral()
        maven {
            url "https://artifactory.quagilis.de/repo/"
            credentials {
                username = "${artifactory_user}"
                password = "${artifactory_password}"
            }
        }
    }

    dependencies {
        compile 'org.codehaus.groovy:groovy-all:2.0.+'
        compile 'commons-logging:commons-logging:1.1.+'

        testCompile 'junit:junit:4.11'
        testCompile 'org.hamcrest:hamcrest-all:1.3'
        testCompile 'org.mockito:mockito-all:1.9.5'
    }

    idea.module {
        downloadJavadoc = true
        downloadSources = true
    }

    artifactory {
        contextUrl = "${artifactory_contextUrl}"   //The base Artifactory URL if not overridden by the publisher/resolver
        publish {
            repository {
                repoKey = 'libs-snapshot-local'
                username = "${artifactory_user}"
                password = "${artifactory_password}"
                maven = true
            }
        }
        resolve {
            repository {
                repoKey = 'libs-release'
                username = "${artifactory_user}"
                password = "${artifactory_password}"
                maven = true
            }
        }
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '1.9'
}

/* vim: set ft=groovy: */