From 7c9166030fb8ecdcea47f759a72520ebbc9f0c38 Mon Sep 17 00:00:00 2001
From: =?UTF-8?q?Micha=C5=82=20G=C3=B3rny?= <mgorny@gentoo.org>
Date: Sat, 15 Jul 2023 03:47:46 +0200
Subject: [PATCH] dev-python/pikepdf: Bump to 8.1.1
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pikepdf/Manifest             |  1 +
 dev-python/pikepdf/pikepdf-8.1.1.ebuild | 60 +++++++++++++++++++++++++
 2 files changed, 61 insertions(+)
 create mode 100644 dev-python/pikepdf/pikepdf-8.1.1.ebuild

diff --git a/dev-python/pikepdf/Manifest b/dev-python/pikepdf/Manifest
index 006433c283db2..0012e0fdee542 100644
--- a/dev-python/pikepdf/Manifest
+++ b/dev-python/pikepdf/Manifest
@@ -1 +1,2 @@
 DIST pikepdf-7.2.0.tar.gz 2913496 BLAKE2B 6992b9e64e7bd718fb09c5cd3eb77937c802bb07b24b72bb0825ec721137ee1211f9f7bbc3d8141b60e0ece1f71e6d9d36b50153377b3475f30d7aac3c8f2181 SHA512 96759f36e3f019d6cba775541e7338e774d61cb71c464e42625b1b6c98b8babf5fc9d9324dc6375257897a130d7fe5facdd7a1ddaec6662c8b088854e01fc97e
+DIST pikepdf-8.1.1.tar.gz 1804397 BLAKE2B c9e990558e761f8597b5519b935a96503ae685747de26b987c91db44b5c3772af993691c4ea0696b0eb54a4ea8d02395724153a0f714738c446049f2b664394e SHA512 7152137e9c11d402095d6aa06e8aa99eade71b35aeb85c9bd5d5811bd3aa785e51792e9ede08110e101893daabbace6d6aef68fa475f2a89e98b5d4de5d2f5bb
diff --git a/dev-python/pikepdf/pikepdf-8.1.1.ebuild b/dev-python/pikepdf/pikepdf-8.1.1.ebuild
new file mode 100644
index 0000000000000..7cd819dbbf606
--- /dev/null
+++ b/dev-python/pikepdf/pikepdf-8.1.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..11} pypy3 )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="Python library to work with pdf files based on qpdf"
+HOMEPAGE="
+	https://github.com/pikepdf/pikepdf/
+	https://pypi.org/project/pikepdf/
+"
+
+LICENSE="MPL-2.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+DEPEND="
+	>=app-text/qpdf-11.1.1:0=
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/deprecation[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+	>=dev-python/pillow-9.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pybind11-2.10.1[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
+		>=dev-python/hypothesis-6.36[${PYTHON_USEDEP}]
+		>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
+		>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
+		>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-2.1.0[${PYTHON_USEDEP}]
+		>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
+		>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			dev-python/tomli[${PYTHON_USEDEP}]
+		' 3.{8..10})
+	)
+"
+
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# fragile to system load
+	tests/test_image_access.py::test_random_image
+)
+
+src_prepare() {
+	sed -e '/-n auto/d' -i pyproject.toml || die
+	distutils-r1_src_prepare
+}