From 7775430083ccb27c764bf599c5134b7e5130a54d Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Wed, 18 Apr 2018 10:52:54 +0200
Subject: [PATCH] app-text/poppler: Bump to version 0.64.0

Package-Manager: Portage-2.3.30, Repoman-2.3.9
---
 app-text/poppler/Manifest              |   1 +
 app-text/poppler/poppler-0.64.0.ebuild | 126 +++++++++++++++++++++++++
 2 files changed, 127 insertions(+)
 create mode 100644 app-text/poppler/poppler-0.64.0.ebuild

diff --git a/app-text/poppler/Manifest b/app-text/poppler/Manifest
index 2a44f3b9a7f37..ae0ba4d847f75 100644
--- a/app-text/poppler/Manifest
+++ b/app-text/poppler/Manifest
@@ -1,2 +1,3 @@
 DIST poppler-0.62.0.tar.xz 1423372 BLAKE2B 01c8745d0c1fa5b412ec92295a8784f5c1deff8b9fa709d09a3236d630f78fecc6af23fe3302964478d6356562712726db422ef51fe59a8b42e13e08370a77ac SHA512 91f7eae7b05965ae97a34e658bed2a676be8a6e4d34f82148ece6eb58932632dcf9a34d50c66412f93f560ce575abf5c608ed6b1e5184604b96024801886c706
 DIST poppler-0.63.0.tar.xz 1439552 BLAKE2B 9bf5cff7f5fec93ec7d49d1745aadb2b03a68d38216003e4bff54a5d264c9dda10265da79a755af1f31b582602d034cfefb16b807185d674a2cfe0d20e5de277 SHA512 a151d08480e9940a02191355ef5e7499d6494cff05f22f49de2bb8223512f5e5c9bb9b33651943ded30b4cd7096a2423fb7a01fa62228fbcd1d3a221b885cfe9
+DIST poppler-0.64.0.tar.xz 1449904 BLAKE2B 260bcc9c1b109b58b66057665d11c0685b525803206497ad0516998d93c132befd6b0ae28f187afd77dace6b35af6c08b8210ad05143d6d068109dc57caf5a4a SHA512 2799c3f628e63803eb11a25e54798a136aad91ea843d4bc1fb284af478f4a8cde87b7f95fc28cf23baf25975fbde6ca93f6ac91befb87af42e642c7650053f1c
diff --git a/app-text/poppler/poppler-0.64.0.ebuild b/app-text/poppler/poppler-0.64.0.ebuild
new file mode 100644
index 0000000000000..13fd0a3103db1
--- /dev/null
+++ b/app-text/poppler/poppler-0.64.0.ebuild
@@ -0,0 +1,126 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils flag-o-matic toolchain-funcs xdg-utils
+
+if [[ "${PV}" == "9999" ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://anongit.freedesktop.org/git/poppler/poppler.git"
+	SLOT="0/9999"
+else
+	SRC_URI="https://poppler.freedesktop.org/${P}.tar.xz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+	SLOT="0/75"   # CHECK THIS WHEN BUMPING!!! SUBSLOT IS libpoppler.so SOVERSION
+fi
+
+DESCRIPTION="PDF rendering library based on the xpdf-3.0 code base"
+HOMEPAGE="https://poppler.freedesktop.org/"
+
+LICENSE="GPL-2"
+IUSE="cairo cjk curl cxx debug doc +introspection +jpeg +jpeg2k +lcms nss png qt5 tiff +utils"
+
+# No test data provided
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=media-libs/fontconfig-2.6.0
+	>=media-libs/freetype-2.3.9
+	sys-libs/zlib
+	cairo? (
+		dev-libs/glib:2
+		>=x11-libs/cairo-1.10.0
+		introspection? ( >=dev-libs/gobject-introspection-1.32.1:= )
+	)
+	curl? ( net-misc/curl )
+	jpeg? ( virtual/jpeg:0 )
+	jpeg2k? ( media-libs/openjpeg:2= )
+	lcms? ( media-libs/lcms:2 )
+	nss? ( >=dev-libs/nss-3.19:0 )
+	png? ( media-libs/libpng:0= )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtxml:5
+	)
+	tiff? ( media-libs/tiff:0 )
+"
+DEPEND="${COMMON_DEPEND}
+	virtual/pkgconfig
+"
+RDEPEND="${COMMON_DEPEND}
+	cjk? ( >=app-text/poppler-data-0.4.7 )
+"
+
+DOCS=(AUTHORS NEWS README README-XPDF)
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.60.1-qt5-dependencies.patch"
+	"${FILESDIR}/${PN}-0.28.1-fix-multilib-configuration.patch"
+	"${FILESDIR}/${PN}-0.61.0-respect-cflags.patch"
+	"${FILESDIR}/${PN}-0.62.0-openjpeg2.patch"
+	"${FILESDIR}/${PN}-0.57.0-disable-internal-jpx.patch"
+)
+
+src_prepare() {
+	cmake-utils_src_prepare
+
+	# Clang doesn't grok this flag, the configure nicely tests that, but
+	# cmake just uses it, so remove it if we use clang
+	if [[ ${CC} == clang ]] ; then
+		sed -i -e 's/-fno-check-new//' cmake/modules/PopplerMacros.cmake || die
+	fi
+
+	if ! grep -Fq 'cmake_policy(SET CMP0002 OLD)' CMakeLists.txt ; then
+		sed '/^cmake_minimum_required/acmake_policy(SET CMP0002 OLD)' \
+			-i CMakeLists.txt || die
+	else
+		einfo "policy(SET CMP0002 OLD) - workaround can be removed"
+	fi
+
+	# we need to up the C++ version, bug #622526, #643278
+	append-cxxflags -std=c++11
+}
+
+src_configure() {
+	xdg_environment_reset
+	local mycmakeargs=(
+		-DBUILD_GTK_TESTS=OFF
+		-DBUILD_QT5_TESTS=OFF
+		-DBUILD_CPP_TESTS=OFF
+		-DENABLE_SPLASH=ON
+		-DENABLE_ZLIB=ON
+		-DENABLE_ZLIB_UNCOMPRESS=OFF
+		-DENABLE_XPDF_HEADERS=ON
+		-DSPLASH_CMYK=OFF
+		-DUSE_FIXEDPOINT=OFF
+		-DUSE_FLOAT=OFF
+		-DWITH_Cairo=$(usex cairo)
+		-DENABLE_LIBCURL=$(usex curl)
+		-DENABLE_CPP=$(usex cxx)
+		-DWITH_GObjectIntrospection=$(usex introspection)
+		-DWITH_JPEG=$(usex jpeg)
+		-DENABLE_DCTDECODER=$(usex jpeg libjpeg none)
+		-DENABLE_LIBOPENJPEG=$(usex jpeg2k openjpeg2 none)
+		-DENABLE_CMS=$(usex lcms lcms2 none)
+		-DWITH_NSS3=$(usex nss)
+		-DWITH_PNG=$(usex png)
+		$(cmake-utils_use_find_package qt5 Qt5Core)
+		-DWITH_TIFF=$(usex tiff)
+		-DENABLE_UTILS=$(usex utils)
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	# live version doesn't provide html documentation
+	if use cairo && use doc && [[ ${PV} != 9999 ]]; then
+		# For now install gtk-doc there
+		insinto /usr/share/gtk-doc/html/poppler
+		doins -r "${S}"/glib/reference/html/*
+	fi
+}