From b716b81e568e8d4481092074dd55f16f2e943d22 Mon Sep 17 00:00:00 2001
From: Guillermo Joandet <gjoandet@gmail.com>
Date: Sat, 7 Jan 2023 11:45:17 -0300
Subject: [PATCH] gnome-extra/evolution-ews: Version bump to 3.46.3

Signed-off-by: Guillermo Joandet <gjoandet@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/29003
Signed-off-by: Matt Turner <mattst88@gentoo.org>
---
 gnome-extra/evolution-ews/Manifest            |  1 +
 .../evolution-ews/evolution-ews-3.46.3.ebuild | 72 +++++++++++++++++++
 2 files changed, 73 insertions(+)
 create mode 100644 gnome-extra/evolution-ews/evolution-ews-3.46.3.ebuild

diff --git a/gnome-extra/evolution-ews/Manifest b/gnome-extra/evolution-ews/Manifest
index 9a2e84ce80b0f..ccacad3794461 100644
--- a/gnome-extra/evolution-ews/Manifest
+++ b/gnome-extra/evolution-ews/Manifest
@@ -1 +1,2 @@
 DIST evolution-ews-3.46.2.tar.xz 694936 BLAKE2B 548fdcaf0e0b9964bbb8b854a7aa7cd83f52195ddf6d9ba70b35ef9ea6f6c7606a967f3a3eece36bf7af3ecc3d7d2dfb8e6a701a6c18e85fe2523c8a3f04fea8 SHA512 dd669b8d562849d588f88dd40f981e0401a046cb5489b00894082b04462fadc43581dadb0eee87077b63998a32e80cb66ae9a5c0de99c7079bb5cbc5aa8c37bd
+DIST evolution-ews-3.46.3.tar.xz 695152 BLAKE2B 2c76f5d5769c6ac610cf8ad2cb55a78374e82793ca6fde838b263759b10f9aa5bb033171001db6a18d5cd2f45744673c063a714f755613c92537e56272683303 SHA512 99259661568fee71898b29a445e87ee110c356a98e3e415d6c2f44e7f9b6f1216b87fd9772c4a006ffde49058dfae594d31ead43ed85fb0c34925f530f8d9495
diff --git a/gnome-extra/evolution-ews/evolution-ews-3.46.3.ebuild b/gnome-extra/evolution-ews/evolution-ews-3.46.3.ebuild
new file mode 100644
index 0000000000000..675ec4ff7d00a
--- /dev/null
+++ b/gnome-extra/evolution-ews/evolution-ews-3.46.3.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake gnome2 optfeature
+
+DESCRIPTION="Evolution module for connecting to Microsoft Exchange Web Services"
+HOMEPAGE="https://wiki.gnome.org/Apps/Evolution https://gitlab.gnome.org/GNOME/evolution-ews"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~riscv ~x86"
+IUSE="test"
+
+# libical-glib currently (2020-02-29) oddly behind USE=introspection
+RDEPEND="
+	dev-db/sqlite:3
+	>=dev-libs/glib-2.68:2
+	>=dev-libs/libical-3.0.5:0=[introspection(-)]
+	>=dev-libs/json-glib-1.0.4
+	>=dev-libs/libmspack-0.4
+	dev-libs/libxml2:2
+	>=gnome-extra/evolution-data-server-${PV}:0=
+	>=mail-client/evolution-${PV}:2.0
+	>=net-libs/libsoup-3.0:3.0
+	>=x11-libs/gtk+-3.10:3
+"
+DEPEND="${RDEPEND}
+	test? ( >=net-libs/uhttpmock-0.9:1.0 )
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=dev-util/intltool-0.35.5
+	>=sys-devel/gettext-0.18.3
+	virtual/pkgconfig
+"
+
+# Unittests fail to find libevolution-ews.so
+RESTRICT="test !test? ( test )"
+
+# global scope PATCHES or DOCS array mustn't be used due to double default_src_prepare
+# call; if needed, set them after cmake_src_prepare call, if that works
+src_prepare() {
+	cmake_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITH_MSPACK=ON
+		-DENABLE_TESTS=$(usex test)
+	)
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+}
+
+src_test() {
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+}
+
+pkg_postinst() {
+	optfeature "oauth support" gnome-extra/evolution-data-server[oauth]
+}