-
Notifications
You must be signed in to change notification settings - Fork 0
/
c2p_grey16asm.asm
557 lines (444 loc) · 17.9 KB
/
c2p_grey16asm.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
* :ts=8 c2p_grey16asm.asm
*
* cp4 - Commodore C+4 emulator
* Copyright (C) 1998 Gáti Gergely
*
* Chunky2Planar written by Zavacki Ferenc
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software Foundation,
* Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
*
* e-mail: [email protected]
*
xref _c ; *b chunky
xref _PenTable ; b[] PenTable
CHUNKY_BUFFER_WIDTH equ 352
CHUNKY_BUFFER_HEIGHT equ 283
*-------------------------------------------------------------------------------
* IN: a0.l - Chunky Buffer Address
* a1.l - Planar Buffer Address
* d0.l - Bitplane Byte Width
xdef _c2pf
_c2pf bsr cpentab
movem.l d2-d7/a2-a6,-(sp)
move.l a0,(C2P_ChunkyBufferAddress)
move.l a1,(C2P_PlanarBufferAddress)
move.l d0,(C2P_BitplaneByteWidth)
move.l (C2P_ChunkyBufferAddress,pc),a0
move.l (C2P_PlanarBufferAddress,pc),a1
lea (CHUNKY_BUFFER_WIDTH*CHUNKY_BUFFER_HEIGHT,a0),a2
move.l (C2P_BitplaneByteWidth,pc),d7
move.l #$0F0F0F0F,d5
move.l (a0)+,d0
and.l d5,d0
lsl.l #4,d0
move.l (a0)+,d1
and.l d5,d1
or.l d1,d0
move.l (a0)+,d1
and.l d5,d1
lsl.l #4,d1
move.l (a0)+,d2
and.l d5,d2
or.l d2,d1
move.l (a0)+,d2
and.l d5,d2
lsl.l #4,d2
move.l (a0)+,d3
and.l d5,d3
or.l d3,d2
move.l (a0)+,d3
and.l d5,d3
lsl.l #4,d3
move.l (a0)+,d4
and.l d5,d4
or.l d4,d3
move.w d2,d4
move.w d0,d2
swap d2
move.w d2,d0
move.w d4,d2
move.w d3,d4
move.w d1,d3
swap d3
move.w d3,d1
move.w d4,d3
move.l #$00FF00FF,d5
move.l d1,d4
lsr.l #8,d4
eor.l d0,d4
and.l d5,d4
eor.l d4,d0
lsl.l #8,d4
eor.l d4,d1
move.l d3,d4
lsr.l #8,d4
eor.l d2,d4
and.l d5,d4
eor.l d4,d2
lsl.l #8,d4
eor.l d4,d3
move.l #$33333333,d5
move.l d2,d4
lsr.l #2,d4
eor.l d0,d4
and.l d5,d4
eor.l d4,d0
lsl.l #2,d4
eor.l d4,d2
move.l d3,d4
lsr.l #2,d4
eor.l d1,d4
and.l d5,d4
eor.l d4,d1
lsl.l #2,d4
eor.l d4,d3
move.l #$55555555,d5
move.l d1,d4
lsr.l #1,d4
eor.l d0,d4
and.l d5,d4
eor.l d4,d0
lsl.l #1,d4
eor.l d4,d1
move.l d3,d4
lsr.l #1,d4
eor.l d2,d4
and.l d5,d4
eor.l d4,d2
lsl.l #1,d4
eor.l d4,d3
move.l d0,a3
move.l d1,a4
move.l d2,a5
move.l d3,a6
move.l #CHUNKY_BUFFER_WIDTH/32,d6
.1 move.l #$0F0F0F0F,d5
move.l (a0)+,d0
and.l d5,d0
lsl.l #4,d0
move.l (a0)+,d1
and.l d5,d1
or.l d1,d0
move.l (a0)+,d1
and.l d5,d1
lsl.l #4,d1
move.l (a0)+,d2
and.l d5,d2
or.l d2,d1
move.l (a0)+,d2
and.l d5,d2
lsl.l #4,d2
move.l (a0)+,d3
and.l d5,d3
or.l d3,d2
move.l (a0)+,d3
and.l d5,d3
lsl.l #4,d3
move.l (a0)+,d4
and.l d5,d4
or.l d4,d3
move.l a6,(a1)+
move.w d2,d4
move.w d0,d2
swap d2
move.w d2,d0
move.w d4,d2
move.w d3,d4
move.w d1,d3
swap d3
move.w d3,d1
move.w d4,d3
move.l #$00FF00FF,d5
move.l d1,d4
lsr.l #8,d4
eor.l d0,d4
and.l d5,d4
eor.l d4,d0
lsl.l #8,d4
eor.l d4,d1
move.l a5,(-4,a1,d7.l)
move.l d3,d4
lsr.l #8,d4
eor.l d2,d4
and.l d5,d4
eor.l d4,d2
lsl.l #8,d4
eor.l d4,d3
move.l #$33333333,d5
move.l d2,d4
lsr.l #2,d4
eor.l d0,d4
and.l d5,d4
eor.l d4,d0
lsl.l #2,d4
eor.l d4,d2
move.l a4,(-4,a1,d7.l*2)
move.l d3,d4
lsr.l #2,d4
eor.l d1,d4
and.l d5,d4
eor.l d4,d1
lsl.l #2,d4
eor.l d4,d3
move.l #$55555555,d5
move.l d1,d4
lsr.l #1,d4
eor.l d0,d4
and.l d5,d4
eor.l d4,d0
lsl.l #1,d4
eor.l d4,d1
add.l d7,a1
move.l a3,(-4,a1,d7.l*2)
sub.l d7,a1
move.l d3,d4
lsr.l #1,d4
eor.l d2,d4
and.l d5,d4
eor.l d4,d2
lsl.l #1,d4
eor.l d4,d3
move.l d0,a3
move.l d1,a4
move.l d2,a5
move.l d3,a6
sub.l #1,d6
bne .2
move.l #CHUNKY_BUFFER_WIDTH/32,d6
lea (-CHUNKY_BUFFER_WIDTH/8,a1,d7.l*4),a1
.2 cmp.l a2,a0
bne .1
move.l a6,(a1)
move.l a5,(a1,d7.l)
move.l a4,(a1,d7.l*2)
add.l d7,a1
move.l a3,(a1,d7.l*2)
movem.l (sp)+,d2-d7/a2-a6
rts
*-------------------------------------------------------------------------------
*
* a0 - chunky-buffer (PenTab)
* _c - real chunky
* _PenTable - converter
*
cpentab movem.l d0/a0-a3,-(sp)
move.l _c,a1
move.l #_PenTable,a2
clr.l d0
move.w #6204,d1
.c1 move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
move.b (a1)+,d0
move.b (a2,d0.l),(a0)+
dbf d1,.c1
movem.l (sp)+,d0/a0-a3
rts
*-------------------------------------------------------------------------------
* IN: a0.l - Chunky Buffer Address
* a1.l - Delta Buffer Address
* a2.l - Planar Buffer Address
* a3.l - Line Skip Buffer Address
* d0.l - Bitplane Byte Width
xdef _c2pd
_c2pd bsr cpentab
movem.l d2-d7/a2-a4,-(sp)
move.l a0,(C2P_ChunkyBufferAddress)
move.l a1,(C2P_DeltaBufferAddress)
move.l a2,(C2P_PlanarBufferAddress)
move.l a3,(C2P_LineSkipBufferAddress)
move.l d0,(C2P_BitplaneByteWidth)
move.l (C2P_ChunkyBufferAddress,pc),a0
move.l (C2P_DeltaBufferAddress,pc),a1
move.l (C2P_PlanarBufferAddress,pc),a2
move.l (C2P_LineSkipBufferAddress),a3
lea (CHUNKY_BUFFER_WIDTH*CHUNKY_BUFFER_HEIGHT,a0),a4
move.l (C2P_BitplaneByteWidth,pc),d7
.12 tst.b (a3)+
beq .14
add.l #CHUNKY_BUFFER_WIDTH,a0
add.l #CHUNKY_BUFFER_WIDTH,a1
lea (a2,d7.l*4),a2
bra .13
.14 move.l #CHUNKY_BUFFER_WIDTH/32,d6
.11 cmp.l (a0)+,(a1)+
bne .1
cmp.l (a0)+,(a1)+
bne .2
cmp.l (a0)+,(a1)+
bne .3
cmp.l (a0)+,(a1)+
bne .4
cmp.l (a0)+,(a1)+
bne .5
cmp.l (a0)+,(a1)+
bne .6
cmp.l (a0)+,(a1)+
bne .7
cmp.l (a0)+,(a1)+
bne .8
.10 add.l #4,a2
sub.l #1,d6
bne .11
lea (-CHUNKY_BUFFER_WIDTH/8,a2,d7.l*4),a2
.13 cmp.l a4,a0
bne .12
movem.l (sp)+,d2-d7/a2-a4
rts
.1 sub.l #1*4,a0
add.l #7*4,a1
bra .9
.2 sub.l #2*4,a0
add.l #6*4,a1
bra .9
.3 sub.l #3*4,a0
add.l #5*4,a1
bra .9
.4 sub.l #4*4,a0
add.l #4*4,a1
bra .9
.5 sub.l #5*4,a0
add.l #3*4,a1
bra .9
.6 sub.l #6*4,a0
add.l #2*4,a1
bra .9
.7 sub.l #7*4,a0
add.l #1*4,a1
bra .9
.8 sub.l #8*4,a0
add.l #0*4,a1
bra .9
.9 move.l #$0F0F0F0F,d5
move.l (a0)+,d0
and.l d5,d0
lsl.l #4,d0
move.l (a0)+,d1
and.l d5,d1
or.l d1,d0
move.l (a0)+,d1
and.l d5,d1
lsl.l #4,d1
move.l (a0)+,d2
and.l d5,d2
or.l d2,d1
move.l (a0)+,d2
and.l d5,d2
lsl.l #4,d2
move.l (a0)+,d3
and.l d5,d3
or.l d3,d2
move.l (a0)+,d3
and.l d5,d3
lsl.l #4,d3
move.l (a0)+,d4
and.l d5,d4
or.l d4,d3
move.w d2,d4
move.w d0,d2
swap d2
move.w d2,d0
move.w d4,d2
move.w d3,d4
move.w d1,d3
swap d3
move.w d3,d1
move.w d4,d3
move.l #$00FF00FF,d5
move.l d1,d4
lsr.l #8,d4
eor.l d0,d4
and.l d5,d4
eor.l d4,d0
lsl.l #8,d4
eor.l d4,d1
move.l d3,d4
lsr.l #8,d4
eor.l d2,d4
and.l d5,d4
eor.l d4,d2
lsl.l #8,d4
eor.l d4,d3
move.l #$33333333,d5
move.l d2,d4
lsr.l #2,d4
eor.l d0,d4
and.l d5,d4
eor.l d4,d0
lsl.l #2,d4
eor.l d4,d2
move.l d3,d4
lsr.l #2,d4
eor.l d1,d4
and.l d5,d4
eor.l d4,d1
lsl.l #2,d4
eor.l d4,d3
move.l #$55555555,d5
move.l d1,d4
lsr.l #1,d4
eor.l d0,d4
and.l d5,d4
eor.l d4,d0
add.l d7,a2
move.l d0,(a2,d7.l*2)
sub.l d7,a2
lsl.l #1,d4
eor.l d4,d1
move.l d1,(a2,d7.l*2)
move.l d3,d4
lsr.l #1,d4
eor.l d2,d4
and.l d5,d4
eor.l d4,d2
move.l d2,(a2,d7.l)
lsl.l #1,d4
eor.l d4,d3
move.l d3,(a2)
bra .10
*-------------------------------------------------------------------------------
cnop 0,4
C2P_ChunkyBufferAddress dc.l 0
C2P_DeltaBufferAddress dc.l 0
C2P_PlanarBufferAddress dc.l 0
C2P_LineSkipBufferAddress dc.l 0
C2P_BitplaneByteWidth dc.l 0