diff --git a/app-admin/elektra/Manifest b/app-admin/elektra/Manifest
index 1d0b438526bb9..33752845bd683 100644
--- a/app-admin/elektra/Manifest
+++ b/app-admin/elektra/Manifest
@@ -1 +1,2 @@
 DIST elektra-0.8.16.tar.gz 2405443 BLAKE2B 221f254b240f4f38fb0975749003f8b4c9fbfbd28df2b42b99c8e1fa7795cb4a1565b77cc424b6180abd481326ccab4c8f554749150e36f0ab01146aa72575f8 SHA512 b225e61379907365a423ea75ec7138e5257bb78c526bb05a1ec21f66a52eb4bad9e6f1eb23209d700670b21b86166497b47c3bc46bc9d45f6d366cd544afc326
+DIST elektra-0.8.20.tar.gz 4740032 BLAKE2B e76ad93eadbbec9bb273da4f7bab5622d47deebdab6736c430543159c0754f3b96696954891962b60716d5b969e64bf5ef6886a6239abee8b98888aae09fcdd9 SHA512 11cc88329f84ad4d6337132d76479d26f2d9c12f7a939558a79ea96540129096ea0a26ffda3705c01a2c7c749453588bb1654a4c07cca3374e4076ce768c5848
diff --git a/app-admin/elektra/elektra-0.8.20.ebuild b/app-admin/elektra/elektra-0.8.20.ebuild
new file mode 100644
index 0000000000000..43f955bb844bc
--- /dev/null
+++ b/app-admin/elektra/elektra-0.8.20.ebuild
@@ -0,0 +1,116 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-multilib eutils java-pkg-opt-2
+
+DESCRIPTION="Framework to store config parameters in hierarchical key-value pairs"
+HOMEPAGE="https://www.libelektra.org"
+SRC_URI="https://www.libelektra.org/ftp/elektra/releases/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+PLUGIN_IUSE="augeas iconv ini java simpleini syslog systemd tcl +uname xml yajl";
+IUSE="dbus doc qt5 static-libs test ${PLUGIN_IUSE}"
+
+RDEPEND="dev-libs/libltdl:0[${MULTILIB_USEDEP}]
+	>=dev-libs/libxml2-2.9.1-r4[${MULTILIB_USEDEP}]
+	augeas? ( app-admin/augeas )
+	dbus? ( >=sys-apps/dbus-1.6.18-r1[${MULTILIB_USEDEP}] )
+	iconv? ( >=virtual/libiconv-0-r1[${MULTILIB_USEDEP}] )
+	java? ( >=virtual/jdk-1.8.0 )
+	qt5? (
+		dev-qt/qtdeclarative:5
+		dev-qt/qtgui:5
+		dev-qt/qttest:5
+		dev-qt/qtwidgets:5
+	)
+	uname? ( sys-apps/coreutils )
+	systemd? ( sys-apps/systemd[${MULTILIB_USEDEP}] )
+	yajl? ( >=dev-libs/yajl-1.0.11-r1[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( >=dev-cpp/gtest-1.7.0 )"
+
+DOCS=( README.md doc/AUTHORS doc/CODING.md doc/todo/TODO )
+# tries to write to user's home directory (and doesn't respect HOME)
+RESTRICT="test"
+
+MULTILIB_WRAPPED_HEADERS=( /usr/include/elektra/kdbconfig.h )
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	einfo remove bundled libs
+	# TODO: Remove bundled inih from src/plugins/ini (add to portage):
+	# https://code.google.com/p/inih/
+	rm -rf src/external || die
+
+	# move doc files to correct location
+	sed -e "s/elektra-api/${PF}/" \
+		-i cmake/ElektraCache.cmake || die
+
+	# avoid useless build time, nothing ends up installed
+	cmake_comment_add_subdirectory benchmarks
+	cmake_comment_add_subdirectory examples
+}
+
+multilib_src_configure() {
+	local my_plugins="ALL"
+
+	if multilib_is_native_abi ; then
+		use augeas || my_plugins+=";-augeas"
+		use java || my_plugins+=";-jni"
+	else
+		my_plugins+=";-augeas;-jni"
+	fi
+
+	use dbus      || my_plugins+=";-dbus"
+	use iconv     || my_plugins+=";-iconv"
+	use ini       || my_plugins+=";-ini"		# bundles inih
+	use simpleini || my_plugins+=";-simpleini"
+	use syslog    || my_plugins+=";-syslog"
+	use systemd   || my_plugins+=";-journald"
+	use tcl       || my_plugins+=";-tcl"
+	use uname     || my_plugins+=";-uname"
+	use xml       || my_plugins+=";-xmltool"
+	use yajl      || my_plugins+=";-yajl"
+
+	# Disabling for good (?):
+	# counter - Only useful for debugging the plugin framework
+	# doc - Explaining basic makeup of a function //bug #514402
+	# noresolver - Does not resolve, but can act as one
+	# template - Template for new plugin written in C
+	# wresolver - Resolver for non-POSIX, e.g. w32/w64 systems
+	my_plugins+=";-counter;-doc;-noresolver;-template;-wresolver"
+
+	local my_tools
+
+	if multilib_is_native_abi ; then
+		my_tools="kdb"
+		use qt5 && my_tools+=";qt-gui"
+	fi
+
+	local mycmakeargs=(
+		-DBUILD_PDF=OFF
+		-DBUILD_SHARED=ON
+		-DBUILD_STATIC=$(usex static-libs)
+		-DBUILD_TESTING=$(usex test)
+		-DENABLE_TESTING=$(usex test)
+		-DPLUGINS=${my_plugins}
+		-DTOOLS=${my_tools}
+		-DBUILD_DOCUMENTATION=$(multilib_is_native_abi && usex doc || echo no)
+		-DTARGET_CMAKE_FOLDER=share/cmake/Modules
+	)
+
+	cmake-utils_src_configure
+}
+
+multilib_src_install_all() {
+	einfo remove test_data
+	rm -rvf "${ED%/}/usr/share/${PN}" || die "Failed to remove test_data"
+	einfo remove tool_exec
+	rm -rvf "${ED%/}/usr/$(get_libdir)/${PN}/tool_exec" || die "Failed to remove tool_exec"
+}