From 8369eb1b8d3e87675061923b85e3fc110edfd1ec Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Fri, 19 Mar 2021 02:12:50 +0000
Subject: [PATCH] dev-libs/libindicator: update EAPI 5 -> 7 in :3

Signed-off-by: Sam James <sam@gentoo.org>
---
 .../libindicator-12.10.1-r301.ebuild          | 39 ++++++++++++-------
 1 file changed, 25 insertions(+), 14 deletions(-)

diff --git a/dev-libs/libindicator/libindicator-12.10.1-r301.ebuild b/dev-libs/libindicator/libindicator-12.10.1-r301.ebuild
index 068768b22c0fa..2b6dd20a0cb2f 100644
--- a/dev-libs/libindicator/libindicator-12.10.1-r301.ebuild
+++ b/dev-libs/libindicator/libindicator-12.10.1-r301.ebuild
@@ -1,8 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit autotools eutils flag-o-matic ltprune virtualx multilib-minimal
+EAPI=7
+
+inherit autotools flag-o-matic virtualx multilib-minimal
 
 DESCRIPTION="A set of symbols and convience functions that all indicators would like to use"
 HOMEPAGE="https://launchpad.net/libindicator"
@@ -14,32 +15,41 @@ KEYWORDS="~alpha amd64 ~arm arm64 ~ia64 ~ppc64 x86"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
-RDEPEND=">=dev-libs/glib-2.22[${MULTILIB_USEDEP}]
-	>=x11-libs/gtk+-3.2:3[${MULTILIB_USEDEP}]"
-DEPEND="${RDEPEND}
+RDEPEND="
+	>=dev-libs/glib-2.22[${MULTILIB_USEDEP}]
+	>=x11-libs/gtk+-3.2:3[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
 	dev-util/glib-utils
 	virtual/pkgconfig
 	test? ( dev-util/dbus-test-runner )"
 
-src_prepare() {
+PATCHES=(
 	# https://bugs.launchpad.net/libindicator/+bug/1502925
-	epatch "${FILESDIR}"/${PN}-ldflags-spacing.patch
+	"${FILESDIR}"/${PN}-ldflags-spacing.patch
+)
+
+src_prepare() {
+	default
+
 	eautoreconf
 }
 
 multilib_src_configure() {
 	append-flags -Wno-error
 
-	myconf=(
+	local myconf=(
 		--disable-static
 		--with-gtk=3
 	)
-	local ECONF_SOURCE=${S}
-	econf "${myconf[@]}"
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
 }
 
 multilib_src_test() {
-	Xemake check #391179
+	# bug #391179
+	Xemake check
 }
 
 multilib_src_install() {
@@ -47,6 +57,7 @@ multilib_src_install() {
 }
 
 multilib_src_install_all() {
-	einstalldocs
-	prune_libtool_files --all
+	default
+
+	find "${ED}" -name '*.la' -delete || die
 }