diff --git a/kde-plasma/plasma-firewall/Manifest b/kde-plasma/plasma-firewall/Manifest
index e58f755968614..788aa383ef1b1 100644
--- a/kde-plasma/plasma-firewall/Manifest
+++ b/kde-plasma/plasma-firewall/Manifest
@@ -1,2 +1,3 @@
 DIST plasma-firewall-5.27.11.tar.xz 362988 BLAKE2B 484e853f4a8c61823e2a235fe5d5e40b6861c04044ca5058b8e866d9a9d9cb072b8a64c2c1b8a950f1604acc85dd27c38314735db2b6e4f59e8fb9085eda0ea8 SHA512 9c6a41448ef83a1c464e1e10441ae811bc898afc451b821fbd46141df4ffe1ad395692c420ce02dd5618197a307fa2729dbe8f0f703c1a64b14068f6c018ba7b
 DIST plasma-firewall-6.1.4.tar.xz 373820 BLAKE2B 8a876ab313192094d3da622fa66c3d149bf80f673f7ee27b13dc54b5a00b4a127e9d1e9cc133b5001806f43f81f1aa231f461c853046d722a314da0924ab8a9c SHA512 f685c378184a177237158db2cd3a14fc7e4806af60e28b93d5e7932dc18bb26538a5415891b6b562e79deff17d7929dc7673e9a0088f1591c0654b9937d6e94a
+DIST plasma-firewall-6.1.5.tar.xz 373904 BLAKE2B 46a7e73c8b16dc031a75754ee58ef2b790dd43543571b8ea5cb65c7175d0e2f6671167043e107ed535591d6d64f1b295ebf8e6fc60cd5f5bb5104d11914cd193 SHA512 3b3e63b7c5516e7e0775577fe272fb800fdcb125310181c74aa0e2499c62eccdf8f313d136dadb87bc9abd0c014a5dfc26337e3910aa7bafbf548f302e12d78e
diff --git a/kde-plasma/plasma-firewall/plasma-firewall-6.1.5.ebuild b/kde-plasma/plasma-firewall/plasma-firewall-6.1.5.ebuild
new file mode 100644
index 0000000000000..88450aae88aa2
--- /dev/null
+++ b/kde-plasma/plasma-firewall/plasma-firewall-6.1.5.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+PYTHON_COMPAT=( python3_{10..12} )
+KFMIN=6.5.0
+QTMIN=6.7.2
+inherit ecm plasma.kde.org python-single-r1
+
+DESCRIPTION="Plasma frontend for Firewalld or UFW"
+HOMEPAGE="https://invent.kde.org/network/plasma-firewall"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="firewalld +ufw"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE} || ( firewalld ufw )"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,xml]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+"
+RDEPEND="${DEPEND}
+	${PYTHON_DEPS}
+	firewalld? ( net-firewall/firewalld )
+	ufw? ( net-firewall/ufw )
+"
+BDEPEND=">=kde-frameworks/kcmutils-${KFMIN}:6"
+
+src_prepare() {
+	ecm_src_prepare
+	# this kind of cmake magic doesn't work for us at all.
+	sed -e "1 s:^.*$:\#\!/usr/bin/env ${EPYTHON}:" \
+		-i kcm/backends/ufw/helper/kcm_ufw_helper.py.cmake || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_FIREWALLD_BACKEND=$(usex firewalld)
+		-DBUILD_UFW_BACKEND=$(usex ufw)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst () {
+	ecm_pkg_postinst
+
+	if ! has_version sys-apps/systemd; then
+		ewarn "${PN} is not functional without sys-apps/systemd at this point."
+		ewarn "See also: https://bugs.gentoo.org/778527"
+	fi
+}