-
Notifications
You must be signed in to change notification settings - Fork 1
/
Copy pathdis280.mac
1674 lines (1428 loc) · 24.5 KB
/
dis280.mac
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;**********************************************************************;
; ;
; Simple Z280 disassembler. ;
; Copyright (C) 2020, Hector Peraza. ;
; ;
; Part of this code is based on Luc Rooijakker's generic Z80/Z280 ;
; disassembler written in C language, (C) 1989. ;
; ;
; This program is free software; you can redistribute it and/or ;
; modify it under the terms of the GNU General Public License as ;
; published by the Free Software Foundation; either version 2 of ;
; the License, or (at your option) any later version. ;
; ;
; This program is distributed in the hope that it will be useful, ;
; but WITHOUT ANY WARRANTY; without even the implied warranty of ;
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the ;
; GNU General Public License for more details. ;
; ;
; You should have received a copy of the GNU General Public License ;
; along with this program; if not, write to the Free Software ;
; Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA. ;
; ;
;**********************************************************************;
.Z280
TAB equ 9
cseg
public DIS280
extrn PUTCH,AHEX,HLHEX,GETB,GETAB,GETW,GETADR
;-----------------------------------------------------------------------
; Decode single instruction.
DIS280: xor a
ld (prefix),a ; clear IX/IY prefix
call GETADR
ld (iaddr),hl
dis_op: call GETB ; get next instruction byte
ld (op),a ; save it
ld c,a
rrca
rrca
rrca
and 07h
ld (opshr3),a ; will need this often
ld hl,opcgrp
ld a,c
and 0C0h ; first-level decoding
rlca
rlca
switch: add a,a
add hl,a
ldw hl,(hl)
jp (hl)
opcgrp: dw grp_00 ; LD-16, INC, DEC, ADD-16, JR, etc.
dw grp_40 ; LD-8
dw grp_80 ; CALL, RET, PUSH, POP, etc.
dw grp_C0 ; ADD/SUB/CP-8, logical ops, CALL, RET, etc.
; 00xxxxxx group
grp_00: ld a,(op)
and 7
ld hl,optbl0
jp switch
optbl0: dw op_000 ; JRs, NOP, EXAF
dw op_001 ; LD rp,n16 and ADD HL,rp
dw op_002 ; LD A/HL,(...) and LD (...),A/HL
dw op_003 ; INC/DEC rp
dw op_004 ; INC r8
dw op_005 ; DEC r8
dw op_006 ; LD r8,n8
dw op_007 ; RLCA, RRCA, RLA, RRA, CPL, DAA, SCF, CCF
; 00,10,20,30 and 08,18,28,38: JRs, NOP, EXAF
op_000: ld a,(prefix)
or a ; prefixed instruction?
jr nz,op11 ; branch if yes
ld a,(op)
or a
jr z,opnop
cp 08h
jr z,opexaf
cp 10h
jr z,opdjnz
call outs ; the rest are relative jumps
db 'JR',TAB,0
ld a,(op)
cp 20h ; unconditional relative jump?
jp c,outjrt ; if yes, output target address and return
rrca
rrca
rrca
and 03h
call outcc ; output condition code
ld c,','
call PUTCH
jp outjrt ; output target address
opnop: call outs ; 00 is NOP
db 'NOP',0
ret
opexaf: call outs ; 08 is EX AF,AF'
db 'EX',TAB,'AF,AF''',0
ret
opdjnz: call outs ; 10 is DJNZ
db 'DJNZ',TAB,0
jp outjrt ; output target address
op11: cp 0DDh
jp nz,unknw ; nothing here with FD prefix...
ld a,(op)
ld c,a
and 37h
cp 20h
jp nz,unknw
ld a,c
cp 20h
jr nz,op107
call outs
db 'JAR',TAB,0
jp outjrt
op107: call outs
db 'JAF',TAB,0
jp outjrt
; 01,11,21,31 and 09,19,29,39
op_001: ld a,(op)
and 08h ; ADD HL,rp group?
jr z,op111 ; branch if not, LD rp,n16 group
call outs
db 'ADD',TAB,0
call outihl ; output HL/IX/IY according to prefix
ld c,','
call PUTCH
ld a,(opshr3)
rrca ; op shr 4
and 03h
jp outirp ; output src reg pair
op111: ld a,(prefix)
cp 0FDh ; IX prefix?
jr nz,op112 ; IY prefix used for additional Z280 instr
ld a,(op)
cp 21h ; only LD IX,n16 allowed
jp nz,unknw
op112: call outldw ; 'LDW'
ld a,(opshr3)
rrca ; op shr 4
and 03h
call outxrp
ld c,','
call PUTCH
jp outn16
; 02,12,22,32 and 0A,1A,2A,3A
op_002: ld a,(op)
and 37h
cp 22h ; LD HL,(n16) or LD (n16),HL?
jr nz,op122 ; no, is LD A,(n8) or LD (n8),A
call outldw ; 'LDW'
ld a,(op)
cp 22h ; store?
jr nz,op121 ; no, load
call outi16
ld c,','
call PUTCH
jp outihl
op121: call outihl
ld c,','
call PUTCH
jp outi16
op122: ld a,(prefix)
or a
jp nz,unknw ; can't be prefixed
call outld ; 'LD'
ld a,(opshr3)
ld hl,tbl01
jp otx1
tbl01: db '(BC),A',0
db 'A,(BC)',0
db '(DE),A',0
db 'A,(DE)',0
db 0
db 0
db '(',3,'),A',0 ; 3 = n16
db 'A,(',3,')',0
; 03,13,23,33 and 0B,1B,2B,3B
op_003: ld a,(prefix)
cp 0FDh
ld a,(op)
jr nz,op301
cp 30h
jp nc,unknw ; >= 30h
op301: and 08h
jr z,op303
call outs
db 'DECW',TAB,0
jr op304
op303: call outs
db 'INCW',TAB,0
op304: ld a,(opshr3)
rrca ; op shr 4
and 03h
jp outxrp
; 04,14,24,34 and 0C,1C,2C,3C
op_004: ld a,(prefix)
cp 0FDh
jr nz,op401
ld a,(op)
cp 3Ch
jp z,unknw
op401: call outs
db 'INC',TAB,0
ld a,(opshr3)
jp outxr
; 05,15,25,35 and 0D,1D,2D,3D
op_005: ld a,(prefix)
cp 0FDh
jr nz,op501
ld a,(op)
cp 3Dh
jp z,unknw
op501: call outs
db 'DEC',TAB,0
ld a,(opshr3)
jp outxr
; 06,16,26,36 and 0E,1E,2E,3E
op_006: ld a,(prefix)
cp 0FDh
jr nz,op601
ld a,(op)
cp 3Eh
jp z,unknw
op601: call outld ; 'LD'
ld a,(opshr3)
call outxr
ld c,','
call PUTCH
jp outn8
; 07,17,27,37 and 0F,1F,2F,3F
op_007: ld a,(prefix)
or a
jp nz,unknw
ld a,(opshr3)
ld hl,tbl07
call otx1 ; output instruction from table
ld a,(op)
cp 2Fh ; only CPL has 'A' argument
ret nz
call outs
db TAB,'A',0
ret
tbl07: db 'RLCA',0
db 'RRCA',0
db 'RLA',0
db 'RRA',0
db 'DAA',0
db 'CPL',0
db 'SCF',0
db 'CCF',0
; 01xxxxxx group: 8-bit r-r loads and HALT
grp_40: ld a,(op)
cp 76h ; HALT?
jr nz,op41 ; branch if not
ld a,(prefix)
or a
jp nz,unknw ; can't be prefixed
call outs
db 'HALT',0
ret
op41: ld a,(prefix)
or a
jr z,op42
ld a,(op)
cp 60h
jr c,op420
cp 7Fh
jr nz,op42
op420: and 07h
cp 04h
jp c,unknw
cp 06h+1
jp nc,unknw
op42: call outld ; 'LD'
ld a,(op)
cp 66h
jr z,op421
cp 6Eh
jr nz,op422
op421: ld a,(opshr3)
call outr
jr op423
op422: ld a,(opshr3)
call outir
op423: ld c,','
call PUTCH
ld a,(op)
cp 74h
jr z,op424
cp 75h
jr nz,op425
op424: and 07h
jp outr
op425: cp 78h
jr c,op426
and 07h
jp outxr
op426: and 07h
jp outir
; 10xxxxxx group
grp_80: ld a,(prefix)
cp 0FDh
ld a,(op)
ld e,a
jr nz,op801
and 07h
cp 07h
jp z,unknw
op801: ld a,e
call outop1
ld a,e
call outa ; 'A,'
ld a,e
and 07h
jp outxr
outop1: rrca
rrca
rrca
and 07h
ld hl,optbl1
outop: call otx1
ld c,TAB
jp PUTCH
optbl1: db 'ADD',0
db 'ADC',0
db 'SUB',0
db 'SBC',0
db 'AND',0
db 'XOR',0
db 'OR',0
db 'CP',0
; 11xxxxxx group
grp_C0: ld a,(op)
and 7
ld hl,optbl4
jp switch
optbl4: dw op_CC0
dw op_CC1
dw op_CC2
dw op_CC3
dw op_CC4
dw op_CC5
dw op_CC6
dw op_CC7
op_CC0: ld a,(prefix)
or a
jp nz,unknw
call outs
db 'RET',TAB,0
ld a,(opshr3)
jp outcc ; output condition code
op_CC1: ld a,(op)
ld c,a
and 0EFh
cp 0C9h
jr nz,opc11
ld a,(prefix)
or a
jp nz,unknw
opc11: ld a,c
and 08h
jr z,opc12
ld a,c
cp 0C9h
jr nz,opc13
call outs
db 'RET',0
ret
opc13: ld a,c
cp 0D9h
jr nz,opc14
call outs
db 'EXX',0
ret
opc14: ld a,c
cp 0E9h
jr nz,opc15
call outs
db 'JP',TAB,'(',0
call outihl
ld c,')'
jp PUTCH
opc15: call outldw ; 'LDW'
call outs
db 'SP,',0
jp outihl
opc12: ld a,(prefix)
cp 0FDh
jr nz,opc16
ld a,(op)
cp 0E1h
jp nz,unknw
opc16: call outs
db 'POP',TAB,0
ld a,(opshr3)
rrca ; op shr 4
and 03h
jp outprp
op_CC2: call outs
db 'JP',TAB,0
ld a,(opshr3)
call outcc ; output condition code
ld c,','
call PUTCH
jp outjpt
op_CC3: ld a,(op)
cp 0C3h
jp z,opjmp
cp 0CBh
jp z,dis_CB
cp 0D3h
jp z,opout
cp 0DBh
jp z,opin
cp 0E3h
jp z,opsphl
cp 0EBh
jp z,opxchg
cp 0F3h
jp z,opdi
cp 0FBh
jp z,opei
jp unknw
opjmp: ld a,(prefix)
cp 0DDh
jp z,unknw
call outs
db 'JP',TAB,0
jp outjpt
opout: ld a,(prefix)
or a
jp nz,unknw
call outs
db 'OUT',TAB,'(',0
call outn8
call outs
db '),A',0
ret
opin: ld a,(prefix)
or a
jp nz,unknw
call outs
db 'IN',TAB,'A,(',0
call outn8
ld c,')'
jp PUTCH
opsphl: call outs
db 'EX',TAB,'(SP),',0
jp outihl
opxchg: call outs
db 'EX',TAB,0
ld a,(prefix)
or a
jr nz,opex1
call outs
db 'DE',0
jr opex2
opex1: call outihl
opex2: call outs
db ',HL',0
ret
opdi: ld a,(prefix)
or a
jp nz,unknw
call outs
db 'DI',0
ret
opei: ld a,(prefix)
or a
jp nz,unknw
call outs
db 'EI',0
ret
op_CC4: call outs
db 'CALL',TAB,0
ld a,(opshr3)
call outcc ; output condition code
ld c,','
call PUTCH
jp outjpt
op_CC5: ld a,(op)
ld c,a
and 08h
jr z,opc51
ld a,c
cp 0CDh
jr nz,opc52
call outs
db 'CALL',TAB,0
jp outjpt
opc52: cp 0EDh ; ED?
jp z,dis_ED ; jump to decode ED-instruction
ld a,(prefix)
or a
jp nz,unknw
ld a,c
ld (prefix),a
jp dis_op ; loop back
opc51: ld a,(prefix)
cp 0FDh
jr nz,opc54
ld a,c
cp 0E0h
jp c,unknw
opc54: call outs
db 'PUSH',TAB,0
ld a,(opshr3)
rrca ; op shr 4
and 03h
jp outprp
op_CC6: ld a,(prefix)
or a
jp nz,unknw
ld a,(op)
ld e,a
call outop1
ld a,e
call outa ; 'A,'
jp outn8
op_CC7: ld a,(prefix)
or a
jp nz,unknw
call outs
db 'RST',TAB,0
ld a,(op)
and 38h
jp AHEX
;-----------------------------------------------------------------------
; Decode CB-instruction
dis_CB: ld a,(prefix)
or a ; IX/IY prefixed?
jr nz,dcb1 ; branch if yes
call GETB ; get byte following CB
ld (op),a ; store it
ld c,a
jr dcb2 ; contnue below
dcb1: call GETB ; get displacement
ld (offs),a ; store it
call GETB ; get CB-opcode
ld (op),a
ld c,a
and 07h
cp 6
jp nz,unknw
dcb2: ld a,c
and 0C0h ; bit manipulation opcodes?
jr nz,dcb3 ; branch if yes
ld a,(op) ; else is a rotate or TSET
rrca
rrca
rrca
and 07h
ld hl,tblCB1
call outop ; output instruction name from table
jr dcb4 ; continue below
dcb3: ld a,c
rlca
rlca
and 03h
ld hl,tblCB2
call outop ; output instruction name from table
ld a,(op)
rrca
rrca
rrca
and 07h
add a,'0'
ld c,a
call PUTCH ; output bit number
ld c,','
call PUTCH
dcb4: ld a,(prefix)
or a ; IX/IY prefixed?
jr nz,dcb5 ; branch if yes
ld a,(op)
and 07h
jp outr ; else output register operand
dcb5: ld c,'('
call PUTCH
call outihl ; output index reg name
ld a,(offs)
call disp8 ; output displacement
ld c,')'
jp PUTCH
tblCB1: db 'RLC',0
db 'RRC',0
db 'RL',0
db 'RR',0
db 'SLA',0
db 'SRA',0
db 'TSET',0
db 'SRL',0
tblCB2: db 0
db 'BIT',0
db 'RES',0
db 'SET',0
;-----------------------------------------------------------------------
; Decode ED-instruction
dis_ED: call GETB ; get byte following ED
ld (op),a ; store it
ld c,a
rrca
rrca
rrca
and 07h
ld (opshr3),a ; will need this often below
ld a,c
rlca
rlca
and 03h
ld hl,edgrp
jp switch ; process by group
edgrp: dw ed_00
dw ed_40
dw ed_80
dw ed_C0
; 00xxxxxx
ed_00: ld a,(op)
and 07h
ld hl,edgrp0
jp switch
edgrp0: dw unknw
dw unknw
dw ed02 ; LDA
dw ed03 ; LD store with extended addressing
dw ed04 ; LDW load with extended addressing
dw ed05 ; LDW store with extended addressing
dw ed06 ; LDW (HL)
dw ed07 ; EX A,...
ed02: call outs
db 'LDA',TAB,0
call outihl
ld c,','
call PUTCH
ld a,(opshr3)
jp outea
ed03: ld a,(prefix)
or a
jp nz,unknw ; can't be prefixed
call outld ; 'LD'
ld a,(opshr3)
call outea
call outs
db ',A',0
ret
ed04: call outldw ; 'LDW'
call outihl
ld c,','
call PUTCH
ld a,(opshr3)
jp outea
ed05: call outldw ; 'LDW'
ld a,(opshr3)
call outea
ld c,','
call PUTCH
jp outihl
ed06: ld a,(op)
and 08h
jr z,ed601
call outldw ; 'LDW (HL),...'
call outm
ld c,','
call PUTCH
ld a,(opshr3)
rrca ; op shr 4
and 03h
jp outrp
ed601: call outldw ; 'LDW ...,(HL)'
ld a,(opshr3)
rrca
and 03h ; op shr 4
call outrp
ld c,','
call PUTCH
jp outm
ed07: ld a,(prefix)
cp 0FDh
jr nz,ed701
ld a,(op)
cp 3Fh
jp z,unknw
ed701: call outs
db 'EX',TAB,'A,',0
ld a,(opshr3)
jp outxr
; 01xxxxxx
ed_40: ld a,(op)
and 07h
ld hl,edgrp4
jp switch
edgrp4: dw ed40 ; TSTI, IN
dw ed41 ; SC, OUT
dw ed42 ; ADC, SBC
dw ed43 ; LDW
dw ed44 ; NEG, EXTS
dw ed45 ; ADD HL,A, RETI, RETN, RETIL, PCACHE
dw ed46 ; IM, LDCTL
dw ed47 ; LD I&R, EI/DI, RRD, RLD
ed40: ld a,(op)
cp 70h
jr nz,ed401
ld a,(prefix)
or a
jp nz,unknw
call outs
db 'TSTI',TAB,'(C)',0
ret
ed401: ld a,(prefix)
cp 0FDh
jr nz,ed402
ld a,(op)
cp 78h
jp z,unknw
ed402: call outs
db 'IN',TAB,0
ld a,(opshr3)
call outxr
call outs
db ',(C)',0
ret
ed41: ld a,(op)
cp 71h
jr nz,ed411
ld a,(prefix)
or a
jp nz,unknw
call outs
db 'SC',TAB,0
jp outn16
ed411: ld a,(prefix)
cp 0FDh
jr nz,ed412
ld a,(op)
cp 79h
jp z,unknw
ed412: call outs
db 'OUT',TAB,'(C),',0
ld a,(opshr3)
jp outxr
ed42: ld a,(op)
and 08h
jr z,ed421
call outs
db 'ADC',TAB,0
jr ed422
ed421: call outs
db 'SBC',TAB,0
ed422: call outihl
ld c,','
call PUTCH
ld a,(opshr3)
rrca ; op shr 4
and 03h
jp outirp
ed43: ld a,(prefix)
or a
jp nz,unknw
ld a,(op)
and 0F7h
cp 63h
jp z,unknw
ld a,(op)
and 08h
jr z,ed431
call outldw ; 'LDW'
ld a,(opshr3)
rrca ; op shr 4
and 03h
ld c,a
call outrp
ld c,','
call PUTCH
jp outi16
ed431: call outldw ; 'LDW'
call outi16
ld c,','
call PUTCH
ld a,(opshr3)
rrca ; op shr 4
and 03h
ld c,a
jp outrp
ed44: ld a,(prefix)
or a
jp nz,unknw
ld a,(op)
cp 44h ; NEG A
jr z,edneg1
cp 4Ch ; NEG HL
jr z,edneg2
cp 64h ; EXTS A
jr z,edexs1
cp 6Ch ; EXTS HL
jr z,edexs2
jp unknw
edneg1: call outs
db 'NEG',TAB,'A',0
ret
edneg2: call outs
db 'NEG',TAB,'HL',0
ret
edexs1: call outs
db 'EXTS',TAB,'A',0
ret
edexs2: call outs
db 'EXTS',TAB,'HL',0
ret
ed45: ld a,(op)
cp 6Dh
jr nz,ed451
call outs
db 'ADD',TAB,0
call outihl
call outs
db ',A',0
ret
ed451: ld a,(prefix)
or a
jp nz,unknw
ld a,(opshr3)
cp 3
jr c,ed452
dec a ; make PCACHE = 03 to keep table short
cp 4
jp nc,unknw
ed452: ld hl,tbl45
jp outop
tbl45: db 'RETN',0
db 'RETI',0
db 'RETIL',0
db 'PCACHE',0
ed46: ld a,(prefix)
or a
jr nz,ed461
ld a,(op)
cp 60h
jr nc,ed461
call outs
db 'IM',TAB,0
ld a,(opshr3)
and 03h
ld hl,imtbl
add hl,a
ld c,(hl)
jp PUTCH
imtbl: db '0312'
ed461: ld a,(op)
cp 66h
jr nz,ed462
call outldc ; 'LDCTL'
call outihl
call outs
db ',(C)',0
ret
ed462: cp 6Eh
jp nz,unknw
call outldc ; 'LDCTL'
call outs
db '(C),',0
jp outihl
ed47: ld a,(prefix)
or a
jp nz,unknw