-
Notifications
You must be signed in to change notification settings - Fork 0
/
c2p_monoasm.asm
339 lines (308 loc) · 6.89 KB
/
c2p_monoasm.asm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
* :ts=8 c2p_monoasm.asm
*
* cp4 - Commodore C+4 emulator
* Copyright (C) 1998 Gáti Gergely
*
* This program is free software; you can redistribute it and/or modify
* it under the terms of the GNU General Public License as published by
* the Free Software Foundation; either version 2 of the License, or
* (at your option) any later version.
*
* This program is distributed in the hope that it will be useful,
* but WITHOUT ANY WARRANTY; without even the implied warranty of
* MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
* GNU General Public License for more details.
*
* You should have received a copy of the GNU General Public License
* along with this program; if not, write to the Free Software Foundation,
* Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
*
* e-mail: [email protected]
*
SCRHEIGHT EQU 283
SCRWIDTH EQU 352
xref _bmx * l
xdef _convdeltaasm
xdef _convfullasm
*
* IN: a0 - chunky
* a1 - planar
_convfullasm movem.l d2-d7/a2-a3,-(sp)
move.l _bmx,d5
move.l #$40404040,d7
move.w #SCRHEIGHT-2,d0
.out moveq #(SCRWIDTH/32)-1,d1
move.l a1,a2
.in
; 1. byte
move.l (a0)+,d3 ; D3
and.l d7,d3 ;.1......|.2......|.3......|.4......
lsr.w #1,d3 ;.1......|.2......|..3.....|..4.....
move.w d3,d4 ; \------ D4 ------/
swap d3 ; D3: .1......|.2......
add.w d3,d3 ; 1.......|2.......
or.w d3,d4 ; D4: 1.3.....|2.4.....
lsr.b #1,d4 ; D4: 1.3.....|.2.4....
move.w d4,d3 ; \------ D3 ------/
lsr.w #8,d3 ; D3: ........|1.3.....
or.b d4,d3 ; D3: 1234....
move.b d3,d6 ; D6: 1234....
move.l (a0)+,d3 ; D3
and.l d7,d3 ;.1......|.2......|.3......|.4......
lsr.w #5,d3 ;.1......|.2......|......3.|......4.
move.w d3,d4 ; \------ D4 ------/
swap d3 ; D3: .1......|.2......
lsr.w #3,d3 ; D3: ....1...|....2...
or.w d3,d4 ; ....1.3.|....2.4.
lsr.b #1,d4 ; D4: ....1.3.|.....2.4
move.w d4,d3 ; \------ D3 ------/
lsr.w #8,d3 ; D3: ........|....1.3.
or.b d4,d3 ; D3: ....1234
or.b d3,d6 ; D6: 12341234
lsl.l #8,d6
; 2. byte
move.l (a0)+,d3
and.l d7,d3
lsr.w #1,d3
move.w d3,d4
swap d3
add.w d3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ; xxxx....
move.b d3,d6 ; xxxx....
move.l (a0)+,d3
and.l d7,d3
lsr.w #5,d3
move.w d3,d4
swap d3
lsr.w #3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ;....xxxx
or.b d3,d6 ;xxxxxxxx
lsl.l #8,d6
; 3. byte
move.l (a0)+,d3
and.l d7,d3
lsr.w #1,d3
move.w d3,d4
swap d3
add.w d3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ; xxxx....
move.b d3,d6 ; xxxx....
move.l (a0)+,d3
and.l d7,d3
lsr.w #5,d3
move.w d3,d4
swap d3
lsr.w #3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ;....xxxx
or.b d3,d6 ;xxxxxxxx
lsl.l #8,d6
; 4. byte
move.l (a0)+,d3
and.l d7,d3
lsr.w #1,d3
move.w d3,d4
swap d3
add.w d3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ; xxxx....
move.b d3,d6 ; xxxx....
move.l (a0)+,d3
and.l d7,d3
lsr.w #5,d3
move.w d3,d4
swap d3
lsr.w #3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ;....xxxx
or.b d3,d6 ;xxxxxxxx
; TO-CHIP
move.l d6,(a2)+
dbf d1,.in
add.l d5,a1
dbf d0,.out
movem.l (sp)+,d2-d7/a2-a3
rts
*
* IN: a0 - chunky
* a1 - planar
* d0 - delta
*
_convdeltaasm movem.l d2-d7/a2-a3,-(sp)
move.l _bmx,d5
move.l #$40404040,d7
move.l d0,a3
move.w #SCRHEIGHT-2,d0
.out moveq #(SCRWIDTH/32)-1,d1
move.l a1,a2
.in cmp.l (a3)+,(a0)+
bne .1
cmp.l (a3)+,(a0)+
bne .2
cmp.l (a3)+,(a0)+
bne .3
cmp.l (a3)+,(a0)+
bne .4
cmp.l (a3)+,(a0)+
bne .5
cmp.l (a3)+,(a0)+
bne .6
cmp.l (a3)+,(a0)+
bne .7
cmp.l (a3)+,(a0)+
bne .8
addq.l #4,a2
.tov dbf d1,.in
add.l d5,a1
dbf d0,.out
movem.l (sp)+,d2-d7/a2-a3
rts
.1 subq.l #4,a0
add.l #28,a3
bra .conv
.2 subq.l #8,a0
add.l #24,a3
bra .conv
.3 sub.l #12,a0
add.l #20,a3
bra .conv
.4 sub.l #16,a0
add.l #16,a3
bra .conv
.5 sub.l #20,a0
add.l #12,a3
bra .conv
.6 sub.l #24,a0
addq.l #8,a3
bra .conv
.7 sub.l #28,a0
addq.l #4,a3
bra .conv
.8 sub.l #32,a0
; 1. byte
.conv move.l (a0)+,d3 ; D3
and.l d7,d3 ;.1......|.2......|.3......|.4......
lsr.w #1,d3 ;.1......|.2......|..3.....|..4.....
move.w d3,d4 ; \------ D4 ------/
swap d3 ; D3: .1......|.2......
add.w d3,d3 ; 1.......|2.......
or.w d3,d4 ; D4: 1.3.....|2.4.....
lsr.b #1,d4 ; D4: 1.3.....|.2.4....
move.w d4,d3 ; \------ D3 ------/
lsr.w #8,d3 ; D3: ........|1.3.....
or.b d4,d3 ; D3: 1234....
move.b d3,d6 ; D6: 1234....
move.l (a0)+,d3 ; D3
and.l d7,d3 ;.1......|.2......|.3......|.4......
lsr.w #5,d3 ;.1......|.2......|......3.|......4.
move.w d3,d4 ; \------ D4 ------/
swap d3 ; D3: .1......|.2......
lsr.w #3,d3 ; D3: ....1...|....2...
or.w d3,d4 ; ....1.3.|....2.4.
lsr.b #1,d4 ; D4: ....1.3.|.....2.4
move.w d4,d3 ; \------ D3 ------/
lsr.w #8,d3 ; D3: ........|....1.3.
or.b d4,d3 ; D3: ....1234
or.b d3,d6 ; D6: 12341234
lsl.l #8,d6
; 2. byte
move.l (a0)+,d3
and.l d7,d3
lsr.w #1,d3
move.w d3,d4
swap d3
add.w d3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ; xxxx....
move.b d3,d6 ; xxxx....
move.l (a0)+,d3
and.l d7,d3
lsr.w #5,d3
move.w d3,d4
swap d3
lsr.w #3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ;....xxxx
or.b d3,d6 ;xxxxxxxx
lsl.l #8,d6
; 3. byte
move.l (a0)+,d3
and.l d7,d3
lsr.w #1,d3
move.w d3,d4
swap d3
add.w d3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ; xxxx....
move.b d3,d6 ; xxxx....
move.l (a0)+,d3
and.l d7,d3
lsr.w #5,d3
move.w d3,d4
swap d3
lsr.w #3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ;....xxxx
or.b d3,d6 ;xxxxxxxx
lsl.l #8,d6
; 4. byte
move.l (a0)+,d3
and.l d7,d3
lsr.w #1,d3
move.w d3,d4
swap d3
add.w d3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ; xxxx....
move.b d3,d6 ; xxxx....
move.l (a0)+,d3
and.l d7,d3
lsr.w #5,d3
move.w d3,d4
swap d3
lsr.w #3,d3
or.w d3,d4
lsr.b #1,d4
move.w d4,d3
lsr.w #8,d3
or.b d4,d3 ;....xxxx
or.b d3,d6 ;xxxxxxxx
; TO-CHIP
move.l d6,(a2)+
bra .tov