From f4db9e070d5e0e476b5b4a66a84776ae9f104c13 Mon Sep 17 00:00:00 2001
From: Lars Wendler <polynomial-c@gentoo.org>
Date: Wed, 8 Mar 2017 11:41:25 +0100
Subject: [PATCH] media-libs/harfbuzz: Bump to version 1.4.4

Package-Manager: Portage-2.3.4, Repoman-2.3.2
---
 media-libs/harfbuzz/Manifest              |   1 +
 media-libs/harfbuzz/harfbuzz-1.4.4.ebuild | 101 ++++++++++++++++++++++
 2 files changed, 102 insertions(+)
 create mode 100644 media-libs/harfbuzz/harfbuzz-1.4.4.ebuild

diff --git a/media-libs/harfbuzz/Manifest b/media-libs/harfbuzz/Manifest
index 567328770235c..3ca5b3b910fca 100644
--- a/media-libs/harfbuzz/Manifest
+++ b/media-libs/harfbuzz/Manifest
@@ -2,3 +2,4 @@ DIST harfbuzz-1.3.1.tar.bz2 1358437 SHA256 a242206dd119d5e6cc1b2253c116abbae03f9
 DIST harfbuzz-1.3.4.tar.bz2 1408308 SHA256 718aa6fcadef1a6548315b8cfe42cc27e926256302c337f42df3a443843f6a2b SHA512 72027ce64d735f1f7ecabcc78ba426d6155cebd564439feb77cefdfc28b00bfd9f6314e6735addaa90cee1d98cf6d2c0b61f77b446ba34e11f7eb7cdfdcd386a WHIRLPOOL 998c7255dc2a67e40c9872434a3c73e0133fb70d7423772286c485c4cf97c56578d922bc68e934dec64e88d2a6b35ef91e5aae39373cbd941aa4990b94abc387
 DIST harfbuzz-1.4.2.tar.bz2 1446752 SHA256 8f234dcfab000fdec24d43674fffa2fdbdbd654eb176afbde30e8826339cb7b3 SHA512 80c06e17f7e2ca4ac847c77489f02b3b6f7bf6fde54194c5d4a47e893db7d1e75bfb0350ce50829c6ae0520202e35ad1711110c09c8d2a9497c0622f000f3357 WHIRLPOOL bccb0cdc89155dc1f4c9eafda7d055f5e009e81a95abc480aeb32161e6b603f487ebd5aba43e8303c3cff86ba4c8ca0fdec73cfb5aaa32ae1f922b58d024ddbe
 DIST harfbuzz-1.4.3.tar.bz2 1470967 SHA256 838c17400a88a3a451eb401573ef94cdd50919730d98255547c459fef1d85321 SHA512 d80efc65054ef7310441a0f49961fb8df1ca569c9ab12bd4a36255863b896021b1c1516455e38b011fb2871b5428bd285dfca884e263d976937bee16e515124c WHIRLPOOL 299a01ce9189843dc5bc5de87e1081e2f2eb929d31d7740f7ed88889604ecf7f7a8976ceeae2206ca170f4deab191b848345c515b30a2e14c60446825f7fc084
+DIST harfbuzz-1.4.4.tar.bz2 1480766 SHA256 35d2f8ca476cbbec64ee824eca6b0209ff8db0334990b9f5af893b94f119d255 SHA512 2ea0a971ed150598a6e8f48173e60b9bc539d698b34891a2668a34449be286c6790ed47b604cb82406187e8701ed040d01934ffc028970fd460855e2887bf238 WHIRLPOOL fa48edbd747a23ae87e6984b1f52744eaff636d7f7e516e47dc869a13c28fc7a21b37b31445594b972c1aa6e5c12e228cf947ffd0328175dae71c2dce25b9e0a
diff --git a/media-libs/harfbuzz/harfbuzz-1.4.4.ebuild b/media-libs/harfbuzz/harfbuzz-1.4.4.ebuild
new file mode 100644
index 0000000000000..c46b2a1d717ef
--- /dev/null
+++ b/media-libs/harfbuzz/harfbuzz-1.4.4.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+EGIT_REPO_URI="git://anongit.freedesktop.org/harfbuzz"
+[[ ${PV} == 9999 ]] && inherit git-r3 autotools
+
+PYTHON_COMPAT=( python2_7 )
+
+inherit eutils libtool multilib-minimal python-any-r1 xdg-utils
+
+DESCRIPTION="An OpenType text shaping engine"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/HarfBuzz"
+[[ ${PV} == 9999 ]] || SRC_URI="https://www.freedesktop.org/software/${PN}/release/${P}.tar.bz2"
+
+LICENSE="Old-MIT ISC icu"
+SLOT="0/0.9.18" # 0.9.18 introduced the harfbuzz-icu split; bug #472416
+[[ ${PV} == 9999 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris"
+
+IUSE="+cairo fontconfig +glib +graphite icu +introspection static-libs test +truetype"
+REQUIRED_USE="introspection? ( glib )"
+
+RDEPEND="
+	cairo? ( x11-libs/cairo:= )
+	fontconfig? ( media-libs/fontconfig:1.0[${MULTILIB_USEDEP}] )
+	glib? ( >=dev-libs/glib-2.38:2[${MULTILIB_USEDEP}] )
+	graphite? ( >=media-gfx/graphite2-1.2.1:=[${MULTILIB_USEDEP}] )
+	icu? ( >=dev-libs/icu-51.2-r1:=[${MULTILIB_USEDEP}] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34:= )
+	truetype? ( >=media-libs/freetype-2.5.0.1:2=[${MULTILIB_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	virtual/pkgconfig
+	test? ( ${PYTHON_DEPS} )
+"
+# eautoreconf requires gobject-introspection-common
+# ragel needed if regenerating *.hh files from *.rl
+[[ ${PV} = 9999 ]] && DEPEND="${DEPEND}
+	>=dev-libs/gobject-introspection-common-1.34
+	dev-util/ragel
+"
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+
+	xdg_environment_reset
+
+	if [[ ${CHOST} == *-darwin* || ${CHOST} == *-solaris* ]] ; then
+		# on Darwin/Solaris we need to link with g++, like automake defaults
+		# to, but overridden by upstream because on Linux this is not
+		# necessary, bug #449126
+		sed -i \
+			-e 's/\<LINK\>/CXXLINK/' \
+			src/Makefile.am || die
+		sed -i \
+			-e '/libharfbuzz_la_LINK = /s/\<LINK\>/CXXLINK/' \
+			src/Makefile.in || die
+		sed -i \
+			-e '/AM_V_CCLD/s/\<LINK\>/CXXLINK/' \
+			test/api/Makefile.in || die
+	fi
+
+	[[ ${PV} == 9999 ]] && eautoreconf
+	elibtoolize # for Solaris
+
+	# failing test, https://bugs.freedesktop.org/show_bug.cgi?id=89190
+	sed -e 's#tests/arabic-fallback-shaping.tests##' -i test/shaping/Makefile.in || die "sed failed"
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" \
+	# harfbuzz-gobject only used for instrospection, bug #535852
+	econf \
+		--without-coretext \
+		--without-uniscribe \
+		$(use_enable static-libs static) \
+		$(multilib_native_use_with cairo) \
+		$(use_with fontconfig) \
+		$(use_with glib) \
+		$(use_with introspection gobject) \
+		$(use_with graphite graphite2) \
+		$(use_with icu) \
+		$(multilib_native_use_enable introspection) \
+		$(use_with truetype freetype)
+
+	if multilib_is_native_abi; then
+		ln -s "${S}"/docs/html docs/html || die
+	fi
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files --modules
+}