From a48d9e2e519f6db172dc5b0d8b3364993ba19b0f Mon Sep 17 00:00:00 2001
From: Patrice Clement <monsieurp@gentoo.org>
Date: Sat, 17 Oct 2015 11:07:25 +0000
Subject: [PATCH] dev-java/bcprov: Set SLOT back to 1.50. Fixes bug 563272.

Package-Manager: portage-2.2.20.1
Signed-off-by: Patrice Clement <monsieurp@gentoo.org>
---
 dev-java/bcprov/bcprov-1.50-r4.ebuild | 62 +++++++++++++++++++++++++++
 1 file changed, 62 insertions(+)
 create mode 100644 dev-java/bcprov/bcprov-1.50-r4.ebuild

diff --git a/dev-java/bcprov/bcprov-1.50-r4.ebuild b/dev-java/bcprov/bcprov-1.50-r4.ebuild
new file mode 100644
index 0000000000000..d2a0a1c564498
--- /dev/null
+++ b/dev-java/bcprov/bcprov-1.50-r4.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-pkg-simple
+
+MY_P="${PN}-jdk15on-${PV/./}"
+
+DESCRIPTION="Java cryptography APIs"
+HOMEPAGE="http://www.bouncycastle.org/java.html"
+SRC_URI="http://www.bouncycastle.org/download/${MY_P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="1.50"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~x64-macos"
+
+DEPEND=">=virtual/jdk-1.6
+	app-arch/unzip"
+
+RDEPEND=">=virtual/jre-1.6"
+
+S="${WORKDIR}/${MY_P}"
+
+JAVA_ENCODING="ISO-8859-1"
+
+# Package can't be built with test as bcprov and bcpkix can't be built with test.
+RESTRICT="test"
+
+src_unpack() {
+	default
+	cd "${S}"
+	unpack ./src.zip
+}
+
+java_prepare() {
+	if ! use test; then
+		# There are too many files to delete so we won't be using JAVA_RM_FILES
+		# (it produces a lot of output).
+		local RM_TEST_FILES=()
+		while read -d $'\0' -r file; do
+			RM_TEST_FILES+=("${file}")
+		done < <(find . -name "*Test*.java" -type f -print0)
+		while read -d $'\0' -r file; do
+			RM_TEST_FILES+=("${file}")
+		done < <(find . -name "*Mock*.java" -type f -print0)
+
+		rm -v "${RM_TEST_FILES[@]}" || die
+	fi
+}
+
+src_compile() {
+	java-pkg-simple_src_compile
+}
+
+src_install() {
+	java-pkg-simple_src_install
+	use source && java-pkg_dosrc org
+}