forked from biotrump/OouraFFT
-
Notifications
You must be signed in to change notification settings - Fork 0
/
fft4g.f
1240 lines (1240 loc) · 37.4 KB
/
fft4g.f
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
! Fast Fourier/Cosine/Sine Transform
! dimension :one
! data length :power of 2
! decimation :frequency
! radix :4, 2
! data :inplace
! table :use
! subroutines
! cdft: Complex Discrete Fourier Transform
! rdft: Real Discrete Fourier Transform
! ddct: Discrete Cosine Transform
! ddst: Discrete Sine Transform
! dfct: Cosine Transform of RDFT (Real Symmetric DFT)
! dfst: Sine Transform of RDFT (Real Anti-symmetric DFT)
!
!
! -------- Complex DFT (Discrete Fourier Transform) --------
! [definition]
! <case1>
! X(k) = sum_j=0^n-1 x(j)*exp(2*pi*i*j*k/n), 0<=k<n
! <case2>
! X(k) = sum_j=0^n-1 x(j)*exp(-2*pi*i*j*k/n), 0<=k<n
! (notes: sum_j=0^n-1 is a summation from j=0 to n-1)
! [usage]
! <case1>
! ip(0) = 0 ! first time only
! call cdft(2*n, 1, a, ip, w)
! <case2>
! ip(0) = 0 ! first time only
! call cdft(2*n, -1, a, ip, w)
! [parameters]
! 2*n :data length (integer)
! n >= 1, n = power of 2
! a(0:2*n-1) :input/output data (real*8)
! input data
! a(2*j) = Re(x(j)),
! a(2*j+1) = Im(x(j)), 0<=j<n
! output data
! a(2*k) = Re(X(k)),
! a(2*k+1) = Im(X(k)), 0<=k<n
! ip(0:*) :work area for bit reversal (integer)
! length of ip >= 2+sqrt(n)
! strictly,
! length of ip >=
! 2+2**(int(log(n+0.5)/log(2.0))/2).
! ip(0),ip(1) are pointers of the cos/sin table.
! w(0:n/2-1) :cos/sin table (real*8)
! w(),ip() are initialized if ip(0) = 0.
! [remark]
! Inverse of
! call cdft(2*n, -1, a, ip, w)
! is
! call cdft(2*n, 1, a, ip, w)
! do j = 0, 2 * n - 1
! a(j) = a(j) / n
! end do
! .
!
!
! -------- Real DFT / Inverse of Real DFT --------
! [definition]
! <case1> RDFT
! R(k) = sum_j=0^n-1 a(j)*cos(2*pi*j*k/n), 0<=k<=n/2
! I(k) = sum_j=0^n-1 a(j)*sin(2*pi*j*k/n), 0<k<n/2
! <case2> IRDFT (excluding scale)
! a(k) = (R(0) + R(n/2)*cos(pi*k))/2 +
! sum_j=1^n/2-1 R(j)*cos(2*pi*j*k/n) +
! sum_j=1^n/2-1 I(j)*sin(2*pi*j*k/n), 0<=k<n
! [usage]
! <case1>
! ip(0) = 0 ! first time only
! call rdft(n, 1, a, ip, w)
! <case2>
! ip(0) = 0 ! first time only
! call rdft(n, -1, a, ip, w)
! [parameters]
! n :data length (integer)
! n >= 2, n = power of 2
! a(0:n-1) :input/output data (real*8)
! <case1>
! output data
! a(2*k) = R(k), 0<=k<n/2
! a(2*k+1) = I(k), 0<k<n/2
! a(1) = R(n/2)
! <case2>
! input data
! a(2*j) = R(j), 0<=j<n/2
! a(2*j+1) = I(j), 0<j<n/2
! a(1) = R(n/2)
! ip(0:*) :work area for bit reversal (integer)
! length of ip >= 2+sqrt(n/2)
! strictly,
! length of ip >=
! 2+2**(int(log(n/2+0.5)/log(2.0))/2).
! ip(0),ip(1) are pointers of the cos/sin table.
! w(0:n/2-1) :cos/sin table (real*8)
! w(),ip() are initialized if ip(0) = 0.
! [remark]
! Inverse of
! call rdft(n, 1, a, ip, w)
! is
! call rdft(n, -1, a, ip, w)
! do j = 0, n - 1
! a(j) = a(j) * 2 / n
! end do
! .
!
!
! -------- DCT (Discrete Cosine Transform) / Inverse of DCT --------
! [definition]
! <case1> IDCT (excluding scale)
! C(k) = sum_j=0^n-1 a(j)*cos(pi*j*(k+1/2)/n), 0<=k<n
! <case2> DCT
! C(k) = sum_j=0^n-1 a(j)*cos(pi*(j+1/2)*k/n), 0<=k<n
! [usage]
! <case1>
! ip(0) = 0 ! first time only
! call ddct(n, 1, a, ip, w)
! <case2>
! ip(0) = 0 ! first time only
! call ddct(n, -1, a, ip, w)
! [parameters]
! n :data length (integer)
! n >= 2, n = power of 2
! a(0:n-1) :input/output data (real*8)
! output data
! a(k) = C(k), 0<=k<n
! ip(0:*) :work area for bit reversal (integer)
! length of ip >= 2+sqrt(n/2)
! strictly,
! length of ip >=
! 2+2**(int(log(n/2+0.5)/log(2.0))/2).
! ip(0),ip(1) are pointers of the cos/sin table.
! w(0:n*5/4-1) :cos/sin table (real*8)
! w(),ip() are initialized if ip(0) = 0.
! [remark]
! Inverse of
! call ddct(n, -1, a, ip, w)
! is
! a(0) = a(0) / 2
! call ddct(n, 1, a, ip, w)
! do j = 0, n - 1
! a(j) = a(j) * 2 / n
! end do
! .
!
!
! -------- DST (Discrete Sine Transform) / Inverse of DST --------
! [definition]
! <case1> IDST (excluding scale)
! S(k) = sum_j=1^n A(j)*sin(pi*j*(k+1/2)/n), 0<=k<n
! <case2> DST
! S(k) = sum_j=0^n-1 a(j)*sin(pi*(j+1/2)*k/n), 0<k<=n
! [usage]
! <case1>
! ip(0) = 0 ! first time only
! call ddst(n, 1, a, ip, w)
! <case2>
! ip(0) = 0 ! first time only
! call ddst(n, -1, a, ip, w)
! [parameters]
! n :data length (integer)
! n >= 2, n = power of 2
! a(0:n-1) :input/output data (real*8)
! <case1>
! input data
! a(j) = A(j), 0<j<n
! a(0) = A(n)
! output data
! a(k) = S(k), 0<=k<n
! <case2>
! output data
! a(k) = S(k), 0<k<n
! a(0) = S(n)
! ip(0:*) :work area for bit reversal (integer)
! length of ip >= 2+sqrt(n/2)
! strictly,
! length of ip >=
! 2+2**(int(log(n/2+0.5)/log(2.0))/2).
! ip(0),ip(1) are pointers of the cos/sin table.
! w(0:n*5/4-1) :cos/sin table (real*8)
! w(),ip() are initialized if ip(0) = 0.
! [remark]
! Inverse of
! call ddst(n, -1, a, ip, w)
! is
! a(0) = a(0) / 2
! call ddst(n, 1, a, ip, w)
! do j = 0, n - 1
! a(j) = a(j) * 2 / n
! end do
! .
!
!
! -------- Cosine Transform of RDFT (Real Symmetric DFT) --------
! [definition]
! C(k) = sum_j=0^n a(j)*cos(pi*j*k/n), 0<=k<=n
! [usage]
! ip(0) = 0 ! first time only
! call dfct(n, a, t, ip, w)
! [parameters]
! n :data length - 1 (integer)
! n >= 2, n = power of 2
! a(0:n) :input/output data (real*8)
! output data
! a(k) = C(k), 0<=k<=n
! t(0:n/2) :work area (real*8)
! ip(0:*) :work area for bit reversal (integer)
! length of ip >= 2+sqrt(n/4)
! strictly,
! length of ip >=
! 2+2**(int(log(n/4+0.5)/log(2.0))/2).
! ip(0),ip(1) are pointers of the cos/sin table.
! w(0:n*5/8-1) :cos/sin table (real*8)
! w(),ip() are initialized if ip(0) = 0.
! [remark]
! Inverse of
! a(0) = a(0) / 2
! a(n) = a(n) / 2
! call dfct(n, a, t, ip, w)
! is
! a(0) = a(0) / 2
! a(n) = a(n) / 2
! call dfct(n, a, t, ip, w)
! do j = 0, n
! a(j) = a(j) * 2 / n
! end do
! .
!
!
! -------- Sine Transform of RDFT (Real Anti-symmetric DFT) --------
! [definition]
! S(k) = sum_j=1^n-1 a(j)*sin(pi*j*k/n), 0<k<n
! [usage]
! ip(0) = 0 ! first time only
! call dfst(n, a, t, ip, w)
! [parameters]
! n :data length + 1 (integer)
! n >= 2, n = power of 2
! a(0:n-1) :input/output data (real*8)
! output data
! a(k) = S(k), 0<k<n
! (a(0) is used for work area)
! t(0:n/2-1) :work area (real*8)
! ip(0:*) :work area for bit reversal (integer)
! length of ip >= 2+sqrt(n/4)
! strictly,
! length of ip >=
! 2+2**(int(log(n/4+0.5)/log(2.0))/2).
! ip(0),ip(1) are pointers of the cos/sin table.
! w(0:n*5/8-1) :cos/sin table (real*8)
! w(),ip() are initialized if ip(0) = 0.
! [remark]
! Inverse of
! call dfst(n, a, t, ip, w)
! is
! call dfst(n, a, t, ip, w)
! do j = 1, n - 1
! a(j) = a(j) * 2 / n
! end do
! .
!
!
! Appendix :
! The cos/sin table is recalculated when the larger table required.
! w() and ip() are compatible with all routines.
!
!
subroutine cdft(n, isgn, a, ip, w)
integer n, isgn, ip(0 : *)
real*8 a(0 : n - 1), w(0 : *)
if (n .gt. 4 * ip(0)) then
call makewt(n / 4, ip, w)
end if
if (n .gt. 4) then
if (isgn .ge. 0) then
call bitrv2(n, ip(2), a)
call cftfsub(n, a, w)
else
call bitrv2conj(n, ip(2), a)
call cftbsub(n, a, w)
end if
else if (n .eq. 4) then
call cftfsub(n, a, w)
end if
end
!
subroutine rdft(n, isgn, a, ip, w)
integer n, isgn, ip(0 : *), nw, nc
real*8 a(0 : n - 1), w(0 : *), xi
nw = ip(0)
if (n .gt. 4 * nw) then
nw = n / 4
call makewt(nw, ip, w)
end if
nc = ip(1)
if (n .gt. 4 * nc) then
nc = n / 4
call makect(nc, ip, w(nw))
end if
if (isgn .ge. 0) then
if (n .gt. 4) then
call bitrv2(n, ip(2), a)
call cftfsub(n, a, w)
call rftfsub(n, a, nc, w(nw))
else if (n .eq. 4) then
call cftfsub(n, a, w)
end if
xi = a(0) - a(1)
a(0) = a(0) + a(1)
a(1) = xi
else
a(1) = 0.5d0 * (a(0) - a(1))
a(0) = a(0) - a(1)
if (n .gt. 4) then
call rftbsub(n, a, nc, w(nw))
call bitrv2(n, ip(2), a)
call cftbsub(n, a, w)
else if (n .eq. 4) then
call cftfsub(n, a, w)
end if
end if
end
!
subroutine ddct(n, isgn, a, ip, w)
integer n, isgn, ip(0 : *), j, nw, nc
real*8 a(0 : n - 1), w(0 : *), xr
nw = ip(0)
if (n .gt. 4 * nw) then
nw = n / 4
call makewt(nw, ip, w)
end if
nc = ip(1)
if (n .gt. nc) then
nc = n
call makect(nc, ip, w(nw))
end if
if (isgn .lt. 0) then
xr = a(n - 1)
do j = n - 2, 2, -2
a(j + 1) = a(j) - a(j - 1)
a(j) = a(j) + a(j - 1)
end do
a(1) = a(0) - xr
a(0) = a(0) + xr
if (n .gt. 4) then
call rftbsub(n, a, nc, w(nw))
call bitrv2(n, ip(2), a)
call cftbsub(n, a, w)
else if (n .eq. 4) then
call cftfsub(n, a, w)
end if
end if
call dctsub(n, a, nc, w(nw))
if (isgn .ge. 0) then
if (n .gt. 4) then
call bitrv2(n, ip(2), a)
call cftfsub(n, a, w)
call rftfsub(n, a, nc, w(nw))
else if (n .eq. 4) then
call cftfsub(n, a, w)
end if
xr = a(0) - a(1)
a(0) = a(0) + a(1)
do j = 2, n - 2, 2
a(j - 1) = a(j) - a(j + 1)
a(j) = a(j) + a(j + 1)
end do
a(n - 1) = xr
end if
end
!
subroutine ddst(n, isgn, a, ip, w)
integer n, isgn, ip(0 : *), j, nw, nc
real*8 a(0 : n - 1), w(0 : *), xr
nw = ip(0)
if (n .gt. 4 * nw) then
nw = n / 4
call makewt(nw, ip, w)
end if
nc = ip(1)
if (n .gt. nc) then
nc = n
call makect(nc, ip, w(nw))
end if
if (isgn .lt. 0) then
xr = a(n - 1)
do j = n - 2, 2, -2
a(j + 1) = -a(j) - a(j - 1)
a(j) = a(j) - a(j - 1)
end do
a(1) = a(0) + xr
a(0) = a(0) - xr
if (n .gt. 4) then
call rftbsub(n, a, nc, w(nw))
call bitrv2(n, ip(2), a)
call cftbsub(n, a, w)
else if (n .eq. 4) then
call cftfsub(n, a, w)
end if
end if
call dstsub(n, a, nc, w(nw))
if (isgn .ge. 0) then
if (n .gt. 4) then
call bitrv2(n, ip(2), a)
call cftfsub(n, a, w)
call rftfsub(n, a, nc, w(nw))
else if (n .eq. 4) then
call cftfsub(n, a, w)
end if
xr = a(0) - a(1)
a(0) = a(0) + a(1)
do j = 2, n - 2, 2
a(j - 1) = -a(j) - a(j + 1)
a(j) = a(j) - a(j + 1)
end do
a(n - 1) = -xr
end if
end
!
subroutine dfct(n, a, t, ip, w)
integer n, ip(0 : *), j, k, l, m, mh, nw, nc
real*8 a(0 : n), t(0 : n / 2), w(0 : *), xr, xi, yr, yi
nw = ip(0)
if (n .gt. 8 * nw) then
nw = n / 8
call makewt(nw, ip, w)
end if
nc = ip(1)
if (n .gt. 2 * nc) then
nc = n / 2
call makect(nc, ip, w(nw))
end if
m = n / 2
yi = a(m)
xi = a(0) + a(n)
a(0) = a(0) - a(n)
t(0) = xi - yi
t(m) = xi + yi
if (n .gt. 2) then
mh = m / 2
do j = 1, mh - 1
k = m - j
xr = a(j) - a(n - j)
xi = a(j) + a(n - j)
yr = a(k) - a(n - k)
yi = a(k) + a(n - k)
a(j) = xr
a(k) = yr
t(j) = xi - yi
t(k) = xi + yi
end do
t(mh) = a(mh) + a(n - mh)
a(mh) = a(mh) - a(n - mh)
call dctsub(m, a, nc, w(nw))
if (m .gt. 4) then
call bitrv2(m, ip(2), a)
call cftfsub(m, a, w)
call rftfsub(m, a, nc, w(nw))
else if (m .eq. 4) then
call cftfsub(m, a, w)
end if
a(n - 1) = a(0) - a(1)
a(1) = a(0) + a(1)
do j = m - 2, 2, -2
a(2 * j + 1) = a(j) + a(j + 1)
a(2 * j - 1) = a(j) - a(j + 1)
end do
l = 2
m = mh
do while (m .ge. 2)
call dctsub(m, t, nc, w(nw))
if (m .gt. 4) then
call bitrv2(m, ip(2), t)
call cftfsub(m, t, w)
call rftfsub(m, t, nc, w(nw))
else if (m .eq. 4) then
call cftfsub(m, t, w)
end if
a(n - l) = t(0) - t(1)
a(l) = t(0) + t(1)
k = 0
do j = 2, m - 2, 2
k = k + 4 * l
a(k - l) = t(j) - t(j + 1)
a(k + l) = t(j) + t(j + 1)
end do
l = 2 * l
mh = m / 2
do j = 0, mh - 1
k = m - j
t(j) = t(m + k) - t(m + j)
t(k) = t(m + k) + t(m + j)
end do
t(mh) = t(m + mh)
m = mh
end do
a(l) = t(0)
a(n) = t(2) - t(1)
a(0) = t(2) + t(1)
else
a(1) = a(0)
a(2) = t(0)
a(0) = t(1)
end if
end
!
subroutine dfst(n, a, t, ip, w)
integer n, ip(0 : *), j, k, l, m, mh, nw, nc
real*8 a(0 : n - 1), t(0 : n / 2 - 1), w(0 : *), xr, xi, yr, yi
nw = ip(0)
if (n .gt. 8 * nw) then
nw = n / 8
call makewt(nw, ip, w)
end if
nc = ip(1)
if (n .gt. 2 * nc) then
nc = n / 2
call makect(nc, ip, w(nw))
end if
if (n .gt. 2) then
m = n / 2
mh = m / 2
do j = 1, mh - 1
k = m - j
xr = a(j) + a(n - j)
xi = a(j) - a(n - j)
yr = a(k) + a(n - k)
yi = a(k) - a(n - k)
a(j) = xr
a(k) = yr
t(j) = xi + yi
t(k) = xi - yi
end do
t(0) = a(mh) - a(n - mh)
a(mh) = a(mh) + a(n - mh)
a(0) = a(m)
call dstsub(m, a, nc, w(nw))
if (m .gt. 4) then
call bitrv2(m, ip(2), a)
call cftfsub(m, a, w)
call rftfsub(m, a, nc, w(nw))
else if (m .eq. 4) then
call cftfsub(m, a, w)
end if
a(n - 1) = a(1) - a(0)
a(1) = a(0) + a(1)
do j = m - 2, 2, -2
a(2 * j + 1) = a(j) - a(j + 1)
a(2 * j - 1) = -a(j) - a(j + 1)
end do
l = 2
m = mh
do while (m .ge. 2)
call dstsub(m, t, nc, w(nw))
if (m .gt. 4) then
call bitrv2(m, ip(2), t)
call cftfsub(m, t, w)
call rftfsub(m, t, nc, w(nw))
else if (m .eq. 4) then
call cftfsub(m, t, w)
end if
a(n - l) = t(1) - t(0)
a(l) = t(0) + t(1)
k = 0
do j = 2, m - 2, 2
k = k + 4 * l
a(k - l) = -t(j) - t(j + 1)
a(k + l) = t(j) - t(j + 1)
end do
l = 2 * l
mh = m / 2
do j = 1, mh - 1
k = m - j
t(j) = t(m + k) + t(m + j)
t(k) = t(m + k) - t(m + j)
end do
t(0) = t(m + mh)
m = mh
end do
a(l) = t(0)
end if
a(0) = 0
end
!
! -------- initializing routines --------
!
subroutine makewt(nw, ip, w)
integer nw, ip(0 : *), j, nwh
real*8 w(0 : nw - 1), delta, x, y
ip(0) = nw
ip(1) = 1
if (nw .gt. 2) then
nwh = nw / 2
delta = atan(1.0d0) / nwh
w(0) = 1
w(1) = 0
w(nwh) = cos(delta * nwh)
w(nwh + 1) = w(nwh)
if (nwh .gt. 2) then
do j = 2, nwh - 2, 2
x = cos(delta * j)
y = sin(delta * j)
w(j) = x
w(j + 1) = y
w(nw - j) = y
w(nw - j + 1) = x
end do
call bitrv2(nw, ip(2), w)
end if
end if
end
!
subroutine makect(nc, ip, c)
integer nc, ip(0 : *), j, nch
real*8 c(0 : nc - 1), delta
ip(1) = nc
if (nc .gt. 1) then
nch = nc / 2
delta = atan(1.0d0) / nch
c(0) = cos(delta * nch)
c(nch) = 0.5d0 * c(0)
do j = 1, nch - 1
c(j) = 0.5d0 * cos(delta * j)
c(nc - j) = 0.5d0 * sin(delta * j)
end do
end if
end
!
! -------- child routines --------
!
subroutine bitrv2(n, ip, a)
integer n, ip(0 : *), j, j1, k, k1, l, m, m2
real*8 a(0 : n - 1), xr, xi, yr, yi
ip(0) = 0
l = n
m = 1
do while (8 * m .lt. l)
l = l / 2
do j = 0, m - 1
ip(m + j) = ip(j) + l
end do
m = m * 2
end do
m2 = 2 * m
if (8 * m .eq. l) then
do k = 0, m - 1
do j = 0, k - 1
j1 = 2 * j + ip(k)
k1 = 2 * k + ip(j)
xr = a(j1)
xi = a(j1 + 1)
yr = a(k1)
yi = a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
j1 = j1 + m2
k1 = k1 + 2 * m2
xr = a(j1)
xi = a(j1 + 1)
yr = a(k1)
yi = a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
j1 = j1 + m2
k1 = k1 - m2
xr = a(j1)
xi = a(j1 + 1)
yr = a(k1)
yi = a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
j1 = j1 + m2
k1 = k1 + 2 * m2
xr = a(j1)
xi = a(j1 + 1)
yr = a(k1)
yi = a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
end do
j1 = 2 * k + m2 + ip(k)
k1 = j1 + m2
xr = a(j1)
xi = a(j1 + 1)
yr = a(k1)
yi = a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
end do
else
do k = 1, m - 1
do j = 0, k - 1
j1 = 2 * j + ip(k)
k1 = 2 * k + ip(j)
xr = a(j1)
xi = a(j1 + 1)
yr = a(k1)
yi = a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
j1 = j1 + m2
k1 = k1 + m2
xr = a(j1)
xi = a(j1 + 1)
yr = a(k1)
yi = a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
end do
end do
end if
end
!
subroutine bitrv2conj(n, ip, a)
integer n, ip(0 : *), j, j1, k, k1, l, m, m2
real*8 a(0 : n - 1), xr, xi, yr, yi
ip(0) = 0
l = n
m = 1
do while (8 * m .lt. l)
l = l / 2
do j = 0, m - 1
ip(m + j) = ip(j) + l
end do
m = m * 2
end do
m2 = 2 * m
if (8 * m .eq. l) then
do k = 0, m - 1
do j = 0, k - 1
j1 = 2 * j + ip(k)
k1 = 2 * k + ip(j)
xr = a(j1)
xi = -a(j1 + 1)
yr = a(k1)
yi = -a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
j1 = j1 + m2
k1 = k1 + 2 * m2
xr = a(j1)
xi = -a(j1 + 1)
yr = a(k1)
yi = -a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
j1 = j1 + m2
k1 = k1 - m2
xr = a(j1)
xi = -a(j1 + 1)
yr = a(k1)
yi = -a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
j1 = j1 + m2
k1 = k1 + 2 * m2
xr = a(j1)
xi = -a(j1 + 1)
yr = a(k1)
yi = -a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
end do
k1 = 2 * k + ip(k)
a(k1 + 1) = -a(k1 + 1)
j1 = k1 + m2
k1 = j1 + m2
xr = a(j1)
xi = -a(j1 + 1)
yr = a(k1)
yi = -a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
k1 = k1 + m2
a(k1 + 1) = -a(k1 + 1)
end do
else
a(1) = -a(1)
a(m2 + 1) = -a(m2 + 1)
do k = 1, m - 1
do j = 0, k - 1
j1 = 2 * j + ip(k)
k1 = 2 * k + ip(j)
xr = a(j1)
xi = -a(j1 + 1)
yr = a(k1)
yi = -a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
j1 = j1 + m2
k1 = k1 + m2
xr = a(j1)
xi = -a(j1 + 1)
yr = a(k1)
yi = -a(k1 + 1)
a(j1) = yr
a(j1 + 1) = yi
a(k1) = xr
a(k1 + 1) = xi
end do
k1 = 2 * k + ip(k)
a(k1 + 1) = -a(k1 + 1)
a(k1 + m2 + 1) = -a(k1 + m2 + 1)
end do
end if
end
!
subroutine cftfsub(n, a, w)
integer n, j, j1, j2, j3, l
real*8 a(0 : n - 1), w(0 : *)
real*8 x0r, x0i, x1r, x1i, x2r, x2i, x3r, x3i
l = 2
if (n .gt. 8) then
call cft1st(n, a, w)
l = 8
do while (4 * l .lt. n)
call cftmdl(n, l, a, w)
l = 4 * l
end do
end if
if (4 * l .eq. n) then
do j = 0, l - 2, 2
j1 = j + l
j2 = j1 + l
j3 = j2 + l
x0r = a(j) + a(j1)
x0i = a(j + 1) + a(j1 + 1)
x1r = a(j) - a(j1)
x1i = a(j + 1) - a(j1 + 1)
x2r = a(j2) + a(j3)
x2i = a(j2 + 1) + a(j3 + 1)
x3r = a(j2) - a(j3)
x3i = a(j2 + 1) - a(j3 + 1)
a(j) = x0r + x2r
a(j + 1) = x0i + x2i
a(j2) = x0r - x2r
a(j2 + 1) = x0i - x2i
a(j1) = x1r - x3i
a(j1 + 1) = x1i + x3r
a(j3) = x1r + x3i
a(j3 + 1) = x1i - x3r
end do
else
do j = 0, l - 2, 2
j1 = j + l
x0r = a(j) - a(j1)
x0i = a(j + 1) - a(j1 + 1)
a(j) = a(j) + a(j1)
a(j + 1) = a(j + 1) + a(j1 + 1)
a(j1) = x0r
a(j1 + 1) = x0i
end do
end if
end
!
subroutine cftbsub(n, a, w)
integer n, j, j1, j2, j3, l
real*8 a(0 : n - 1), w(0 : *)
real*8 x0r, x0i, x1r, x1i, x2r, x2i, x3r, x3i
l = 2
if (n .gt. 8) then
call cft1st(n, a, w)
l = 8
do while (4 * l .lt. n)
call cftmdl(n, l, a, w)
l = 4 * l
end do
end if
if (4 * l .eq. n) then
do j = 0, l - 2, 2
j1 = j + l
j2 = j1 + l
j3 = j2 + l
x0r = a(j) + a(j1)
x0i = -a(j + 1) - a(j1 + 1)
x1r = a(j) - a(j1)
x1i = -a(j + 1) + a(j1 + 1)
x2r = a(j2) + a(j3)
x2i = a(j2 + 1) + a(j3 + 1)
x3r = a(j2) - a(j3)
x3i = a(j2 + 1) - a(j3 + 1)
a(j) = x0r + x2r
a(j + 1) = x0i - x2i
a(j2) = x0r - x2r
a(j2 + 1) = x0i + x2i
a(j1) = x1r - x3i
a(j1 + 1) = x1i - x3r
a(j3) = x1r + x3i
a(j3 + 1) = x1i + x3r
end do
else
do j = 0, l - 2, 2
j1 = j + l
x0r = a(j) - a(j1)
x0i = -a(j + 1) + a(j1 + 1)
a(j) = a(j) + a(j1)
a(j + 1) = -a(j + 1) - a(j1 + 1)
a(j1) = x0r
a(j1 + 1) = x0i
end do
end if
end
!
subroutine cft1st(n, a, w)
integer n, j, k1, k2
real*8 a(0 : n - 1), w(0 : *)
real*8 wk1r, wk1i, wk2r, wk2i, wk3r, wk3i
real*8 x0r, x0i, x1r, x1i, x2r, x2i, x3r, x3i
x0r = a(0) + a(2)
x0i = a(1) + a(3)
x1r = a(0) - a(2)
x1i = a(1) - a(3)
x2r = a(4) + a(6)
x2i = a(5) + a(7)
x3r = a(4) - a(6)
x3i = a(5) - a(7)
a(0) = x0r + x2r
a(1) = x0i + x2i
a(4) = x0r - x2r
a(5) = x0i - x2i
a(2) = x1r - x3i
a(3) = x1i + x3r
a(6) = x1r + x3i
a(7) = x1i - x3r
wk1r = w(2)
x0r = a(8) + a(10)
x0i = a(9) + a(11)
x1r = a(8) - a(10)
x1i = a(9) - a(11)
x2r = a(12) + a(14)
x2i = a(13) + a(15)
x3r = a(12) - a(14)
x3i = a(13) - a(15)
a(8) = x0r + x2r
a(9) = x0i + x2i
a(12) = x2i - x0i
a(13) = x0r - x2r
x0r = x1r - x3i
x0i = x1i + x3r
a(10) = wk1r * (x0r - x0i)
a(11) = wk1r * (x0r + x0i)
x0r = x3i + x1r
x0i = x3r - x1i
a(14) = wk1r * (x0i - x0r)
a(15) = wk1r * (x0i + x0r)
k1 = 0
do j = 16, n - 16, 16
k1 = k1 + 2
k2 = 2 * k1
wk2r = w(k1)
wk2i = w(k1 + 1)
wk1r = w(k2)
wk1i = w(k2 + 1)
wk3r = wk1r - 2 * wk2i * wk1i
wk3i = 2 * wk2i * wk1r - wk1i
x0r = a(j) + a(j + 2)
x0i = a(j + 1) + a(j + 3)
x1r = a(j) - a(j + 2)
x1i = a(j + 1) - a(j + 3)
x2r = a(j + 4) + a(j + 6)
x2i = a(j + 5) + a(j + 7)
x3r = a(j + 4) - a(j + 6)
x3i = a(j + 5) - a(j + 7)
a(j) = x0r + x2r
a(j + 1) = x0i + x2i
x0r = x0r - x2r
x0i = x0i - x2i
a(j + 4) = wk2r * x0r - wk2i * x0i
a(j + 5) = wk2r * x0i + wk2i * x0r
x0r = x1r - x3i
x0i = x1i + x3r
a(j + 2) = wk1r * x0r - wk1i * x0i
a(j + 3) = wk1r * x0i + wk1i * x0r