-
-
Notifications
You must be signed in to change notification settings - Fork 267
/
Copy pathinitsem.d
1640 lines (1532 loc) · 57.4 KB
/
initsem.d
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
/**
* Semantic analysis of initializers.
*
* Copyright: Copyright (C) 1999-2025 by The D Language Foundation, All Rights Reserved
* Authors: $(LINK2 https://www.digitalmars.com, Walter Bright)
* License: $(LINK2 https://www.boost.org/LICENSE_1_0.txt, Boost License 1.0)
* Source: $(LINK2 https://github.com/dlang/dmd/blob/master/compiler/src/dmd/initsem.d, _initsem.d)
* Documentation: https://dlang.org/phobos/dmd_initsem.html
* Coverage: https://codecov.io/gh/dlang/dmd/src/master/compiler/src/dmd/initsem.d
*/
module dmd.initsem;
import core.stdc.stdio;
import core.checkedint;
import dmd.aggregate;
import dmd.aliasthis;
import dmd.arraytypes;
import dmd.astenums;
import dmd.dcast;
import dmd.declaration;
import dmd.dinterpret;
import dmd.dscope;
import dmd.dstruct;
import dmd.dsymbol;
import dmd.dsymbolsem;
import dmd.dtemplate;
import dmd.errors;
import dmd.expression;
import dmd.expressionsem;
import dmd.func;
import dmd.funcsem;
import dmd.globals;
import dmd.hdrgen;
import dmd.id;
import dmd.identifier;
import dmd.importc;
import dmd.init;
import dmd.location;
import dmd.mtype;
import dmd.opover;
import dmd.optimize;
import dmd.safe : setUnsafe;
import dmd.statement;
import dmd.target;
import dmd.tokens;
import dmd.typesem;
/********************************
* If possible, convert array initializer to associative array initializer.
*
* Params:
* ai = array initializer to be converted
*
* Returns:
* The converted associative array initializer or ErrorExp if `ai`
* is not an associative array initializer.
*/
Expression toAssocArrayLiteral(ArrayInitializer ai)
{
//printf("ArrayInitializer::toAssocArrayInitializer(%s)\n", ai.toChars());
//static int i; if (++i == 2) assert(0);
auto no(const char* format, Initializer i)
{
error(i.loc, format, toChars(i));
return ErrorExp.get();
}
const dim = ai.value.length;
if (!dim)
return no("invalid associative array initializer `%s`, use `null` instead", ai);
auto keys = new Expressions(dim);
auto values = new Expressions(dim);
foreach (i, iz; ai.value[])
{
assert(iz);
auto ev = iz.initializerToExpression();
if (!ev)
return no("invalid value `%s` in initializer", iz);
(*values)[i] = ev;
auto ei = ai.index[i];
if (!ei)
return no("missing key for value `%s` in initializer", iz);
(*keys)[i] = ei;
}
return new AssocArrayLiteralExp(ai.loc, keys, values);
}
/******************************************
* Perform semantic analysis on init.
* Params:
* init = Initializer AST node
* sc = context
* tx = type that the initializer needs to become. If tx is an incomplete
* type and the initializer completes it, it is updated to be the
* complete type. ImportC has incomplete types
* needInterpret = if CTFE needs to be run on this,
* such as if it is the initializer for a const declaration
* Returns:
* `Initializer` with completed semantic analysis, `ErrorInitializer` if errors
* were encountered
*/
Initializer initializerSemantic(Initializer init, Scope* sc, ref Type tx, NeedInterpret needInterpret)
{
//printf("initializerSemantic() tx: %p %s\n", tx, tx.toChars());
if (init.semanticDone)
return init;
Type t = tx;
static Initializer err()
{
return new ErrorInitializer();
}
Initializer visitVoid(VoidInitializer i)
{
i.type = t;
return i;
}
Initializer visitDefault(DefaultInitializer i)
{
i.type = t;
return i;
}
Initializer visitError(ErrorInitializer i)
{
return i;
}
Initializer visitStruct(StructInitializer i)
{
//printf("StructInitializer::semantic(t = %s) %s\n", t.toChars(), i.toChars());
/* This works by replacing the StructInitializer with an ExpInitializer.
*/
t = t.toBasetype();
if (auto tsa = t.isTypeSArray())
{
auto ts = tsa.nextOf().toBasetype().isTypeStruct();
if (ts)
t = ts;
}
if (auto ts = t.isTypeStruct())
{
StructDeclaration sd = ts.sym;
// check if the sd has a regular ctor (user defined non-copy ctor)
// that is not disabled.
if (sd.hasRegularCtor(true))
{
error(i.loc, "%s `%s` has constructors, cannot use `{ initializers }`, use `%s( initializers )` instead", sd.kind(), sd.toChars(), sd.toChars());
return err();
}
sd.size(i.loc);
if (sd.sizeok != Sizeok.done)
return err();
Expression getExp(size_t j, Type fieldType)
{
// Convert initializer to Expression `ex`
auto tm = fieldType.addMod(t.mod);
auto iz = i.value[j].initializerSemantic(sc, tm, needInterpret);
auto ex = iz.initializerToExpression(null, sc.inCfile);
if (ex.op != EXP.error)
i.value[j] = iz;
return ex;
}
auto elements = resolveStructLiteralNamedArgs(sd, t, sc, i.loc, i.field[], &getExp, (size_t j) => i.value[j].loc);
if (!elements)
return err();
// Make a StructLiteralExp out of elements[]
auto sle = new StructLiteralExp(i.loc, sd, elements, t);
if (!sd.fill(i.loc, *elements, false))
return err();
sle.type = t;
auto ie = new ExpInitializer(i.loc, sle);
return ie.initializerSemantic(sc, t, needInterpret);
}
else if ((t.ty == Tdelegate || t.isPtrToFunction()) && i.value.length == 0)
{
const tok = (t.ty == Tdelegate) ? TOK.delegate_ : TOK.function_;
/* Rewrite as empty delegate literal { }
*/
Type tf = new TypeFunction(ParameterList(), null, LINK.d);
auto fd = new FuncLiteralDeclaration(i.loc, Loc.initial, tf, tok, null);
fd.fbody = new CompoundStatement(i.loc, new Statements());
fd.endloc = i.loc;
Expression e = new FuncExp(i.loc, fd);
auto ie = new ExpInitializer(i.loc, e);
return ie.initializerSemantic(sc, t, needInterpret);
}
if (t.ty != Terror)
error(i.loc, "a struct is not a valid initializer for a `%s`", t.toChars());
return err();
}
Initializer visitArray(ArrayInitializer i)
{
uint length;
const(uint) amax = 0x80000000;
bool errors = false;
//printf("ArrayInitializer::semantic(%s), ai: %s\n", t.toChars(), toChars(i));
t = t.toBasetype();
switch (t.ty)
{
case Tsarray:
case Tarray:
break;
case Tvector:
t = t.isTypeVector().basetype;
break;
case Taarray:
case Tstruct: // consider implicit constructor call
{
Expression e;
// note: MyStruct foo = [1:2, 3:4] is correct code if MyStruct has a this(int[int])
if (t.ty == Taarray || i.isAssociativeArray())
e = i.toAssocArrayLiteral();
else
e = i.initializerToExpression();
// Bugzilla 13987
if (!e)
{
error(i.loc, "cannot use array to initialize `%s`", t.toChars());
return err();
}
auto ei = new ExpInitializer(e.loc, e);
return ei.initializerSemantic(sc, t, needInterpret);
}
case Tpointer:
if (t.nextOf().isTypeFunction())
goto default;
break;
default:
error(i.loc, "cannot use array to initialize `%s`", t.toChars());
return err();
}
i.type = t;
length = 0;
for (size_t j = 0; j < i.index.length; j++) // don't replace with foreach; j is modified
{
Expression idx = i.index[j];
if (idx)
{
sc = sc.startCTFE();
idx = idx.expressionSemantic(sc);
sc = sc.endCTFE();
idx = idx.ctfeInterpret();
i.index[j] = idx;
const uinteger_t idxvalue = idx.toInteger();
if (idxvalue >= amax)
{
error(i.loc, "array index %llu overflow", idxvalue);
errors = true;
}
length = cast(uint)idxvalue;
if (idx.op == EXP.error)
errors = true;
}
Initializer val = i.value[j];
ExpInitializer ei = val.isExpInitializer();
if (ei && !idx)
ei.expandTuples = true;
auto tn = t.nextOf();
val = val.initializerSemantic(sc, tn, needInterpret);
if (val.isErrorInitializer())
errors = true;
ei = val.isExpInitializer();
// found a tuple, expand it
if (ei && ei.exp.op == EXP.tuple)
{
TupleExp te = ei.exp.isTupleExp();
i.index.remove(j);
i.value.remove(j);
foreach (k, e; (*te.exps)[])
{
i.index.insert(j + k, cast(Expression)null);
i.value.insert(j + k, new ExpInitializer(e.loc, e));
}
j--;
continue;
}
else
{
i.value[j] = val;
}
++length;
if (length == 0)
{
error(i.loc, "array dimension overflow");
return err();
}
if (length > i.dim)
i.dim = length;
}
if (auto tsa = t.isTypeSArray())
{
if (sc.inCfile && tsa.isIncomplete())
{
// Change to array of known length
auto tn = tsa.next.toBasetype();
tsa = new TypeSArray(tn, new IntegerExp(Loc.initial, i.dim, Type.tsize_t));
tx = tsa; // rewrite caller's type
i.type = tsa; // remember for later passes
}
else
{
ulong edim = tsa.dim.toInteger();
if (i.dim > edim)
{
error(i.loc, "array initializer has %u elements, but array length is %llu", i.dim, edim);
return err();
}
}
}
if (errors)
return err();
const sz = t.nextOf().size();
if (sz == SIZE_INVALID)
return err();
bool overflow;
const max = mulu(i.dim, sz, overflow);
if (overflow || max >= amax)
{
error(i.loc, "array dimension %llu exceeds max of %llu", ulong(i.dim), ulong(amax / sz));
return err();
}
//printf("returns ai: %s\n", i.toChars());
return i;
}
Initializer visitExp(ExpInitializer i)
{
//printf("ExpInitializer::semantic(%s), type = %s\n", i.exp.toChars(), t.toChars());
if (needInterpret)
sc = sc.startCTFE();
i.exp = i.exp.expressionSemantic(sc);
i.exp = resolveProperties(sc, i.exp);
if (needInterpret)
sc = sc.endCTFE();
if (i.exp.op == EXP.error)
return err();
const olderrors = global.errors;
/* ImportC: convert arrays to pointers, functions to pointers to functions
*/
Type tb = t.toBasetype();
if (tb.isTypePointer())
i.exp = i.exp.arrayFuncConv(sc);
/* Save the expression before ctfe
* Otherwise the error message would contain for example "&[0][0]" instead of "new int"
* Regression: https://issues.dlang.org/show_bug.cgi?id=21687
*/
Expression currExp = i.exp;
if (needInterpret)
{
// If the result will be implicitly cast, move the cast into CTFE
// to avoid premature truncation of polysemous types.
// eg real [] x = [1.1, 2.2]; should use real precision.
if (i.exp.implicitConvTo(t) && !sc.inCfile)
{
i.exp = i.exp.implicitCastTo(sc, t);
}
if (!global.gag && olderrors != global.errors)
{
return i;
}
if (sc.inCfile)
{
/* the interpreter turns (char*)"string" into &"string"[0] which then
* it cannot interpret. Resolve that case by doing optimize() first
*/
i.exp = i.exp.optimize(WANTvalue);
if (i.exp.isSymOffExp())
{
/* `static variable cannot be read at compile time`
* https://issues.dlang.org/show_bug.cgi?id=22513
* Maybe this would be better addressed in ctfeInterpret()?
*/
needInterpret = NeedInterpret.INITnointerpret;
}
}
if (needInterpret)
i.exp = i.exp.ctfeInterpret();
if (i.exp.op == EXP.voidExpression)
error(i.loc, "variables cannot be initialized with an expression of type `void`. Use `void` initialization instead.");
}
else
{
i.exp = i.exp.optimize(WANTvalue);
}
if (!global.gag && olderrors != global.errors)
{
return i; // Failed, suppress duplicate error messages
}
if (i.exp.type.isTypeTuple() && i.exp.type.isTypeTuple().arguments.length == 0)
{
Type et = i.exp.type;
i.exp = new TupleExp(i.exp.loc, new Expressions());
i.exp.type = et;
}
if (i.exp.op == EXP.type)
{
error(i.exp.loc, "initializer must be an expression, not `%s`", i.exp.toChars());
return err();
}
// Make sure all pointers are constants
if (needInterpret && hasNonConstPointers(i.exp))
{
error(i.exp.loc, "cannot use non-constant CTFE pointer in an initializer `%s`", currExp.toChars());
return err();
}
Type ti = i.exp.type.toBasetype();
if (i.exp.op == EXP.tuple && i.expandTuples && !i.exp.implicitConvTo(t))
{
return new ExpInitializer(i.loc, i.exp);
}
/* Look for case of initializing a static array with a too-short
* string literal, such as:
* char[5] foo = "abc";
* Allow this by doing an explicit cast, which will lengthen the string
* literal.
*/
if (i.exp.op == EXP.string_ && tb.ty == Tsarray)
{
StringExp se = i.exp.isStringExp();
Type typeb = se.type.toBasetype();
TY tynto = tb.nextOf().ty;
if (!se.committed &&
typeb.isStaticOrDynamicArray() && tynto.isSomeChar &&
se.numberOfCodeUnits(tynto) < tb.isTypeSArray().dim.toInteger())
{
i.exp = se.castTo(sc, t);
goto L1;
}
/* Lop off terminating 0 of initializer for:
* static char s[5] = "hello";
*/
if (sc.inCfile &&
typeb.ty == Tsarray &&
tynto.isSomeChar &&
tb.isTypeSArray().dim.toInteger() + 1 == typeb.isTypeSArray().dim.toInteger())
{
i.exp = se.castTo(sc, t);
goto L1;
}
}
/* C11 6.7.9-14..15
* Initialize an array of unknown size with a string.
* Change to static array of known size
*/
if (sc.inCfile && i.exp.isStringExp() &&
tb.isTypeSArray() && tb.isTypeSArray().isIncomplete())
{
StringExp se = i.exp.isStringExp();
auto ts = new TypeSArray(tb.nextOf(), new IntegerExp(Loc.initial, se.len + 1, Type.tsize_t));
t = typeSemantic(ts, Loc.initial, sc);
i.exp.type = t;
tx = t;
}
// Look for implicit constructor call
if (tb.ty == Tstruct && !(ti.ty == Tstruct && tb.toDsymbol(sc) == ti.toDsymbol(sc)) && !i.exp.implicitConvTo(t))
{
StructDeclaration sd = tb.isTypeStruct().sym;
if (sd.ctor)
{
// Rewrite as S().ctor(exp)
Expression e;
e = new StructLiteralExp(i.loc, sd, null);
e = new DotIdExp(i.loc, e, Id.ctor);
e = new CallExp(i.loc, e, i.exp);
e = e.expressionSemantic(sc);
if (needInterpret)
i.exp = e.ctfeInterpret();
else
i.exp = e.optimize(WANTvalue);
}
else if (search_function(sd, Id.opCall))
{
/* https://issues.dlang.org/show_bug.cgi?id=1547
*
* Look for static opCall
*
* Rewrite as:
* i.exp = typeof(sd).opCall(arguments)
*/
Expression e = typeDotIdExp(i.loc, sd.type, Id.opCall);
e = new CallExp(i.loc, e, i.exp);
e = e.expressionSemantic(sc);
e = resolveProperties(sc, e);
if (needInterpret)
i.exp = e.ctfeInterpret();
else
i.exp = e.optimize(WANTvalue);
}
}
// Look for the case of statically initializing an array with a single member.
// Recursively strip static array / enum layers until a compatible element is found,
// and return an `ArrayLiteralExp` repeating the initializer, or `null` if no match found
// int[2][3] = 7 => [[7, 7], [7, 7], [7, 7]]
// int[2] = new Object => null
Expression sarrayRepeat(Type tb)
{
auto tsa = tb.isTypeSArray();
if (!tsa)
return null;
// printf("i.exp = %s, tsa = %s\n", i.exp.toChars(), tsa.toChars());
Expression elem = null;
if (i.exp.implicitConvTo(tb.nextOf()))
elem = i.exp.implicitCastTo(sc, tb.nextOf());
else if (auto ae = sarrayRepeat(tb.nextOf().toBasetype()))
elem = ae;
else
return null;
auto arrayElements = new Expressions(cast(size_t) tsa.dim.toInteger());
foreach (ref e; *arrayElements)
e = elem;
return new ArrayLiteralExp(i.exp.loc, tb, elem, arrayElements);
}
if (auto sa = sarrayRepeat(tb))
{
// printf("sa = %s\n", sa.toChars());
i.exp = sa;
}
{
auto tta = t.isTypeSArray();
if (i.exp.implicitConvTo(t))
{
i.exp = i.exp.implicitCastTo(sc, t);
}
else if (sc.inCfile && i.exp.isStringExp() &&
tta && (tta.next.ty == Tint8 || tta.next.ty == Tuns8) &&
ti.ty == Tsarray && ti.nextOf().ty == Tchar)
{
/* unsigned char bbb[1] = "";
* signed char ccc[1] = "";
*/
i.exp = i.exp.castTo(sc, t);
}
else
{
auto tba = tb.isTypeSArray();
// Look for mismatch of compile-time known length to emit
// better diagnostic message, as same as AssignExp::semantic.
if (tba && i.exp.implicitConvTo(tba.next.arrayOf()) > MATCH.nomatch)
{
uinteger_t dim1 = tba.dim.toInteger();
uinteger_t dim2 = dim1;
if (auto ale = i.exp.isArrayLiteralExp())
{
dim2 = ale.elements ? ale.elements.length : 0;
}
else if (auto se = i.exp.isSliceExp())
{
if (Type tx = toStaticArrayType(se))
dim2 = tx.isTypeSArray().dim.toInteger();
}
if (dim1 != dim2)
{
error(i.exp.loc, "mismatched array lengths, %d and %d", cast(int)dim1, cast(int)dim2);
i.exp = ErrorExp.get();
}
}
Type et = i.exp.type;
const errors = global.startGagging();
i.exp = i.exp.implicitCastTo(sc, t);
if (global.endGagging(errors))
error(currExp.loc, "cannot implicitly convert expression `%s` of type `%s` to `%s`", currExp.toErrMsg(), et.toChars(), t.toChars());
}
}
L1:
if (i.exp.op == EXP.error)
{
return i;
}
if (needInterpret)
i.exp = i.exp.ctfeInterpret();
else
i.exp = i.exp.optimize(WANTvalue);
//printf("-ExpInitializer::semantic(): "); i.exp.print();
return i;
}
Initializer visitC(CInitializer ci)
{
//printf("CInitializer::semantic() tx: %s t: %s ci: %s\n", (tx ? tx.toChars() : "".ptr), t.toChars(), toChars(ci));
static if (0)
if (auto ts = tx.isTypeStruct())
{
import dmd.common.outbuffer;
OutBuffer buf;
HdrGenState hgs;
toCBuffer(ts.sym, buf, hgs);
printf("%s\n", buf.peekChars());
}
/* Rewrite CInitializer into ExpInitializer, ArrayInitializer, or StructInitializer
*/
t = t.toBasetype();
if (auto tv = t.isTypeVector())
t = tv.basetype;
/* If `{ expression }` return the expression initializer
*/
ExpInitializer isBraceExpression()
{
auto dil = ci.initializerList[];
return (dil.length == 1 && !dil[0].designatorList)
? dil[0].initializer.isExpInitializer()
: null;
}
/********************************
*/
bool overlaps(VarDeclaration field, VarDeclaration[] fields, StructInitializer si)
{
foreach (fld; fields)
{
if (field.isOverlappedWith(fld))
{
// look for initializer corresponding with fld
foreach (i, ident; si.field[])
{
if (ident == fld.ident && si.value[i])
return true; // already an initializer for `field`
}
}
}
return false;
}
/* Run semantic on ExpInitializer, see if it represents entire struct ts
*/
bool representsStruct(ExpInitializer ei, TypeStruct ts)
{
if (needInterpret)
sc = sc.startCTFE();
ei.exp = ei.exp.expressionSemantic(sc);
ei.exp = resolveProperties(sc, ei.exp);
if (needInterpret)
sc = sc.endCTFE();
return ei.exp.implicitConvTo(ts) != MATCH.nomatch; // initializer represents the entire struct
}
/* If { } are omitted from substructs, use recursion to reconstruct where
* brackets go
* Params:
* ts = substruct to initialize
* index = index into ci.initializer, updated
* Returns: struct initializer for this substruct
*/
Initializer subStruct()(TypeStruct ts, ref size_t index)
{
//printf("subStruct(ts: %s, index %d)\n", ts.toChars(), cast(int)index);
auto si = new StructInitializer(ci.loc);
StructDeclaration sd = ts.sym;
sd.size(ci.loc);
if (sd.sizeok != Sizeok.done)
{
index = ci.initializerList.length;
return err();
}
const nfields = sd.fields.length;
foreach (fieldi; 0 .. nfields)
{
if (index >= ci.initializerList.length)
break; // ran out of initializers
auto di = ci.initializerList[index];
if (di.designatorList && fieldi != 0)
break; // back to top level
VarDeclaration field;
while (1) // skip field if it overlaps with previously seen fields
{
field = sd.fields[fieldi];
++fieldi;
if (!overlaps(field, sd.fields[], si))
break;
if (fieldi == nfields)
break;
}
auto tn = field.type.toBasetype();
auto tnsa = tn.isTypeSArray();
auto tns = tn.isTypeStruct();
auto ix = di.initializer;
if (tnsa && ix.isExpInitializer())
{
ExpInitializer ei = ix.isExpInitializer();
if (ei.exp.isStringExp() && tnsa.nextOf().isIntegral())
{
si.addInit(field.ident, ei);
++index;
}
else
si.addInit(field.ident, subArray(tnsa, index)); // fwd ref of subArray is why subStruct is a template
}
else if (tns && ix.isExpInitializer())
{
/* Disambiguate between an exp representing the entire
* struct, and an exp representing the first field of the struct
*/
if (representsStruct(ix.isExpInitializer(), tns)) // initializer represents the entire struct
{
si.addInit(field.ident, initializerSemantic(ix, sc, tn, needInterpret));
++index;
}
else // field initializers for struct
si.addInit(field.ident, subStruct(tns, index)); // the first field
}
else
{
si.addInit(field.ident, ix);
++index;
}
}
//printf("subStruct() returns ai: %s, index: %d\n", si.toChars(), cast(int)index);
return si;
}
/* If { } are omitted from subarrays, use recursion to reconstruct where
* brackets go
* Params:
* tsa = subarray to initialize
* index = index into ci.initializer, updated
* Returns: array initializer for this subarray
*/
Initializer subArray(TypeSArray tsa, ref size_t index)
{
//printf("array(tsa: %s, index %d)\n", tsa.toChars(), cast(int)index);
if (tsa.isIncomplete())
{
// C11 6.2.5-20 "element type shall be complete whenever the array type is specified"
assert(0); // should have been detected by parser
}
auto tnsa = tsa.nextOf().toBasetype().isTypeSArray();
auto ai = new ArrayInitializer(ci.loc);
ai.isCarray = true;
foreach (n; 0 .. cast(size_t)tsa.dim.toInteger())
{
if (index >= ci.initializerList.length)
break; // ran out of initializers
auto di = ci.initializerList[index];
if (di.designatorList)
break; // back to top level
else if (tnsa && di.initializer.isExpInitializer())
{
ExpInitializer ei = di.initializer.isExpInitializer();
if (ei.exp.isStringExp() && tnsa.nextOf().isIntegral())
{
ai.addInit(null, ei);
++index;
}
else
ai.addInit(null, subArray(tnsa, index));
}
else
{
ai.addInit(null, di.initializer);
++index;
}
}
//printf("array() returns ai: %s, index: %d\n", ai.toChars(), cast(int)index);
return ai;
}
if (auto ts = t.isTypeStruct())
{
auto si = new StructInitializer(ci.loc);
StructDeclaration sd = ts.sym;
sd.size(ci.loc); // run semantic() on sd to get fields
if (sd.sizeok != Sizeok.done)
{
return err();
}
const nfields = sd.fields.length;
size_t fieldi = 0;
Loop1:
for (size_t index = 0; index < ci.initializerList.length; )
{
DesigInit di = ci.initializerList[index];
Designators* dlist = di.designatorList;
if (dlist)
{
const length = (*dlist).length;
if (length == 0 || !(*dlist)[0].ident)
{
error(ci.loc, "`.identifier` expected for C struct field initializer `%s`", toChars(ci));
return err();
}
if (length > 1)
{
error(ci.loc, "only 1 designator currently allowed for C struct field initializer `%s`", toChars(ci));
return err();
}
auto id = (*dlist)[0].ident;
foreach (k, f; sd.fields[]) // linear search for now
{
if (f.ident == id)
{
fieldi = k;
si.addInit(id, di.initializer);
++fieldi;
++index;
continue Loop1;
}
}
error(ci.loc, "`.%s` is not a field of `%s`\n", id.toChars(), sd.toChars());
return err();
}
if (fieldi == nfields)
break;
auto ix = di.initializer;
/* If a C initializer is wrapped in a C initializer, with no designators,
* peel off the outer one
*/
if (ix.isCInitializer())
{
CInitializer cix = ix.isCInitializer();
if (cix.initializerList.length == 1)
{
DesigInit dix = cix.initializerList[0];
if (!dix.designatorList)
{
Initializer inix = dix.initializer;
if (inix.isCInitializer())
ix = inix;
}
}
}
if (auto cix = ix.isCInitializer())
{
/* ImportC loses the structure from anonymous structs, but this is retained
* by the initializer syntax. if a CInitializer has a Designator, it is probably
* a nested anonymous struct
*/
int found;
foreach (dix; cix.initializerList)
{
Designators* dlistx = dix.designatorList;
if (!dlistx)
continue;
if ((*dlistx).length == 1 && (*dlistx)[0].ident)
{
auto id = (*dlistx)[0].ident;
foreach (k, f; sd.fields[]) // linear search for now
{
if (f.ident == id)
{
fieldi = k;
si.addInit(id, dix.initializer);
++fieldi;
++index;
++found;
break;
}
}
}
else {
error(ci.loc, "only 1 designator currently allowed for C struct field initializer `%s`", toChars(ci));
}
}
if (found == cix.initializerList.length)
continue Loop1;
}
VarDeclaration field;
while (1) // skip field if it overlaps with previously seen fields
{
field = sd.fields[fieldi];
++fieldi;
if (!overlaps(field, sd.fields[], si))
break;
if (fieldi == nfields)
break;
}
auto tn = field.type.toBasetype();
auto tnsa = tn.isTypeSArray();
auto tns = tn.isTypeStruct();
if (tnsa && ix.isExpInitializer())
{
ExpInitializer ei = ix.isExpInitializer();
if (ei.exp.isStringExp() && tnsa.nextOf().isIntegral())
{
si.addInit(field.ident, ei);
++index;
}
else
si.addInit(field.ident, subArray(tnsa, index));
}
else if (tns && ix.isExpInitializer())
{
/* Disambiguate between an exp representing the entire
* struct, and an exp representing the first field of the struct
*/
if (representsStruct(ix.isExpInitializer(), tns)) // initializer represents the entire struct
{
si.addInit(field.ident, initializerSemantic(ix, sc, tn, needInterpret));
++index;
}
else // field initializers for struct
si.addInit(field.ident, subStruct(tns, index)); // the first field
}
else
{
si.addInit(field.ident, di.initializer);
++index;
}
}
return initializerSemantic(si, sc, t, needInterpret);
}
else if (auto ta = t.isTypeSArray())
{
auto tn = t.nextOf().toBasetype(); // element type of array
/* If it's an array of integral being initialized by `{ string }`
* replace with `string`
*/
if (tn.isIntegral())
{
if (ExpInitializer ei = isBraceExpression())
{
if (ei.exp.isStringExp())
return ei.initializerSemantic(sc, t, needInterpret);
}
}
auto tnsa = tn.isTypeSArray(); // array of array
auto tns = tn.isTypeStruct(); // array of struct
auto ai = new ArrayInitializer(ci.loc);
ai.isCarray = true;
for (size_t index = 0; index < ci.initializerList.length; )
{
auto di = ci.initializerList[index];
if (auto dlist = di.designatorList)
{
const length = (*dlist).length;
if (length == 0 || !(*dlist)[0].exp)
{
error(ci.loc, "`[ constant-expression ]` expected for C array element initializer `%s`", toChars(ci));
return err();
}
if (length > 1)
{
error(ci.loc, "only 1 designator currently allowed for C array element initializer `%s`", toChars(ci));
return err();
}
//printf("tn: %s, di.initializer: %s\n", tn.toChars(), di.initializer.toChars());
auto ix = di.initializer;
if (tnsa && ix.isExpInitializer())
{
// Wrap initializer in [ ]
auto ain = new ArrayInitializer(ci.loc);
ain.addInit(null, di.initializer);
ix = ain;
ai.addInit((*dlist)[0].exp, initializerSemantic(ix, sc, tn, needInterpret));
++index;
}
else if (tns && ix.isExpInitializer())
{
/* Disambiguate between an exp representing the entire
* struct, and an exp representing the first field of the struct
*/
if (representsStruct(ix.isExpInitializer(), tns)) // initializer represents the entire struct
{
ai.addInit((*dlist)[0].exp, initializerSemantic(ix, sc, tn, needInterpret));