add a way to work with config.fish

[rafaScalet]

I think it would be really cool to have an approach where plugins are declared in config.fish, like in fundle. I really like Fisher because it feels more organized than fundle, but I also find fundle's functionality of declaring plugins in config.fish very useful - so much so that I even implemented my own solution to make this work.

if status --is-interactive
  if not functions -q fisher
    curl -sL https://git.io/fisher | source && fisher install jorgebucaran/fisher > /dev/null
    fisher update > /dev/null
  end
end

function @plugin; set -g plugins $plugins (string lower $argv[1]); end

@plugin jorgebucaran/fisher
@plugin jorgebucaran/autopair.fish
@plugin jorgebucaran/replay.fish
@plugin rafascalet/docker-db.fish
@plugin rafascalet/let-prompt.fish
@plugin jhillyerd/plugin-git
@plugin nickeb96/puffer-fish
@plugin gazorby/fish-abbreviation-tips

function plugins --argument-names command
  set -g installed_plugins (fisher ls)

  switch $command
    case "install" "i" "add"
      install_plugins
    case "uninstall" "rm" "remove"
      remove_plugins
    case "update" "up" "upgrade" "init"
      update_plugins
  end
end

function install_plugins
  # Instalar plugins ausentes
  for plugin in $plugins
    if not contains $plugin $installed_plugins
      fisher install $plugin | head -n 3 | tail -n 1 | string replace "Installing" (set_color normal)"Installing"(set_color green)
    end
  end
end

function remove_plugins
  # Remover plugins que não estão mais na lista
  for installed_plugin in $installed_plugins
    if not contains $installed_plugin $plugins
      fisher remove $installed_plugin | grep 'Removing' --color=never
    end
  end
end

function update_plugins
  install_plugins
  remove_plugins
end

Do you think it would be nice to have this functionality natively in Fisher?

[jorgebucaran]

Adding this functionality to Fisher could introduce unexpected complications, but I'm not entirely against the idea. That said, I personally lean against it. Fisher was and is still intended to be used primarily interactively, which is in the spirit of Fish (the friendly interactive shell).