build.gradle

ext {
  VERSION = project.findProperty('version')
  VCS_URL = 'https://github.com/sava-software/sava'
}

final JLV = JavaLanguageVersion.of(project.findProperty('javaVersion') as Integer ?: 23)
final GPR_USER = project.findProperty("gpr.user") ?: System.getenv("GITHUB_ACTOR")
final GPR_TOKEN = project.findProperty("gpr.token") ?: System.getenv("GITHUB_TOKEN")

subprojects {
  apply plugin: 'java-library'
  apply plugin: 'maven-publish'
  // apply plugin: 'signing'

  project.group = 'software.sava'
  project.version = "$VERSION"

  plugins.withType(JavaPlugin).configureEach {
    java {
      modularity.inferModulePath = true
      toolchain {
        languageVersion = JLV
      }
    }
  }

  repositories {
    maven {
      url = "https://maven.pkg.github.com/comodal/json-iterator"
      credentials {
        username = GPR_USER
        password = GPR_TOKEN
      }
    }
    mavenCentral()
  }

  dependencies {
    testImplementation libs.junit.jupiter
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
  }

  test {
    useJUnitPlatform()
    testLogging {
      events "passed", "skipped", "failed", "standardOut", "standardError"
      exceptionFormat = "full"
      showStandardStreams = true
    }
  }

  java {
    withJavadocJar()
    withSourcesJar()
  }

  tasks.withType(Javadoc).configureEach {
    options.addStringOption('Xdoclint:none', '-quiet')
  }

  publishing {
    publications {
      mavenJava(MavenPublication) {
        from components.java

        groupId = project.group
        artifactId = project.parent.name + '-' + project.name
        version = project.version

        pom {
          name = project.parent.name + '-' + project.name
          description = "Solana Java Core & RPC SDK"
          url = "$VCS_URL"
          licenses {
            license {
              name = 'MIT License'
              url = 'https://github.com/sava-software/sava/blob/main/LICENSE'
            }
          }
          developers {
            developer {
              name = 'Jim'
              id = 'jpe7s'
              email = 'jpe7s.salt188@passfwd.com'
              organization = 'Sava Software'
              organizationUrl = 'https://github.com/sava-software'
            }
          }
          scm {
            connection = 'scm:git:git@github.com:sava-software/sava.git'
            developerConnection = 'scm:git:ssh@github.com:sava-software/sava.git'
            url = "$VCS_URL"
          }
        }
      }
    }

    repositories {
      maven {
        name = "GithubPackages"
        url = "https://maven.pkg.github.com/sava-software/sava"
        credentials {
          username = System.getenv("GITHUB_ACTOR") ?: project.findProperty("gpr.user.write")
          password = System.getenv("GITHUB_TOKEN") ?: project.findProperty("gpr.token.write")
        }
      }
    }
  }

//  signing {
//    sign publishing.publications.mavenJava
//  }
}