diff --git a/media-plugins/hdx-realtime-media-engine/Manifest b/media-plugins/hdx-realtime-media-engine/Manifest
new file mode 100644
index 0000000000000..152bcd589aeb5
--- /dev/null
+++ b/media-plugins/hdx-realtime-media-engine/Manifest
@@ -0,0 +1,2 @@
+DIST HDX_RealTime_Media_Engine_2.9.200_for_Linux.zip 30107965 BLAKE2B e0ffad7f86ceef5cba22a12654452e0f9956b0c0169715900fec02b7d4fdbc22d8fa001c811b4b0d7c716dc05eae64486a0dd67eda817382faa804ec134d82b5 SHA512 291623d36e05ec2bc5269de78906acb05e989eccb7f7b7cf5b00feec93454e1f363f5bdb754c926db2883f60a3486403c39644bbccbfe5ee8557d439fc4bbc01
+DIST HDX_RealTime_Media_Engine_2.9.200_for_Linux_x64.zip 30135671 BLAKE2B 9547e51ac3d1eaa3dc3f8b2ef21b02f500a579029ee3685503199f0308f52131a6135d726a98d0bb7b58332b7e5931cdf2a6028343cd1b4286edd25c584068ca SHA512 79b0e5db35dcb0635a645622a9609ccb20859deb98ceae0c6e6dde9232723a1ef9625dd97b54697662b4a42c39e9de0cc96ab6b38d5587a39ba208120f027e92
diff --git a/media-plugins/hdx-realtime-media-engine/hdx-realtime-media-engine-2.9.200.2506.ebuild b/media-plugins/hdx-realtime-media-engine/hdx-realtime-media-engine-2.9.200.2506.ebuild
new file mode 100644
index 0000000000000..58471fa158f8c
--- /dev/null
+++ b/media-plugins/hdx-realtime-media-engine/hdx-realtime-media-engine-2.9.200.2506.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit unpacker
+
+MY_PV="$(ver_cut 1-3)"
+
+DESCRIPTION="HDX RealTime Media Engine plugin for Citrix Workspace App"
+HOMEPAGE="https://www.citrix.com/"
+SRC_URI="amd64? ( HDX_RealTime_Media_Engine_${MY_PV}_for_Linux_x64.zip )
+	x86? ( HDX_RealTime_Media_Engine_${MY_PV}_for_Linux.zip )"
+LICENSE="icaclient"
+SLOT="0"
+
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+RESTRICT="mirror"
+
+DEPEND="app-arch/unzip"
+RDEPEND="
+	net-misc/icaclient
+	|| (
+		media-sound/pulseaudio
+		media-sound/apulse
+	)
+"
+
+ICAROOT="/opt/Citrix/ICAClient"
+QA_PREBUILT="${ICAROOT#/}/*"
+
+S="${WORKDIR}/usr/local/bin"
+
+pkg_nofetch() {
+	elog "Download the client file ${A} from"
+	elog "https://www.citrix.com/de-de/downloads/citrix-receiver/additional-client-software/hdx-realtime-media-engine-ltsrcu-latest.html"
+	elog "and place it into your DISTDIR directory."
+}
+
+pkg_setup() {
+	case ${ARCH} in
+		amd64)
+			zip_dir="x86_64"
+			zip_arch="amd64"
+		;;
+		x86)
+			zip_dir="i386"
+			zip_arch="i386"
+		;;
+	esac
+}
+
+src_unpack() {
+	default
+
+	local MY_T="${WORKDIR}/HDX_RealTime_Media_Engine_2.9.200_for_Linux$(usex amd64 '_x64' '')"
+	local deb_base_name="citrix-hdx-realtime-media-engine"
+	unpack_deb ${MY_T}/${zip_dir}/${deb_base_name}_$(ver_rs 3 -)_${zip_arch}.deb
+}
+
+src_install() {
+	insinto "${ICAROOT}/rtme"
+
+	# No, we do NOT install such a generic udev rule into the system
+	local destfiles=(
+		DialTone_US.wav
+		EULA.rtf
+		HDXRTME.so
+		InboundCallRing.wav
+	)
+
+	local el
+	for el in "${destfiles[@]}" ; do
+		doins "${el}"
+	done
+	for el in /var/{lib,log}/RTMediaEngineSRV /var/lib/Citrix/HDXRMEP ; do
+		keepdir ${el}
+		fperms a+rw ${el}
+	done
+}
diff --git a/media-plugins/hdx-realtime-media-engine/metadata.xml b/media-plugins/hdx-realtime-media-engine/metadata.xml
new file mode 100644
index 0000000000000..95aa13f6c5ef1
--- /dev/null
+++ b/media-plugins/hdx-realtime-media-engine/metadata.xml
@@ -0,0 +1,8 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>polynomial-c@gentoo.org</email>
+		<name>Lars Wendler</name>
+	</maintainer>
+</pkgmetadata>