diff --git a/games-mud/powwow/powwow-1.2.16-r1.ebuild b/games-mud/powwow/powwow-1.2.16-r1.ebuild
new file mode 100644
index 0000000000000..86654bce6755a
--- /dev/null
+++ b/games-mud/powwow/powwow-1.2.16-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit autotools eutils
+
+DESCRIPTION="PowWow Console MUD Client"
+HOMEPAGE="http://hoopajoo.net/projects/powwow.html"
+SRC_URI="http://hoopajoo.net/static/projects/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+DEPEND="sys-libs/ncurses:0"
+RDEPEND=${DEPEND}
+
+PATCHES=(
+	"${FILESDIR}"/${P}-underlinking.patch
+)
+
+src_prepare() {
+	default
+
+	# note that that the extra, seemingly-redundant files installed are
+	# actually used by in-game help commands
+	sed -i \
+		-e "s/pkgdata_DATA = powwow.doc/pkgdata_DATA = /" \
+		Makefile.am || die
+	mv configure.in configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	econf --includedir=/usr/include
+}
+
+src_install () {
+	DOCS="ChangeLog Config.demo Hacking NEWS powwow.doc powwow.help README.* TODO" \
+		default
+}