build.gradle

import org.jsonschema2pojo.SourceType

plugins {
    id 'application'
    id 'com.github.eirnym.js2p' version '1.0'
    id 'airbyte-integration-test-java'
}

configurations {
    jdbc
}

dependencies {
    implementation 'io.fabric8:kubernetes-client:5.3.1'
    implementation 'io.temporal:temporal-sdk:1.6.0'
    implementation 'org.apache.ant:ant:1.10.10'
    implementation 'org.apache.commons:commons-lang3:3.11'
    implementation 'org.apache.commons:commons-text:1.9'
    implementation 'org.eclipse.jetty:jetty-server:9.4.31.v20200723'
    implementation 'org.eclipse.jetty:jetty-servlet:9.4.31.v20200723'

    implementation project(':airbyte-analytics')
    implementation project(':airbyte-api')
    implementation project(':airbyte-config:models')
    implementation project(':airbyte-config:persistence')
    implementation project(':airbyte-db:lib')
    implementation project(':airbyte-json-validation')
    implementation project(':airbyte-protocol:models')
    implementation project(':airbyte-scheduler:persistence')
    implementation project(':airbyte-scheduler:models')

    testImplementation 'io.temporal:temporal-testing:1.6.0'
    testImplementation 'io.temporal:temporal-testing-junit5:1.5.0'
    testImplementation "org.flywaydb:flyway-core:7.14.0"
    testImplementation 'org.mockito:mockito-inline:4.0.0'
    testImplementation 'org.postgresql:postgresql:42.2.18'
    testImplementation 'org.testcontainers:testcontainers:1.15.3'
    testImplementation 'org.testcontainers:postgresql:1.15.3'

    testImplementation project(':airbyte-commons-docker')
    testImplementation project(':airbyte-test-utils')

    integrationTestJavaImplementation project(':airbyte-workers')
}

jsonSchema2Pojo {
    sourceType = SourceType.YAMLSCHEMA
    source = files("${sourceSets.main.output.resourcesDir}/workers_models")
    targetDirectory = new File(project.buildDir, 'generated/src/gen/java/')
    removeOldOutput = true

    targetPackage = 'io.airbyte.scheduler.models'

    useLongIntegers = true
    generateBuilders = true
    includeConstructors = false
    includeSetters = true
}

mainClassName = 'io.airbyte.workers.WorkerApp'

application {
    mainClass = mainClassName
    applicationDefaultJvmArgs = ['-XX:MaxRAMPercentage=75.0']
}

task copyGeneratedTar(type: Copy) {
    dependsOn copyDocker
    dependsOn distTar

    from('build/distributions') {
        include 'airbyte-workers-*.tar'
    }
    into 'build/docker/bin'
}

Task dockerBuildTask = getDockerBuildTask("worker",  "$project.projectDir")
dockerBuildTask.dependsOn(copyGeneratedTar)
assemble.dependsOn(dockerBuildTask)

task cloudStorageIntegrationTest(type: Test) {
    useJUnitPlatform {
        includeTags cloudStorageTestTagName
    }
    testLogging {
        events "passed", "skipped", "failed"
    }
}