forked from svaante/dape
-
Notifications
You must be signed in to change notification settings - Fork 0
/
dape.el
4189 lines (3839 loc) · 172 KB
/
dape.el
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
;;; dape.el --- Debug Adapter Protocol for Emacs -*- lexical-binding: t -*-
;; Copyright (C) 2023 Free Software Foundation, Inc.
;; Author: Daniel Pettersson
;; Maintainer: Daniel Pettersson <[email protected]>
;; Created: 2023
;; License: GPL-3.0-or-later
;; Version: 0.5.0
;; Homepage: https://github.com/svaante/dape
;; Package-Requires: ((emacs "29.1") (jsonrpc "1.0.21"))
;; This file is not part of GNU Emacs.
;; This program is free software: you can redistribute it and/or modify
;; it under the terms of the GNU General Public License as published by
;; the Free Software Foundation, either version 3 of the License, or
;; (at your option) any later version.
;; This program is distributed in the hope that it will be useful,
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
;; GNU General Public License for more details.
;; You should have received a copy of the GNU General Public License
;; along with this program. If not, see <http://www.gnu.org/licenses/>.
;;; Commentary:
;; This package is an debug adapter client for Emacs.
;; Use `dape-configs' to set up your debug adapter configurations.
;; To initiate debugging sessions, use the command `dape'.
;; Note:
;; For complete functionality, it's essential to activate `eldoc-mode'
;; in your source buffers and enable `repeat-mode' for ergonomics
;; Package looks is heavily inspired by gdb-mi.el
;;; Code:
(require 'cl-lib)
(require 'subr-x)
(require 'seq)
(require 'font-lock)
(require 'pulse)
(require 'comint)
(require 'repeat)
(require 'compile)
(require 'tree-widget)
(require 'project)
(require 'gdb-mi)
(require 'tramp)
(require 'jsonrpc)
(require 'eglot) ;; jdtls config
(unless (package-installed-p 'jsonrpc '(1 0 21))
(error "dape: Requires jsonrpc version >= 1.0.21, use `list-packages'\
to install latest `jsonrpc' release from elpa"))
;;; Custom
(defgroup dape nil
"Debug Adapter Protocol for Emacs."
:prefix "dape-"
:group 'applications)
(defcustom dape-adapter-dir
(file-name-as-directory (concat user-emacs-directory "debug-adapters"))
"Directory to store downloaded adapters in."
:type 'string)
(defcustom dape-configs
`((attach
modes nil
ensure (lambda (config)
(unless (plist-get config 'port)
(user-error "Missing `port' property")))
host "localhost"
:request "attach")
(launch
modes nil
command-cwd dape-command-cwd
ensure (lambda (config)
(unless (plist-get config 'command)
(user-error "Missing `command' property")))
:request "launch")
,@(let ((codelldb
`(ensure dape-ensure-command
command-cwd dape-command-cwd
command ,(file-name-concat dape-adapter-dir
"codelldb"
"extension"
"adapter"
"codelldb")
port :autoport
fn dape-config-autoport
:type "lldb"
:request "launch"
:cwd "."
:args [])))
`((codelldb-cc
modes (c-mode c-ts-mode c++-mode c++-ts-mode)
command-args ("--port" :autoport)
,@codelldb
:program "a.out")
(codelldb-rust
modes (rust-mode rust-ts-mode)
command-args ("--port" :autoport
"--settings" "{\"sourceLanguages\":[\"rust\"]}")
,@codelldb
:program ,(defun dape--rust-program ()
(file-name-concat "target" "debug"
(thread-first (dape-cwd)
(directory-file-name)
(file-name-split)
(last)
(car)))))))
(cpptools
modes (c-mode c-ts-mode c++-mode c++-ts-mode)
ensure dape-ensure-command
command-cwd dape-command-cwd
command ,(file-name-concat dape-adapter-dir
"cpptools"
"extension"
"debugAdapters"
"bin"
"OpenDebugAD7")
:type "cppdbg"
:request "launch"
:cwd "."
:program "a.out"
:MIMode ,(seq-find 'executable-find '("lldb" "gdb")))
(debugpy
modes (python-mode python-ts-mode)
ensure (lambda (config)
(dape-ensure-command config)
(let ((python
(dape--config-eval-value (plist-get config 'command))))
(unless (zerop
(call-process-shell-command
(format "%s -c \"import debugpy.adapter\"" python)))
(user-error "%s module debugpy is not installed" python))))
fn (dape-config-autoport dape-config-tramp)
command "python"
command-args ("-m" "debugpy.adapter" "--host" "0.0.0.0" "--port" :autoport)
port :autoport
:request "launch"
:type "executable"
:cwd dape-cwd
:program dape-buffer-default
:justMyCode nil
:console "integratedTerminal"
:showReturnValue t
:stopAtEntry t)
(dlv
modes (go-mode go-ts-mode)
ensure dape-ensure-command
fn (dape-config-autoport dape-config-tramp)
command "dlv"
command-args ("dap" "--listen" "127.0.0.1::autoport")
command-cwd dape-command-cwd
port :autoport
:request "launch"
:type "debug"
:cwd "."
:program ".")
(flutter
ensure dape-ensure-command
modes (dart-mode)
command "flutter"
command-args ("debug_adapter")
command-cwd dape-command-cwd
:type "dart"
:cwd "."
:program "lib/main.dart"
:toolArgs ["-d" "all"])
(godot
modes (gdscript-mode)
port 6006
:request "launch"
:type "server"
:cwd dape-cwd)
,@(let ((js-debug
`(modes (js-mode js-ts-mode typescript-mode typescript-ts-mode)
ensure ,(lambda (config)
(dape-ensure-command config)
(let ((js-debug-file
(file-name-concat
(dape--config-eval-value (plist-get config 'command-cwd))
(dape--config-eval-value (car (plist-get config 'command-args))))))
(unless (file-exists-p js-debug-file)
(user-error "File %S does not exist" js-debug-file))))
command "node"
command-args (,(expand-file-name
(file-name-concat dape-adapter-dir
"js-debug"
"src"
"dapDebugServer.js"))
:autoport)
port :autoport
fn dape-config-autoport)))
`((js-debug-node
,@js-debug
:type "pwa-node"
:cwd dape-cwd
:program dape-buffer-default
:outputCapture "console"
:sourceMapRenames t
:pauseForSourceMap nil
:autoAttachChildProcesses t
:console "internalConsole"
:killBehavior "forceful")
(js-debug-chrome
,@js-debug
:type "pwa-chrome"
:trace t
:url "http://localhost:3000"
:webRoot dape-cwd
:outputCapture "console")))
(lldb-vscode
modes (c-mode c-ts-mode c++-mode c++-ts-mode rust-mode rust-ts-mode)
ensure dape-ensure-command
command-cwd dape-command-cwd
command "lldb-vscode"
:type "lldb-vscode"
:cwd "."
:program "a.out")
(netcoredbg
modes (csharp-mode csharp-ts-mode)
ensure dape-ensure-command
command "netcoredbg"
command-args ["--interpreter=vscode"]
:request "launch"
:cwd dape-cwd
:program ,(defun dape--netcoredbg-program ()
(let ((dlls
(file-expand-wildcards
(file-name-concat "bin" "Debug" "*" "*.dll"))))
(if dlls
(file-relative-name
(file-relative-name (car dlls)))
".dll"
(dape-cwd))))
:stopAtEntry nil)
(rdbg
modes (ruby-mode ruby-ts-mode)
ensure dape-ensure-command
command "rdbg"
command-args ("-O" "--host" "0.0.0.0" "--port" :autoport "-c" "--" :-c)
fn ((lambda (config)
(plist-put config 'command-args
(mapcar (lambda (arg)
(if (eq arg :-c)
(plist-get config '-c)
arg))
(plist-get config 'command-args))))
dape-config-autoport
dape-config-tramp)
port :autoport
command-cwd dape-command-cwd
:type "Ruby"
;; -- examples:
;; rails server
;; bundle exec ruby foo.rb
;; bundle exec rake test
-c ,(defun dape--rdbg-c ()
(format "ruby %s"
(or (dape-buffer-default) ""))))
(jdtls
modes (java-mode java-ts-mode)
ensure (lambda (config)
(let ((file (thread-first (plist-get config :filePath)
(dape--config-eval-value))))
(unless (and (stringp file) (file-exists-p file))
(thread-first (plist-get config :filePath)
(dape--config-eval-value))
(user-error "Unable to find locate :filePath `%s'" file))
(with-current-buffer (find-file-noselect file)
(unless (eglot-current-server)
(user-error "No eglot instance active in buffer %s" (current-buffer)))
(unless (seq-contains-p (eglot--server-capable :executeCommandProvider :commands)
"vscode.java.resolveClasspath")
(user-error "jdtls instance does not bundle java-debug-server, please install")))))
fn (lambda (config)
(with-current-buffer (thread-first (plist-get config :filePath)
(dape--config-eval-value)
(find-file-noselect))
(if-let ((server (eglot-current-server)))
(pcase-let ((`[,module-paths ,class-paths]
(eglot-execute-command server
"vscode.java.resolveClasspath"
(vector (plist-get config :mainClass)
(plist-get config :projectName))))
(port (eglot-execute-command server
"vscode.java.startDebugSession" nil)))
(thread-first config
(plist-put 'port port)
(plist-put :modulePaths module-paths)
(plist-put :classPaths class-paths)))
server)))
,@(cl-flet ((resolve-main-class (key)
(ignore-errors
(pcase-let ((`[,main-class]
(eglot-execute-command
(eglot-current-server)
"vscode.java.resolveMainClass"
(file-name-nondirectory (directory-file-name (dape-cwd))))))
(plist-get main-class key)))))
`(:filePath
,(defun dape--jdtls-file-path ()
(or (resolve-main-class :filePath)
(expand-file-name (dape-buffer-default) (dape-cwd))))
:mainClass
,(defun dape--jdtls-main-class ()
(or (resolve-main-class :mainClass) ""))
:projectName
,(defun dape--jdtls-project-name ()
(or (resolve-main-class :projectName) ""))))
:args ""
:stopOnEntry nil
:type "java"
:request "launch"
:vmArgs " -XX:+ShowCodeDetailsInExceptionMessages"
:console "integratedConsole"
:internalConsoleOptions "neverOpen"))
"This variable holds the Dape configurations as an alist.
In this alist, the car element serves as a symbol identifying each
configuration. Each configuration, in turn, is a property list (plist)
where keys can be symbols or keywords.
Symbol Keys (Used by Dape):
- fn: Function or list of functions, takes config and returns config.
If list functions are applied in order. Used for hiding unnecessary
configuration details from config history.
- ensure: Function to ensure that adapter is available.
- command: Shell command to initiate the debug adapter.
- command-args: List of string arguments for the command.
- command-cwd: Working directory for the command.
- prefix-local: Defines the source path prefix, accessible from Emacs.
- prefix-remote: Defines the source path prefix, accessible by the adapter.
- host: Host of the debug adapter.
- port: Port of the debug adapter.
- modes: List of modes where the configuration is active in `dape'
completions.
- compile: Executes a shell command with `dape-compile-fn'.
Debug adapter conn in configuration:
- If only command is specified (without host and port), Dape
will communicate with the debug adapter through stdin/stdout.
- If both host and port are specified, Dape will connect to the
debug adapter. If `command is specified, Dape will wait until the
command is initiated before it connects with host and port.
Keywords in configuration:
Keywords are transmitted to the adapter during the initialize and
launch/attach requests. Refer to `json-serialize' for detailed
information on how Dape serializes these keyword elements. Dape
uses nil as false.
Functions and symbols in configuration:
If a value in a key is a function, the function's return value will
replace the key's value before execution.
If a value in a key is a symbol, the symbol will recursively resolve
at runtime."
:type '(alist :key-type (symbol :tag "Name")
:value-type
(plist :options
(((const :tag "List of modes where config is active in `dape' completions" modes) (repeat function))
((const :tag "Ensures adapter availability" ensure) function)
((const :tag "Transforms configuration at runtime" fn) (choice function (repeat function)))
((const :tag "Shell command to initiate the debug adapter" command) (choice string symbol))
((const :tag "List of string arguments for command" command-args) (repeat string))
((const :tag "Working directory for command" command-cwd) (choice string symbol))
((const :tag "Path prefix for local src paths" prefix-local) string)
((const :tag "Path prefix for remote src paths" prefix-remote) string)
((const :tag "Host of debug adapter" host) string)
((const :tag "Port of debug adapter" port) natnum)
((const :tag "Compile cmd" compile) string)
((const :tag "Adapter type" :type) string)
((const :tag "Request type launch/attach" :request) string)))))
(defcustom dape-command nil
"Initial contents for `dape' completion.
Sometimes it is useful for files or directories to supply local values
for this variable.
Example value:
\(codelldb-cc :program \"/home/user/project/a.out\")"
:type 'sexp)
;; TODO Add more defaults, don't know which adapters support
;; sourceReference
(defcustom dape-mime-mode-alist '(("text/x-lldb.disassembly" . asm-mode)
("text/javascript" . js-mode))
"Alist of MIME types vs corresponding major mode functions.
Each element should look like (MIME-TYPE . MODE) where
MIME-TYPE is a string and MODE is the major mode function to
use for buffers of this MIME type."
:type '(alist :key-type string :value-type function))
(defcustom dape-key-prefix "\C-x\C-a"
"Prefix of all dape commands."
:type 'key-sequence)
(defcustom dape-display-source-buffer-action
'(display-buffer-same-window)
"`display-buffer' action used when displaying source buffer."
:type 'sexp)
(define-obsolete-variable-alias
'dape-buffer-window-arrangment
'dape-buffer-window-arrangement "0.3.0")
(defcustom dape-buffer-window-arrangement 'left
"Rules for display dape buffers."
:type '(choice (const :tag "GUD gdb like" gud)
(const :tag "Left side" left)
(const :tag "Right side" right)))
(defcustom dape-stepping-granularity 'line
"The granularity of one step in the stepping requests."
:type '(choice (const :tag "Step statement" statement)
(const :tag "Step line" line)
(const :tag "Step instruction" instruction)))
(defcustom dape-on-start-hooks '(dape-repl dape-info)
"Hook to run on session start."
:type 'hook)
(defcustom dape-on-stopped-hooks '(dape--emacs-grab-focus)
"Hook to run on session stopped."
:type 'hook)
(defcustom dape-update-ui-hooks '(dape-info-update)
"Hook to run on ui update."
:type 'hook)
(defcustom dape-read-memory-default-count 1024
"The default count for `dape-read-memory'."
:type 'natnum)
(defcustom dape-info-hide-mode-line
(and (memql dape-buffer-window-arrangement '(left right)) t)
"Hide mode line in dape info buffers."
:type 'boolean)
(defcustom dape-info-variable-table-aligned nil
"Align columns in variable tables."
:type 'boolean)
(defcustom dape-info-variable-table-row-config `((name . 20)
(value . 50)
(type . 20))
"Configuration for table rows of variables.
An alist that controls the display of the name, type and value of
variables. The key controls which column to change whereas the
value determines the maximum number of characters to display in each
column. A value of 0 means there is no limit.
Additionally, the order the element in the alist determines the
left-to-right display order of the properties."
:type '(alist :key-type symbol :value-type integer))
(defcustom dape-info-thread-buffer-verbose-names t
"Show long thread names in threads buffer."
:type 'boolean)
(defcustom dape-info-thread-buffer-locations t
"Show file information or library names in threads buffer."
:type 'boolean)
(defcustom dape-info-thread-buffer-addresses t
"Show addresses for thread frames in threads buffer."
:type 'boolean)
(defcustom dape-info-stack-buffer-locations t
"Show file information or library names in stack buffers."
:type 'boolean)
(defcustom dape-info-stack-buffer-addresses t
"Show frame addresses in stack buffers."
:type 'boolean)
(defcustom dape-info-buffer-variable-format 'line
"How variables are formatted in *dape-info* buffer."
:type '(choice (const :tag "Truncate string at new line" line)
(const :tag "No formatting" nil)))
(defcustom dape-info-header-scope-max-name 15
"Max length of scope name in `header-line-format'."
:type 'integer)
(defcustom dape-info-file-name-max 30
"Max length of file name in dape info buffers."
:type 'integer)
(defcustom dape-breakpoint-margin-string "B"
"String to display breakpoint in margin."
:type 'string)
(defcustom dape-repl-use-shorthand t
"Dape `dape-repl-commands' can be invokend with first char of command."
:type 'boolean)
(defcustom dape-repl-commands
'(("debug" . dape)
("next" . dape-next)
("continue" . dape-continue)
("pause" . dape-pause)
("step" . dape-step-in)
("out" . dape-step-out)
("restart" . dape-restart)
("kill" . dape-kill)
("disconnect" . dape-disconnect-quit)
("quit" . dape-quit))
"Dape commands available in REPL buffer."
:type '(alist :key-type string
:value-type function))
(defcustom dape-compile-fn #'compile
"Function to run compile with."
:type 'function)
(defcustom dape-cwd-fn #'dape--default-cwd
"Function to get current working directory.
The function should take one optional argument and return a string
representing the absolute file path of the current working directory.
If the optional argument is non nil return path with tramp prefix
otherwise the path should be without prefix.
See `dape--default-cwd'."
:type 'function)
(defcustom dape-compile-compile-hooks nil
"Hook run after dape compilation succeded.
The hook is run with one argument, the compilation buffer."
:type 'hook)
(defcustom dape-minibuffer-hint-ignore-properties
'(ensure fn modes command command-args :type :request)
"Properties to be hidden in `dape--minibuffer-hint'."
:type '(repeat symbol))
(defcustom dape-minibuffer-hint t
"Show hints in mini buffer."
:type 'boolean)
(defcustom dape-debug nil
"Print debug info in *dape-repl* and *dape-connection events*."
:type 'boolean)
;;; Face
(defface dape-breakpoint
'((t :inherit (font-lock-keyword-face)))
"Face used to display breakpoint overlays.")
(defface dape-log
'((t :inherit (font-lock-string-face)
:height 0.85 :box (:line-width -1)))
"Face used to display log breakpoints.")
(defface dape-expression
'((t :inherit (dape-breakpoint)
:height 0.85 :box (:line-width -1)))
"Face used to display conditional breakpoints.")
(defface dape-exception-description
'((t :inherit (error tooltip)))
"Face used to display exception descriptions inline.")
(defface dape-stack-trace
'((t :extend t))
"Face used to display stack trace overlays.")
(defface dape-repl-success
'((t :inherit compilation-mode-line-exit :extend t))
"Face used in repl for exit code 0.")
(defface dape-repl-error
'((t :inherit compilation-mode-line-fail :extend t))
"Face used in repl for non 0 exit codes.")
;;; Vars
(defvar dape-history nil
"History variable for `dape'.")
(defvar dape--source-buffers nil
"Plist of sources reference to buffer.")
(defvar dape--breakpoints nil
"List of session breakpoint overlays.")
(defvar dape--exceptions nil
"List of available exceptions as plists.")
(defvar dape--watched nil
"List of watched expressions.")
(defvar dape--connection nil
"Debug adapter connection.")
(defvar-local dape--source nil
"Store source plist in fetched source buffer.")
(defvar dape--repl-insert-text-guard nil
"Guard var for *dape-repl* buffer text updates.")
(define-minor-mode dape-active-mode
"On when dape debuggin session is active.
Non interactive global minor mode."
:global t
:interactive nil)
;;; Utils
(defmacro dape--callback (&rest body)
"Create callback lambda for `dape-request' with BODY.
Binds CONN, BODY and ERROR-MESSAGE.
Where BODY is assumed to be response body and ERROR-MESSAGE an error
string if the request where unsuccessfully or if the request timed out."
`(lambda (&optional conn body error-message)
(ignore conn body error-message)
,@body))
(defmacro dape--with (request-fn args &rest body)
"Call `dape-request' like REQUEST-FN with ARGS and BODY."
(declare (indent 2))
`(,request-fn ,@args (dape--callback ,@body)))
(defun dape--next-like-command (conn command)
"Helper for interactive step like commands.
Run step like COMMAND on CONN. If ARG is set run COMMAND ARG times."
(if (dape--stopped-threads conn)
(dape--with dape-request
(conn
command
`(,@(dape--thread-id-object conn)
,@(when (dape--capable-p conn :supportsSteppingGranularity)
(list :granularity
(symbol-name dape-stepping-granularity)))))
(unless error-message
(dape--update-state conn 'running)
(dape--remove-stack-pointers)
(dolist (thread (dape--threads conn))
(plist-put thread :status "running"))
(run-hooks 'dape-update-ui-hooks)))
(user-error "No stopped threads")))
(defun dape--thread-id-object (conn)
"Construct a thread id object for CONN."
(when-let ((thread-id (dape--thread-id conn)))
(list :threadId thread-id)))
(defun dape--stopped-threads (conn)
"List of stopped threads for CONN."
(and conn
(mapcan (lambda (thread)
(when (equal (plist-get thread :status) "stopped")
(list thread)))
(dape--threads conn))))
(defun dape--current-thread (conn)
"Current thread plist for CONN."
(and conn
(seq-find (lambda (thread)
(eq (plist-get thread :id) (dape--thread-id conn)))
(dape--threads conn))))
(defun dape--path (conn path format)
"Translate PATH to FORMAT from CONN config.
Accepted FORMAT values is `local' and `remote'.
See `dape-config' keywords `prefix-local' `prefix-remote'."
(if-let* ((config (and conn (dape--config conn)))
((or (plist-member config 'prefix-local)
(plist-member config 'prefix-remote)))
(prefix-local (or (plist-get config 'prefix-local)
""))
(prefix-remote (or (plist-get config 'prefix-remote)
""))
(mapping (pcase format
('local (cons prefix-remote prefix-local))
('remote (cons prefix-local prefix-remote))
(_ (error "Unknown format")))))
(concat
(cdr mapping)
(string-remove-prefix (car mapping) path))
path))
(defun dape--capable-p (conn of)
"If CONN capable OF."
(eq (plist-get (dape--capabilities conn) of) t))
(defun dape--current-stack-frame (conn)
"Current stack frame plist for CONN."
(let* ((stack-frames (thread-first
(dape--current-thread conn)
(plist-get :stackFrames)))
(stack-frames-with-source
(seq-filter (lambda (stack-frame)
(let* ((source (plist-get stack-frame :source))
(path (plist-get source :path))
(source-reference (or (plist-get source :sourceReference) 0)))
(or path (not (zerop source-reference)))))
stack-frames)))
(or (seq-find (lambda (stack-frame)
(eq (plist-get stack-frame :id)
(dape--stack-id conn)))
stack-frames-with-source)
(car stack-frames-with-source)
(car stack-frames))))
(defun dape--object-to-marker (plist)
"Create marker from dap PLIST containing source information.
Note requires `dape--source-ensure' if source is by reference."
(when-let ((source (plist-get plist :source))
(line (or (plist-get plist :line) 1))
(buffer
(or (when-let* ((source-reference
(plist-get source :sourceReference))
(buffer (plist-get dape--source-buffers
source-reference))
((buffer-live-p buffer)))
buffer)
(when-let* ((path (plist-get source :path))
(path (dape--path (dape--live-connection t)
path 'local))
((file-exists-p path))
(buffer (find-file-noselect path t)))
buffer))))
(with-current-buffer buffer
(save-excursion
(goto-char (point-min))
(forward-line (1- line))
(when-let ((column (plist-get plist :column)))
(when (> column 0)
(forward-char (1- column))))
(point-marker)))))
(defun dape--default-cwd ()
"Try to guess current project absolute file path with `project'."
(or (when-let ((project (project-current)))
(expand-file-name (project-root project)))
default-directory))
(defun dape-cwd ()
"Use `dape-cwd-fn' to guess current working as local path."
(tramp-file-local-name (funcall dape-cwd-fn)))
(defun dape-command-cwd ()
"Use `dape-cwd-fn' to guess current working directory."
(funcall dape-cwd-fn))
(defun dape-buffer-default ()
"Return current buffers file name."
(tramp-file-local-name
(file-relative-name (buffer-file-name) (dape-command-cwd))))
(defun dape--guess-root (config)
"Guess adapter path root from CONFIG."
;; FIXME We need some property on the adapter telling us how it
;; decided on root
;; FIXME Is this function meant to return root emacs world (with tramp)
;; or adapter world w/o tramp?
(let ((cwd (plist-get config :cwd))
(command-cwd (plist-get config 'command-cwd)))
(cond
((and cwd (stringp cwd) (file-name-absolute-p cwd))
cwd)
((stringp command-cwd) command-cwd)
(t default-directory))))
(defun dape-config-autoport (config)
"Replace :autoport in CONFIG keys `command-args' and `port'.
If `port' is `:autoport' replaces with open port, if not replaces
with value of `port' instead.
Replaces symbol and string occurences of \"autoport\"."
;; Stolen from `Eglot'
(let ((port (plist-get config 'port)))
(when (eq (plist-get config 'port) :autoport)
(let ((port-probe (make-network-process :name "dape-port-probe-dummy"
:server t
:host "localhost"
:service 0)))
(setq port
(unwind-protect
(process-contact port-probe :service)
(delete-process port-probe)))))
(let ((command-args (seq-map (lambda (item)
(cond
((eq item :autoport)
(number-to-string port))
((stringp item)
(string-replace ":autoport"
(number-to-string port)
item))))
(plist-get config 'command-args))))
(thread-first config
(plist-put 'port port)
(plist-put 'command-args command-args)))))
(defun dape-config-tramp (config)
"Infer `prefix-local' and `host' on CONFIG if in tramp context."
(when-let* ((default-directory
(or (plist-get config 'command-cwd)
default-directory))
((tramp-tramp-file-p default-directory))
(parts (tramp-dissect-file-name default-directory)))
(when (and (not (plist-get config 'prefix-local))
(not (plist-get config 'prefix-remote))
(plist-get config 'command))
(plist-put config 'prefix-local
(tramp-completion-make-tramp-file-name
(tramp-file-name-method parts)
(tramp-file-name-user parts)
(tramp-file-name-host parts)
"")))
(when (and (plist-get config 'command)
(plist-get config 'port)
(not (plist-get config 'host))
(equal (tramp-file-name-method parts) "ssh"))
(plist-put config 'host (file-remote-p default-directory 'host))))
config)
(defun dape-ensure-command (config)
"Ensure that `command' from CONFIG exist system."
(let ((command
(dape--config-eval-value (plist-get config 'command))))
(unless (or (file-executable-p command)
(executable-find command t))
(user-error "Unable to locate %S with default-directory %s"
command default-directory))))
(defun dape--overlay-region (&optional extended)
"List of beg and end of current line.
If EXTENDED end of line is after newline."
(list (line-beginning-position)
(if extended
(line-beginning-position 2)
(1- (line-beginning-position 2)))))
(defun dape--variable-string (plist)
"Formats dap variable PLIST to string."
(let ((name (plist-get plist :name))
(value (or (plist-get plist :value)
(plist-get plist :result)))
(type (plist-get plist :type)))
(concat
(propertize name
'face 'font-lock-variable-name-face)
(unless (or (null value)
(string-empty-p value))
(format " = %s"
(propertize value
'face 'font-lock-number-face)))
(unless (or (null type)
(string-empty-p type))
(format ": %s"
(propertize type
'face 'font-lock-type-face))))))
(defun dape--format-file-line (file line)
"Formats FILE and LINE to string."
(let* ((conn (dape--live-connection t))
(config
(and conn
;; If child connection check parent
(or (and-let* ((parent (dape--parent conn)))
(dape--config parent))
(dape--config conn))))
(root-guess (dape--guess-root config))
;; Normalize paths for `file-relative-name'
(file (tramp-file-local-name file))
(root-guess (tramp-file-local-name root-guess)))
(concat
(string-truncate-left (file-relative-name file root-guess)
dape-info-file-name-max)
(when line
(format ":%d" line)))))
(defun dape--kill-buffers (&optional skip-process-buffers)
"Kill all Dape related buffers.
On SKIP-PROCESS-BUFFERS skip deletion of buffers which has processes."
(thread-last (buffer-list)
(seq-filter (lambda (buffer)
(unless (and skip-process-buffers
(get-buffer-process buffer))
(string-match-p "\\*dape-.+\\*" (buffer-name buffer)))))
(seq-do (lambda (buffer)
(condition-case err
(let ((window (get-buffer-window buffer)))
(kill-buffer buffer)
(when (window-live-p window)
(delete-window window)))
(error
(message (error-message-string err))))))))
(defun dape--display-buffer (buffer)
"Display BUFFER according to `dape-buffer-window-arrangement'."
(display-buffer
buffer
(let ((mode (with-current-buffer buffer major-mode)))
(pcase dape-buffer-window-arrangement
((or 'left 'right)
(cons '(display-buffer-in-side-window)
(pcase mode
('dape-repl-mode '((side . bottom) (slot . -1)))
('shell-mode '((side . bottom) (slot . 0)))
((or 'dape-info-scope-mode 'dape-info-watch-mode)
`((side . ,dape-buffer-window-arrangement) (slot . -1)))
((or 'dape-info-stack-mode 'dape-info-modules-mode
'dape-info-sources-mode)
`((side . ,dape-buffer-window-arrangement) (slot . 0)))
((or 'dape-info-breakpoints-mode 'dape-info-threads-mode)
`((side . ,dape-buffer-window-arrangement) (slot . 1)))
(_ (error "Unable to display buffer of mode `%s'" mode)))))
('gud
(pcase mode
('dape-repl-mode
'((display-buffer-in-side-window) (side . top) (slot . -1)))
('shell-mode
'((display-buffer-reuse-window)
(display-buffer-pop-up-window) (direction . right) (dedicated . t)))
((or 'dape-info-scope-mode 'dape-info-watch-mode)
'((display-buffer-in-side-window) (side . top) (slot . 0)))
((or 'dape-info-stack-mode 'dape-info-modules-mode
'dape-info-sources-mode)
'((display-buffer-in-side-window) (side . bottom) (slot . -1)))
((or 'dape-info-breakpoints-mode 'dape-info-threads-mode)
'((display-buffer-in-side-window) (side . bottom) (slot . 1)))
(_ (error "Unable to display buffer of mode `%s'" mode))))
(_ (user-error "Invalid value of `dape-buffer-window-arrangement'"))))))
(defmacro dape--mouse-command (name doc command)
"Create mouse command with NAME, DOC which runs COMMANDS."
(declare (indent 1))
`(defun ,name (event)
,doc
(interactive "e")
(save-selected-window
(let ((start (event-start event)))
(select-window (posn-window start))
(save-excursion
(goto-char (posn-point start))
(call-interactively ',command))))))
(defun dape--emacs-grab-focus ()
"If `display-graphic-p' focus emacs."
(select-frame-set-input-focus (selected-frame)))
;;; Connection
(defun dape--live-connection (&optional nowarn)
"Get current live process.
If NOWARN does not error on no active process."
(if (and dape--connection (jsonrpc-running-p dape--connection))
dape--connection
(unless nowarn
(user-error "No debug connection live"))))
(defclass dape-connection (jsonrpc-process-connection)
((last-id
:initform 0
:documentation "Used for converting JSONRPC's `id' to DAP' `seq'.")
(n-sent-notifs
:initform 0
:documentation "Used for converting JSONRPC's `id' to DAP' `seq'.")
(parent
:accessor dape--parent :initarg :parent :initform #'ignore
:documentation "Parent connection. Used by startDebugging adapters.")
(config
:accessor dape--config :initarg :config :initform #'ignore
:documentation "Current session configuration plist.")
(server-process
:accessor dape--server-process :initarg :server-process :initform #'ignore
:documentation "Debug adapter server process.")
(threads
:accessor dape--threads :initform nil
:documentation "Session plist of thread data.")
(capabilities
:accessor dape--capabilities :initform nil
:documentation "Session capabilities plist.")
(thread-id
:accessor dape--thread-id :initform nil
:documentation "Selected thread id.")
(stack-id
:accessor dape--stack-id :initform nil
:documentation "Selected stack id.")
(modules
:accessor dape--modules :initform nil
:documentation "List of modules.")
(sources
:accessor dape--sources :initform nil
:documentation "List of loaded sources.")
(state
:accessor dape--state :initform nil
:documentation "Session state.")
(exception-description