build.gradle

apply plugin: 'groovy'
apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'codenarc'
apply plugin: 'idea'

version = '1.0.0-SNAPSHOT'
group = 'com.github.groovy-wslite'

sourceCompatibility = 1.5
targetCompatibility = 1.5

//compileGroovy.options.compilerArgs = ['-Xlint:unchecked']

repositories {
    mavenCentral()
    mavenRepo url: 'http://m2repo.spockframework.org/releases'
}

dependencies {
    compile 'org.codehaus.groovy:groovy-all:1.7.6'
    testCompile('org.spockframework:spock-core:0.6-groovy-1.7') {
        exclude module: 'groovy-all'
    }
    testCompile 'cglib:cglib-nodep:2.2'
}

sourceSets {
    integrationTest {
        compileClasspath = sourceSets.main.output + configurations.testRuntime
        runtimeClasspath = output + sourceSets.main.output + configurations.testRuntime
        groovy {
            srcDir 'src/integrationTest/groovy'
        }
    }
}

task sourcesJar(type: Jar, dependsOn: classes) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

task javadocJar(type: Jar, dependsOn: javadoc) {
    classifier = 'javadoc'
    from javadoc.destinationDir
}

task groovydocJar(type: Jar, dependsOn: groovydoc) {
    classifier = 'groovydoc'
    from groovydoc.destinationDir
}

task integrationTest(type: Test) {
    testClassesDir = sourceSets.integrationTest.output.classesDir
    classpath = sourceSets.integrationTest.runtimeClasspath
}

tasks.withType(CodeNarc) {
    ignoreFailures = true
    configFile = file("$rootProject.projectDir/config/codenarc/codenarc.groovy")
}

build.dependsOn integrationTest

artifacts {
    archives jar, sourcesJar, javadocJar, groovydocJar
}

signing {
    required {
        gradle.taskGraph.hasTask("uploadArchives") 
    }
    sign configurations.archives
}

uploadArchives {
    // Should be set in gradle.properties (check gradle.properties.sample)
    if (['mavenUsername', 'mavenPassword'].every { project.hasProperty(it) }) {
       repositories {
            mavenDeployer {
                beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

                snapshotRepository(url: 'https://oss.sonatype.org/content/repositories/snapshots/') {
                    authentication(userName: mavenUsername, password: mavenPassword)
                }

                repository(url: 'https://oss.sonatype.org/service/local/staging/deploy/maven2/') {
                    authentication(userName: mavenUsername, password: mavenPassword)
                }

                pom.project {
                    name 'groovy-wslite'
                    description 'Lightweight SOAP and REST webservice clients for Groovy'
                    url 'https://github.com/jwagenleitner/groovy-wslite'
                    inceptionYear '2011'
                    licenses {
                        license {
                            name 'The Apache Software License, Version 2.0'
                            url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
                            distribution 'repo'
                        }
                    }
                    scm {
                        url 'scm:git:git@github.com:jwagenleitner/groovy-wslite.git'
                        connection 'https://github.com/jwagenleitner/groovy-wslite'
                    }
                    developers {
                        developer {
                            id 'jwagenleitner'
                            name 'John Wagenleitner'
                            email 'john.wagenleitner@gmail.com'
                            roles {
                                role 'Lead'
                                role 'Founder'
                            }
                        }
                    }
                }
            }
        }
    }
}

task wrapper(type: Wrapper) {
    gradleVersion = '1.7'
}