diff --git a/dev-python/automat/Manifest b/dev-python/automat/Manifest
new file mode 100644
index 0000000000000..6edae925f264e
--- /dev/null
+++ b/dev-python/automat/Manifest
@@ -0,0 +1 @@
+DIST Automat-0.5.0.tar.gz 32599 SHA256 4889ec6763377432ec4db265ad552bbe956768ea3fff39014855308ba79dd7c2 SHA512 7b4fc64e1b3cc514e3513c4be7387309a9e0c6d59ef091131404642b517a324b4a0eb677bee99da038664bd6713f2d2078c621f056e98b35966caf324741eeeb WHIRLPOOL 5d3d258cb0eae2393edd4b12860b4312522c4a0eff7c17724ecf13032b633e1803b3817bd095f5e24a680d6d006ea4a389bd038022ac21376ba4e969e3bc4200
diff --git a/dev-python/automat/automat-0.5.0.ebuild b/dev-python/automat/automat-0.5.0.ebuild
new file mode 100644
index 0000000000000..667cc866282d6
--- /dev/null
+++ b/dev-python/automat/automat-0.5.0.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} pypy)
+
+inherit distutils-r1
+
+MYPN="Automat"
+MYP="${MYPN}-${PV}"
+
+DESCRIPTION="Self-service finite-state machines for the programmer on the go"
+HOMEPAGE="https://github.com/glyph/automat https://pypi.python.org/pypi/Automat"
+SRC_URI="mirror://pypi/${MYPN:0:1}/${MYPN}/${MYP}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="examples test"
+
+RDEPEND="
+	dev-python/attrs[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+"
+DEPEND="
+	${RDEPEND}
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]
+	dev-python/m2r[${PYTHON_USEDEP}]
+	test? ( dev-python/pytest[${PYTHON_USEDEP}] )
+"
+
+S=${WORKDIR}/${MYP}
+
+python_test() {
+	PYTHONPATH="${S}/test:${BUILD_DIR}/lib" py.test -v || die "Tests failed under ${EPYTHON}"
+}
+
+src_install() {
+	if use examples; then
+		docinto examples
+		dodoc docs/examples/*.py
+	fi
+	distutils-r1_src_install
+}
+
+pkg_postinst() {
+	einfo "For additional visualization functionality install these optional dependencies"
+	einfo "    >=dev-python/twisted-16.1.1"
+	einfo "    media-gfx/graphviz[python]"
+}
diff --git a/dev-python/automat/metadata.xml b/dev-python/automat/metadata.xml
new file mode 100644
index 0000000000000..1b291a9ad5be6
--- /dev/null
+++ b/dev-python/automat/metadata.xml
@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>dolsen@gentoo.org</email>
+		<description>Primary maintainer</description>
+	</maintainer>
+	<upstream>
+		<maintainer>
+			<email>glyph@twistedmatrix.com</email>
+			<name>Glyph</name>
+		</maintainer>
+		<remote-id type="pypi">Automat</remote-id>
+	</upstream>
+	<longdescription>
+		Automat is a library for concise, idiomatic Python expression of
+		finite-state automata (particularly deterministic finite-state
+		transducers).
+	</longdescription>
+</pkgmetadata>