From 699adbfffec109afdebd68b1997bef7f0f11ac4d Mon Sep 17 00:00:00 2001
From: Mart Raudsepp <leio@gentoo.org>
Date: Mon, 17 Sep 2018 23:29:45 +0300
Subject: [PATCH] media-libs/gst-plugins-base: bump to 1.14.3 for upstream bug
 fixes

Two revisions (broken automagic graphene dep in -r0), because otherwise the
deptree would be broken for many slow architectures necessitating de-keywording
of ALL gstreamer plugin packages on 1.14.3 bumps..

Bug: https://bugs.gentoo.org/662458
Package-Manager: Portage-2.3.49, Repoman-2.3.10
---
 media-libs/gst-plugins-base/Manifest          |   1 +
 .../gst-plugins-base-1.14.3-r1.ebuild         | 181 ++++++++++++++++++
 .../gst-plugins-base-1.14.3.ebuild            | 181 ++++++++++++++++++
 .../gst-plugins-cdparanoia-1.14.3.ebuild      |  19 ++
 .../gst-plugins-libvisual-1.14.3.ebuild       |  25 +++
 5 files changed, 407 insertions(+)
 create mode 100644 media-libs/gst-plugins-base/gst-plugins-base-1.14.3-r1.ebuild
 create mode 100644 media-libs/gst-plugins-base/gst-plugins-base-1.14.3.ebuild
 create mode 100644 media-plugins/gst-plugins-cdparanoia/gst-plugins-cdparanoia-1.14.3.ebuild
 create mode 100644 media-plugins/gst-plugins-libvisual/gst-plugins-libvisual-1.14.3.ebuild

diff --git a/media-libs/gst-plugins-base/Manifest b/media-libs/gst-plugins-base/Manifest
index ae29113787eec..dd1463a62081a 100644
--- a/media-libs/gst-plugins-base/Manifest
+++ b/media-libs/gst-plugins-base/Manifest
@@ -2,3 +2,4 @@ DIST gst-plugins-base-0.10.36.tar.xz 2364108 BLAKE2B a71ef5d5c7462d60937602681c0
 DIST gst-plugins-base-1.12.4.tar.xz 3119468 BLAKE2B d5ac157618a25c8f0323d1922d5b26b0b5c49f56cb75df3ceeadd0566f873be1a06c863a1da6afff40901fbbbeb1ec6cd6ef4614309ca7f7ff988c0fa9040a10 SHA512 89a6e92cd294612cf1406eb156416ab4606643f6b43637e64a18f6f28ab789ca8d4cf1308434ed85e5fc679c79cc3ca115db48f37e0065a6ab3cdfdbaaad9f53
 DIST gst-plugins-base-1.14.1.tar.xz 3689184 BLAKE2B 17abcab2c84b113180de55d6c781ae11feec66c215febfffefe4a22353c56e82a585647688e2078603b6c3ece6f26afa99969091a72886880a2f8549dd9cb379 SHA512 bca9db8780fe24c19a2c4eae9a16dc0856cb38077580e4344bd4f7fa9a7a03079b92556ff35475a574f624a5a721d80ef925790670e4cc809361ed01108a141e
 DIST gst-plugins-base-1.14.2.tar.xz 3693856 BLAKE2B 7ed05718bfd1dcb15e05e5a2c8758ad409c4ad7f331146363f264aaf7123c8a14c1db81f482710d1069d33e5281087f66e2e38504e39b214befba73ffdd9295c SHA512 35e7eb5c42fe265d38c433575f88d3306f15ff927a989eb375ed5399cbf92af2e9bf553d6eee349dc13673540cee00e1f879595f25e58c188ea443d8a969682f
+DIST gst-plugins-base-1.14.3.tar.xz 3702184 BLAKE2B 8b13cdcb912968ed51bba91faf70060cced562f374d2b6987a9b9ff9a261b553836394cc4dc16df299c21cb303fd87bb0becb57225767c3502c8c16359430523 SHA512 3b5f0dc46d148dd9f162c651594be740f798c1d6272ecabced544f09900b6f2909a9fc705d42e4e98130d6f7cb1368458bfeee27444b5c43e62551defbc3838a
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-1.14.3-r1.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-1.14.3-r1.ebuild
new file mode 100644
index 0000000000000..73db5954b48b3
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-1.14.3-r1.ebuild
@@ -0,0 +1,181 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-base"
+
+inherit flag-o-matic gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~amd64 ~arm ~ppc64 ~sparc ~x86"
+
+# For OpenGL we have three separate concepts, with a list of possibilities in each:
+#  * opengl APIs - opengl and/or gles2; USE=opengl and USE=gles2 enable these accordingly; if neither is enabled, OpenGL helper library and elements are not built at all and all the other options aren't relevant
+#  * opengl platforms - glx and/or egl; also cgl, wgl, eagl for non-linux; USE="X opengl" enables glx platform; USE="egl" enables egl platform. Rest is up for relevant prefix teams.
+#  * opengl windowing system - x11, wayland, win32, cocoa, android, viv_fb, gbm and/or dispmanx; USE=X enables x11 (but for WSI it's automagic - FIXME), USE=wayland enables wayland, USE=gbm enables gbm (automagic upstream - FIXME); rest is up for relevant prefix/arch teams/contributors to test and provide patches
+# With the following limitations:
+#  * If opengl and/or gles2 is enabled, a platform has to be enabled - x11 or egl in our case, but x11 (glx) is acceptable only with opengl
+#  * If opengl and/or gles2 is enabled, a windowing system has to be enabled - x11, wayland or gbm in our case
+#  * glx platform requires opengl API
+#  * wayland, gbm and most other non-glx WSIs require egl platform
+# Additionally there is optional dmabuf support with egl for additional dmabuf based upload/download/eglimage options;
+#  and optional graphene usage for gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader;
+#  and libpng/jpeg are required for gloverlay element;
+
+# Keep default IUSE options for relevant ones mirrored with gst-plugins-gtk and gst-plugins-bad
+IUSE="alsa +egl gbm gles2 +introspection ivorbis +ogg +opengl +orc +pango theora +vorbis wayland +X"
+GL_REQUIRED_USE="
+	|| ( gbm wayland X )
+	wayland? ( egl )
+	gbm? ( egl )
+"
+REQUIRED_USE="
+	ivorbis? ( ogg )
+	theora? ( ogg )
+	vorbis? ( ogg )
+	opengl? ( || ( egl X ) ${GL_REQUIRED_USE} )
+	gles2? ( egl ${GL_REQUIRED_USE} )
+"
+
+# Dependencies needed by opengl library and plugin (enabled via USE gles2 and/or opengl)
+# dmabuf automagic from libdrm headers (drm_fourcc.h) and EGL, so ensure it with USE=egl (platform independent header used only, thus no MULTILIB_USEDEP); provides dmabuf based upload/download/eglimage options
+GL_DEPS="
+	>=media-libs/mesa-9.0[egl?,gbm?,gles2?,wayland?,${MULTILIB_USEDEP}]
+	egl? (
+		x11-libs/libdrm
+	)
+	gbm? (
+		>=dev-libs/libgudev-147[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
+	)
+	wayland? (
+		dev-libs/wayland[${MULTILIB_USEDEP}]
+	)
+
+	>=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
+	media-libs/libpng:0[${MULTILIB_USEDEP}]
+	virtual/jpeg:0[${MULTILIB_USEDEP}]
+" # graphene for optional gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader; libpng/jpeg for gloverlay element
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:1.0[introspection?,${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+	ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+	ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.24[${MULTILIB_USEDEP}] )
+	pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
+	theora? ( >=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}] )
+	vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}]
+	)
+
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+
+	!<media-libs/gst-plugins-bad-1.13.1:1.0
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.12
+	X? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	# Disable GL tests for now; prone to fail with EGL_NOT_INITIALIZED, etc
+	sed -i -e '/^@USE_GL_TRUE@/d' tests/check/Makefile.in
+	default
+}
+
+multilib_src_configure() {
+	filter-flags -mno-sse -mno-sse2 -mno-sse4.1 #610340
+
+	local myconf=()
+	# FIXME: Automagic gbm and x11 wsi
+	if use opengl || use gles2; then
+		myconf+=(
+			--enable-gl
+			$(use_enable egl)
+			$(use_enable gles2)
+			$(use_enable opengl)
+			$(use_enable wayland)
+			$(use_enable X x11)
+		)
+	else
+		myconf+=(
+			--disable-gl
+			--disable-egl
+			--disable-gles2
+			--disable-opengl
+			--disable-wayland
+			--disable-x11
+		)
+	fi
+
+	if use opengl && use X; then
+		# GLX requires desktop OpenGL and X
+		myconf+=( --enable-glx )
+	else
+		myconf+=( --disable-glx )
+	fi
+
+	myconf+=(
+		--disable-cocoa
+		--disable-dispmanx
+		--disable-wgl
+	)
+
+	gstreamer_multilib_src_configure \
+		$(use_enable alsa) \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable ivorbis) \
+		$(use_enable ogg) \
+		$(use_enable orc) \
+		$(use_enable pango) \
+		$(use_enable theora) \
+		$(use_enable vorbis) \
+		$(use_enable X x) \
+		$(use_enable X xshm) \
+		$(use_enable X xvideo) \
+		--enable-iso-codes \
+		--enable-zlib \
+		--disable-debug \
+		--disable-examples \
+		--disable-static \
+		"${myconf[@]}"
+
+	# bug #366931, flag-o-matic for the whole thing is overkill
+	if [[ ${CHOST} == *86-*-darwin* ]] ; then
+		sed -i \
+			-e '/FLAGS = /s|-O[23]|-O1|g' \
+			gst/audioconvert/Makefile \
+			gst/volume/Makefile || die
+	fi
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS NEWS README RELEASE"
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}
+
+multilib_src_test() {
+	unset GSETTINGS_BACKEND
+	emake check
+}
diff --git a/media-libs/gst-plugins-base/gst-plugins-base-1.14.3.ebuild b/media-libs/gst-plugins-base/gst-plugins-base-1.14.3.ebuild
new file mode 100644
index 0000000000000..8ba7028264981
--- /dev/null
+++ b/media-libs/gst-plugins-base/gst-plugins-base-1.14.3.ebuild
@@ -0,0 +1,181 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE="gst-plugins-base"
+
+inherit flag-o-matic gstreamer
+
+DESCRIPTION="Basepack of plugins for gstreamer"
+HOMEPAGE="https://gstreamer.freedesktop.org/"
+
+LICENSE="GPL-2+ LGPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+
+# For OpenGL we have three separate concepts, with a list of possibilities in each:
+#  * opengl APIs - opengl and/or gles2; USE=opengl and USE=gles2 enable these accordingly; if neither is enabled, OpenGL helper library and elements are not built at all and all the other options aren't relevant
+#  * opengl platforms - glx and/or egl; also cgl, wgl, eagl for non-linux; USE="X opengl" enables glx platform; USE="egl" enables egl platform. Rest is up for relevant prefix teams.
+#  * opengl windowing system - x11, wayland, win32, cocoa, android, viv_fb, gbm and/or dispmanx; USE=X enables x11 (but for WSI it's automagic - FIXME), USE=wayland enables wayland, USE=gbm enables gbm (automagic upstream - FIXME); rest is up for relevant prefix/arch teams/contributors to test and provide patches
+# With the following limitations:
+#  * If opengl and/or gles2 is enabled, a platform has to be enabled - x11 or egl in our case, but x11 (glx) is acceptable only with opengl
+#  * If opengl and/or gles2 is enabled, a windowing system has to be enabled - x11, wayland or gbm in our case
+#  * glx platform requires opengl API
+#  * wayland, gbm and most other non-glx WSIs require egl platform
+# Additionally there is optional dmabuf support with egl for additional dmabuf based upload/download/eglimage options;
+#  and optional graphene usage for gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader;
+#  and libpng/jpeg are required for gloverlay element;
+
+# Keep default IUSE options for relevant ones mirrored with gst-plugins-gtk and gst-plugins-bad
+IUSE="alsa +egl gbm gles2 +introspection ivorbis +ogg +opengl +orc +pango theora +vorbis wayland +X"
+GL_REQUIRED_USE="
+	|| ( gbm wayland X )
+	wayland? ( egl )
+	gbm? ( egl )
+"
+REQUIRED_USE="
+	ivorbis? ( ogg )
+	theora? ( ogg )
+	vorbis? ( ogg )
+	opengl? ( || ( egl X ) ${GL_REQUIRED_USE} )
+	gles2? ( egl ${GL_REQUIRED_USE} )
+"
+
+# Dependencies needed by opengl library and plugin (enabled via USE gles2 and/or opengl)
+# dmabuf automagic from libdrm headers (drm_fourcc.h) and EGL, so ensure it with USE=egl (platform independent header used only, thus no MULTILIB_USEDEP); provides dmabuf based upload/download/eglimage options
+GL_DEPS="
+	>=media-libs/mesa-9.0[egl?,gbm?,gles2?,wayland?,${MULTILIB_USEDEP}]
+	egl? (
+		x11-libs/libdrm
+	)
+	gbm? (
+		>=dev-libs/libgudev-147[${MULTILIB_USEDEP}]
+		>=x11-libs/libdrm-2.4.55[${MULTILIB_USEDEP}]
+	)
+	wayland? (
+		dev-libs/wayland[${MULTILIB_USEDEP}]
+	)
+
+	media-libs/libpng:0[${MULTILIB_USEDEP}]
+	virtual/jpeg:0[${MULTILIB_USEDEP}]
+" # graphene for optional gltransformation and glvideoflip elements and more GLSL Uniforms support in glshader; libpng/jpeg for gloverlay element
+# >=media-libs/graphene-1.4.0[${MULTILIB_USEDEP}]
+
+RDEPEND="
+	app-text/iso-codes
+	>=dev-libs/glib-2.40.0:2[${MULTILIB_USEDEP}]
+	>=media-libs/gstreamer-${PV}:1.0[introspection?,${MULTILIB_USEDEP}]
+	>=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}]
+	alsa? ( >=media-libs/alsa-lib-1.0.27.2[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.31.1:= )
+	ivorbis? ( >=media-libs/tremor-0_pre20130223[${MULTILIB_USEDEP}] )
+	ogg? ( >=media-libs/libogg-1.3.0[${MULTILIB_USEDEP}] )
+	orc? ( >=dev-lang/orc-0.4.24[${MULTILIB_USEDEP}] )
+	pango? ( >=x11-libs/pango-1.36.3[${MULTILIB_USEDEP}] )
+	theora? ( >=media-libs/libtheora-1.1.1[encode,${MULTILIB_USEDEP}] )
+	vorbis? ( >=media-libs/libvorbis-1.3.3-r1[${MULTILIB_USEDEP}] )
+	X? (
+		>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXext-1.3.2[${MULTILIB_USEDEP}]
+		>=x11-libs/libXv-1.0.10[${MULTILIB_USEDEP}]
+	)
+
+	gles2? ( ${GL_DEPS} )
+	opengl? ( ${GL_DEPS} )
+
+	!<media-libs/gst-plugins-bad-1.13.1:1.0
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.12
+	X? ( x11-base/xorg-proto )
+"
+
+src_prepare() {
+	# Disable GL tests for now; prone to fail with EGL_NOT_INITIALIZED, etc
+	sed -i -e '/^@USE_GL_TRUE@/d' tests/check/Makefile.in
+	default
+}
+
+multilib_src_configure() {
+	filter-flags -mno-sse -mno-sse2 -mno-sse4.1 #610340
+
+	local myconf=()
+	# FIXME: Automagic gbm and x11 wsi
+	if use opengl || use gles2; then
+		myconf+=(
+			--enable-gl
+			$(use_enable egl)
+			$(use_enable gles2)
+			$(use_enable opengl)
+			$(use_enable wayland)
+			$(use_enable X x11)
+		)
+	else
+		myconf+=(
+			--disable-gl
+			--disable-egl
+			--disable-gles2
+			--disable-opengl
+			--disable-wayland
+			--disable-x11
+		)
+	fi
+
+	if use opengl && use X; then
+		# GLX requires desktop OpenGL and X
+		myconf+=( --enable-glx )
+	else
+		myconf+=( --disable-glx )
+	fi
+
+	myconf+=(
+		--disable-cocoa
+		--disable-dispmanx
+		--disable-wgl
+	)
+
+	gstreamer_multilib_src_configure \
+		$(use_enable alsa) \
+		$(multilib_native_use_enable introspection) \
+		$(use_enable ivorbis) \
+		$(use_enable ogg) \
+		$(use_enable orc) \
+		$(use_enable pango) \
+		$(use_enable theora) \
+		$(use_enable vorbis) \
+		$(use_enable X x) \
+		$(use_enable X xshm) \
+		$(use_enable X xvideo) \
+		--enable-iso-codes \
+		--enable-zlib \
+		--disable-debug \
+		--disable-examples \
+		--disable-static \
+		"${myconf[@]}"
+
+	# bug #366931, flag-o-matic for the whole thing is overkill
+	if [[ ${CHOST} == *86-*-darwin* ]] ; then
+		sed -i \
+			-e '/FLAGS = /s|-O[23]|-O1|g' \
+			gst/audioconvert/Makefile \
+			gst/volume/Makefile || die
+	fi
+
+	if multilib_is_native_abi; then
+		local x
+		for x in libs plugins; do
+			ln -s "${S}"/docs/${x}/html docs/${x}/html || die
+		done
+	fi
+}
+
+multilib_src_install_all() {
+	DOCS="AUTHORS NEWS README RELEASE"
+	einstalldocs
+	find "${ED}" -name '*.la' -delete || die
+}
+
+multilib_src_test() {
+	unset GSETTINGS_BACKEND
+	emake check
+}
diff --git a/media-plugins/gst-plugins-cdparanoia/gst-plugins-cdparanoia-1.14.3.ebuild b/media-plugins/gst-plugins-cdparanoia/gst-plugins-cdparanoia-1.14.3.ebuild
new file mode 100644
index 0000000000000..8d994bf79a2bd
--- /dev/null
+++ b/media-plugins/gst-plugins-cdparanoia/gst-plugins-cdparanoia-1.14.3.ebuild
@@ -0,0 +1,19 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE=gst-plugins-base
+
+inherit gstreamer
+
+DESCRIPTION="CD Audio Source (cdda) plugin for GStreamer"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE=""
+
+RDEPEND=">=media-sound/cdparanoia-3.10.2-r6[${MULTILIB_USEDEP}]"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	gstreamer_system_link gst-libs/gst/audio:gstreamer-audio
+}
diff --git a/media-plugins/gst-plugins-libvisual/gst-plugins-libvisual-1.14.3.ebuild b/media-plugins/gst-plugins-libvisual/gst-plugins-libvisual-1.14.3.ebuild
new file mode 100644
index 0000000000000..bba6db422d23f
--- /dev/null
+++ b/media-plugins/gst-plugins-libvisual/gst-plugins-libvisual-1.14.3.ebuild
@@ -0,0 +1,25 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GST_ORG_MODULE=gst-plugins-base
+
+inherit gstreamer
+
+DESCRIPTION="Visualization elements for GStreamer"
+KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd"
+IUSE=""
+
+RDEPEND="
+	>=media-libs/libvisual-0.4.0-r3[${MULTILIB_USEDEP}]
+	>=media-plugins/libvisual-plugins-0.4.0-r3[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	gstreamer_system_link \
+		gst-libs/gst/audio:gstreamer-audio \
+		gst-libs/gst/video:gstreamer-video \
+		gst-libs/gst/pbutils:gstreamer-pbutils
+}