From 320787d23a876fdb01eb84ce46baac1b6054288b Mon Sep 17 00:00:00 2001
From: Marek Szuba <marecki@gentoo.org>
Date: Mon, 10 Jul 2023 23:24:18 +0100
Subject: [PATCH] mail-mta/msmtp: add 1.8.24

Signed-off-by: Marek Szuba <marecki@gentoo.org>
---
 mail-mta/msmtp/Manifest            |   1 +
 mail-mta/msmtp/msmtp-1.8.24.ebuild | 143 +++++++++++++++++++++++++++++
 2 files changed, 144 insertions(+)
 create mode 100644 mail-mta/msmtp/msmtp-1.8.24.ebuild

diff --git a/mail-mta/msmtp/Manifest b/mail-mta/msmtp/Manifest
index b8d65d24b3c9c..24f30a703154d 100644
--- a/mail-mta/msmtp/Manifest
+++ b/mail-mta/msmtp/Manifest
@@ -1 +1,2 @@
 DIST msmtp-1.8.23.tar.xz 401656 BLAKE2B 7033c7e8ad74826ab233bd9b08b8db8e17f6c9bd4cc9f6e65890099e4e12445f4665acc2faf1468f5d6f5e16a53c2479d5a0144e39d65c0521436832c1a049c5 SHA512 69675cb539fa5c78b83e90a460e8215e56b1d0fa7a18729eb058b8d51414d13b88fbcdb2092767e7e96c325a143230ac09e041ea74d068bf267e508418cf674a
+DIST msmtp-1.8.24.tar.xz 409268 BLAKE2B 1661dffbdf9418665dfea3eacdcb716a27ea0916024247ccc221d0f6c3da0076f9bc3b822e9f0c152185f08b8d929268f8eaf63489304225d200a093fcff9d46 SHA512 9bcd1431bd27a74cea931da0e89adfdc53b5be027cef4a735e2fdaba3aed38408b4a266960b51a4071664b88b1af4545a3df5acf64b9ab8ce84000c49a8286ff
diff --git a/mail-mta/msmtp/msmtp-1.8.24.ebuild b/mail-mta/msmtp/msmtp-1.8.24.ebuild
new file mode 100644
index 0000000000000..f8f460e9df26b
--- /dev/null
+++ b/mail-mta/msmtp/msmtp-1.8.24.ebuild
@@ -0,0 +1,143 @@
+# Copyright 2004-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit fcaps
+
+DESCRIPTION="An SMTP client and SMTP plugin for mail user agents such as Mutt"
+HOMEPAGE="https://marlam.de/msmtp/"
+SRC_URI="https://marlam.de/msmtp/releases/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="daemon doc keyring +gnutls idn +mta nls sasl ssl"
+
+# fcaps.eclass unconditionally defines "filecaps" USE flag which we need for
+# USE="daemon" in order to set the caps we need.
+REQUIRED_USE="daemon? ( filecaps )"
+
+# Upstream discourages usage of openssl. See also
+# https://marlam.de/msmtp/news/openssl-discouraged/
+DEPEND="
+	keyring? ( app-crypt/libsecret )
+	idn? ( net-dns/libidn2:= )
+	nls? ( virtual/libintl )
+	sasl? ( net-misc/gsasl[client] )
+	ssl? (
+		gnutls? ( net-libs/gnutls[idn?] )
+		!gnutls? ( dev-libs/libretls:= )
+	)
+"
+
+RDEPEND="${DEPEND}
+	net-mail/mailbase
+	daemon? (
+		acct-group/msmtpd
+		acct-user/msmtpd
+	)
+	mta? (
+		!mail-mta/courier
+		!mail-mta/esmtp
+		!mail-mta/exim
+		!mail-mta/netqmail
+		!mail-mta/nullmailer
+		!mail-mta/postfix
+		!mail-mta/sendmail
+		!mail-mta/opensmtpd
+		!>=mail-mta/ssmtp-2.64-r2[mta]
+	)
+"
+
+BDEPEND="
+	doc? ( virtual/texi2dvi )
+	nls? ( sys-devel/gettext )
+	virtual/pkgconfig
+"
+
+DOCS="AUTHORS ChangeLog NEWS README THANKS doc/msmtprc*"
+
+src_prepare() {
+	# Use default Gentoo location for mail aliases
+	sed 's:/etc/aliases:/etc/mail/aliases:' \
+		-i scripts/find_alias/find_alias_for_msmtp.sh || die
+
+	default
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-gai-idn
+		$(use_enable nls)
+		$(use_with daemon msmtpd)
+		$(use_with keyring libsecret)
+		$(use_with idn libidn)
+		$(use_with sasl libgsasl)
+		$(use_with ssl tls $(usex gnutls gnutls libtls))
+	)
+	econf "${myeconfargs[@]}"
+}
+
+src_compile() {
+	default
+
+	if use doc ; then
+		cd doc || die
+		emake html pdf
+	fi
+}
+
+src_install() {
+	default
+
+	if use daemon ; then
+		fcaps CAP_NET_BIND_SERVICE usr/bin/msmtpd
+		newinitd "${FILESDIR}"/msmtpd.init msmtpd
+		newconfd "${FILESDIR}"/msmtpd.confd msmtpd
+	fi
+
+	if use doc ; then
+		dodoc doc/msmtp.{html,pdf}
+	fi
+
+	if use mta ; then
+		dosym ../bin/msmtp /usr/sbin/sendmail
+		dosym ../bin/msmtp /usr/$(get_libdir)/sendmail
+	fi
+
+	insinto /usr/share/vim/vimfiles/syntax
+	doins scripts/vim/msmtp.vim
+
+	insinto /etc
+	newins doc/msmtprc-system.example msmtprc
+
+	src_install_contrib find_alias find_alias_for_msmtp.sh
+	src_install_contrib msmtpqueue "*.sh" "README ChangeLog"
+	src_install_contrib msmtpq "msmtpq msmtp-queue" README.msmtpq
+	src_install_contrib set_sendmail set_sendmail.sh set_sendmail.conf
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]]; then
+		einfo "Please edit ${EROOT}/etc/msmtprc before first use."
+		einfo "In addition, per user configuration files can be placed"
+		einfo "as '~/.msmtprc'.  See the msmtprc-user.example file under"
+		einfo "/usr/share/doc/${PF}/ for an example."
+	fi
+}
+
+src_install_contrib() {
+	subdir="$1"
+	bins="$2"
+	docs="$3"
+	local dir=/usr/share/${PN}/${subdir}
+	insinto ${dir}
+	exeinto ${dir}
+	for i in ${bins} ; do
+		doexe scripts/${subdir}/${i}
+	done
+	for i in ${docs} ; do
+		newdoc scripts/${subdir}/${i} ${subdir}.${i}
+	done
+}