Add "SQLite" and "MongoDB" recipes to new "Databases" chapter.

Author: thirdtruck

chapters/databases/index.html

@@ -0,0 +1,18 @@
+---
+layout: chapter
+title: Databases
+chapter: Databases
+---
+
+{% capture url %}/chapters/{{ page.chapter | replace: ' ', '_' | downcase }}{% endcapture %}
+{% capture indexurl %}{{ url }}/index.html{% endcapture %}
+
+<ul>
+{% for page in site.pages %}
+  {% if page.url contains url %}
+    {% unless page.url == indexurl %}
+  <li><a href="{{ page.url | replace: '.html', '' }}">{{ page.title }}</a></li>
+    {% endunless %}
+  {% endif %}
+{% endfor %}
+</ul>

chapters/databases/mongodb.md

@@ -0,0 +1,67 @@
+---
+layout: recipe
+title: MongoDB
+chapter: Databases
+---
+## Problem
+
+You need to interface with a MongoDB database.
+
+## Solution
+
+### For Node.js
+
+### Setup
+* [Install MongoDB](http://www.mongodb.org/display/DOCS/Quickstart) on your computer if you have not already.
+
+* [Install the native MongoDB module](https://github.com/christkv/node-mongodb-native).
+
+#### Saving Records
+
+{% highlight coffeescript %}
+mongo = require 'mongodb'
+
+server = new mongo.Server "127.0.0.1", 27017, {}
+
+client = new mongo.Db 'test', server
+
+# save() updates existing records or inserts new ones as needed
+exampleSave = (dbErr, collection) ->
+	console.log "Unable to access database: #{dbErr}" if dbErr
+	collection.save { _id: "my_favorite_latte", flavor: "honeysuckle" }, (err, docs) ->
+		console.log "Unable to save record: #{err}" if err
+		client.close()
+
+client.open (err, database) ->
+	client.collection 'coffeescript_example', exampleSave
+{% endhighlight %}
+
+#### Finding Records
+
+{% highlight coffeescript %}
+mongo = require 'mongodb'
+
+server = new mongo.Server "127.0.0.1", 27017, {}
+
+client = new mongo.Db 'test', server
+
+exampleFind = (dbErr, collection) ->
+	console.log "Unable to access database: #{dbErr}" if dbErr
+	collection.find({ _id: "my_favorite_latte" }).nextObject (err, result) ->
+		if err
+			console.log "Unable to find record: #{err}"
+		else
+			console.log result # => {  id: "my_favorite_latte", flavor: "honeysuckle" }
+		client.close()
+
+client.open (err, database) ->
+	client.collection 'coffeescript_example', exampleFind
+{% endhighlight %}
+
+### For Browsers
+
+A [REST-based interface](https://github.com/tdegrunt/mongodb-rest) is in the works.  This will provide AJAX-based access.
+
+## Discussion
+
+This recipe breaks the *save* and *find* into separate examples in order to separate the MongoDB-specific concerns from the task of connection and callback management.  The [async module](https://github.com/caolan/async) can help with that.

chapters/databases/sqlite.md

@@ -0,0 +1,92 @@
+---
+layout: recipe
+title: SQLite
+chapter: Databases
+---
+## Problem
+
+You need to interface with a [SQLite](http://www.sqlite.org/) database from inside of Node.js.
+
+## Solution
+
+Use the [SQLite module](http://code.google.com/p/node-sqlite/).
+
+{% highlight coffeescript %}
+sqlite = require 'sqlite'
+
+db = new sqlite.Database
+
+# The module uses asynchronous methods,
+# so we chain the calls the db.execute
+exampleCreate = ->
+	db.execute "CREATE TABLE snacks (name TEXT(25), flavor TEXT(25))",
+		(exeErr, rows) ->
+			throw exeErr if exeErr
+			exampleInsert()
+
+exampleInsert = ->
+	db.execute "INSERT INTO snacks (name, flavor) VALUES ($name, $flavor)",
+		{ $name: "Potato Chips", $flavor: "BBQ" },
+		(exeErr, rows) ->
+			throw exeErr if exeErr
+			exampleSelect()
+
+exampleSelect = ->
+	db.execute "SELECT name, flavor FROM snacks",
+		(exeErr, rows) ->
+			throw exeErr if exeErr
+			console.log rows[0] # => { name: 'Potato Chips', flavor: 'BBQ' }
+
+# :memory: creates a DB in RAM
+# You can supply a filepath (like './example.sqlite') to create/open one on disk
+db.open ":memory:", (openErr) ->
+	throw openErr if openErr
+	exampleCreate()
+{% endhighlight %}
+
+## Discussion
+
+You can also prepare your SQL queries beforehand:
+
+{% highlight coffeescript %}
+sqlite = require 'sqlite'
+async = require 'async' # Not required but added to make the example more concise
+
+db = new sqlite.Database
+
+createSQL = "CREATE TABLE drinks (name TEXT(25), price NUM)"
+
+insertSQL = "INSERT INTO drinks (name, price) VALUES (?, ?)"
+
+selectSQL = "SELECT name, price FROM drinks WHERE price < ?"
+
+create = (onFinish) ->
+	db.execute createSQL, (exeErr) ->
+		throw exeErr if exeErr
+		onFinish()
+	
+prepareInsert = (name, price, onFinish) ->
+	db.prepare insertSQL, (prepErr, statement) ->
+		statement.bindArray [name, price], (bindErr) ->
+			statement.fetchAll (fetchErr, rows) -> # Called so that it executes the insert
+				onFinish()
+
+prepareSelect = (onFinish) ->
+	db.prepare selectSQL, (prepErr, statement) ->
+		statement.bindArray [1.00], (bindErr) ->
+			statement.fetchAll (fetchErr, rows) ->
+				console.log rows[0] # => { name: "Mia's Root Beer", price: 0.75 }
+				onFinish()
+
+db.open ":memory:", (openErr) ->
+	async.series([
+		(onFinish) -> create onFinish,
+		(onFinish) -> prepareInsert "LunaSqueeze", 7.95, onFinish,
+		(onFinish) -> prepareInsert "Viking Sparkling Grog", 4.00, onFinish,
+		(onFinish) -> prepareInsert "Mia's Root Beer", 0.75, onFinish,
+		(onFinish) -> prepareSelect onFinish
+	])
+{% endhighlight %}
+
+The [SQLite version of SQL](http://www.sqlite.org/lang.html) and the [node-sqlite module documentation](https://github.com/orlandov/node-sqlite#readme) provide more complete information.
+