How to call QueryServiceConfig?

[mprkins]

Hello,
I'd like to call QueryServiceConfig to get some more info about the running service.

import winim/lean
import strformat except `&`
import strutils

const SERVICE_EXAMPLE:LPSTR = "SysMain"

proc main =
  var sc = OpenSCManager(nil, nil, SERVICE_QUERY_CONFIG  )
  echo fmt"OpenSCMAnager: {GetLastError()}"
  if sc != 0:
    defer: CloseServiceHandle(sc)

  var os = OpenService(sc,SERVICE_EXAMPLE,SERVICE_QUERY_CONFIG )
  echo fmt"OpenService: {GetLastError()} : os: {os}"
  if os != 0:
      defer: CloseServiceHandle(os)

  var 
      bytesNeeded: DWORD
      
  QueryServiceConfig(os,nil,0,&bytesNeeded)
  echo fmt"QueryServiceConfig: {GetLastError()}"

  var buffer = newString(bytesNeeded)
  let lpServiceConfig = cast[LPQUERY_SERVICE_CONFIGW](&buffer)
  let config = cast[ptr UncheckedArray[LPQUERY_SERVICE_CONFIGW]](lpServiceConfig)

  QueryServiceConfig(os,lpServiceConfig,bytesNeeded,&bytesNeeded)

  echo fmt"Let's print the path {bytesNeeded}"
  for i in 0..<bytesNeeded:
    echo fmt"{config[i].lpBinaryPathName}"

when isMainModule:
  main()

I am not sure what I am doing wrong..I am getting error code 6 (ERROR_INVALID_HANDLE) for OpenService...but...I guess I just dont know what I am doing.
)

[khchen]

In nim, if starts a new scope, so that defer: CloseServiceHandle(os) is always run after the scope end.

I modified your code:

import winim/lean
import strformat except `&`
import strutils

const SERVICE_EXAMPLE = "SysMain"

proc main =
  var sc = OpenSCManager(nil, nil, SERVICE_QUERY_CONFIG)
  echo fmt"OpenSCMAnager: {GetLastError()}"
  defer:
    if sc != 0: CloseServiceHandle(sc)

  var os = OpenService(sc, SERVICE_EXAMPLE, SERVICE_QUERY_CONFIG)
  echo fmt"OpenService: {GetLastError()} : os: {os}"
  defer:
    if os != 0: CloseServiceHandle(os)

  var bytesNeeded: DWORD

  QueryServiceConfig(os, nil, 0, &bytesNeeded)
  echo fmt"QueryServiceConfig: {GetLastError()}"

  var buffer = newString(bytesNeeded)
  let lpServiceConfig = cast[LPQUERY_SERVICE_CONFIG](&buffer)

  QueryServiceConfig(os, lpServiceConfig, bytesNeeded, &bytesNeeded)

  echo fmt"Let's print the path {bytesNeeded}"
  echo lpServiceConfig.lpBinaryPathName

when isMainModule:
  main()