check-source-header.gradle

project.ext.licenseHeaderText = """/*
 * Copyright 2018-2019 the original author or authors.
 *
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *      http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */
"""

task checkCopyrightHeader {
    doLast {
        def headerLines = project.licenseHeaderText.readLines()

        sourceSets.main.kotlin.srcDirs.each { dir ->
            def tree = fileTree(dir)
            tree.include("**/*.kt")

            tree.visit {
                if (!it.isDirectory()) {
                    def failed = false

                    it.file.withReader { reader ->
                        for (line in headerLines) {
                            if (line != reader.readLine()) {
                                failed = true
                                break
                            }
                        }
                    }

                    if (failed) {
                        throw new IllegalStateException("Copyright header not found in file: " + it.file)
                    }
                }
            }
        }
    }
}

check.dependsOn(checkCopyrightHeader)