dd-trace-java.gradle

buildscript {
  repositories {
    jcenter()
  }
  dependencies {
    classpath "io.franzbecker:gradle-lombok:1.13"
    classpath "org.jfrog.buildinfo:build-info-extractor-gradle:4.7.3"
    classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.1"
    classpath "net.ltgt.gradle:gradle-errorprone-plugin:0.0.14"
    classpath "org.unbroken-dome.gradle-plugins:gradle-testsets-plugin:1.5.0"
  }
}

plugins {
  id 'com.gradle.build-scan' version '1.15.1'
  id 'com.github.sherter.google-java-format' version '0.7.1'
  id 'com.dorongold.task-tree' version '1.3'
}

def isCI = System.getenv("CI") != null

allprojects {
  group = 'com.datadoghq'
  version = '0.16.0-SNAPSHOT'

  if (isCI) {
    buildDir = "${rootDir}/workspace/${projectDir.path.replace(rootDir.path, '')}/build/"
  }

  apply from: "${rootDir}/gradle/dependencies.gradle"
}

repositories {
  jcenter()
  mavenCentral()
}

description = 'dd-trace-java'

task traceAgentTest {}
task latestDepTest {}

// Applied here to allow publishing of artifactory build info
apply from: "${rootDir}/gradle/publish.gradle"

buildScan {
  termsOfServiceUrl = 'https://gradle.com/terms-of-service'
  termsOfServiceAgree = 'yes'

  if (isCI) {
    publishAlways()
    tag 'CI'
  }
}

ext.gradleWrapperVersion = '4.10.1'
task wrapper(type: Wrapper) {
  gradleVersion = gradleWrapperVersion
}