forked from facebook/igl
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathRenderSessionController.mm
172 lines (150 loc) · 5.06 KB
/
RenderSessionController.mm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
/*
* Copyright (c) Meta Platforms, Inc. and affiliates.
*
* This source code is licensed under the MIT license found in the
* LICENSE file in the root directory of this source tree.
*/
// @fb-only
#import "RenderSessionController.h"
#import "IglShellPlatformAdapterInternal.hpp"
#import "IglSurfaceTexturesAdapterInternal.hpp"
#import "RenderSessionFactoryAdapterInternal.hpp"
#import <QuartzCore/CADisplayLink.h>
#import <UIKit/UIKit.h>
#import <igl/IGL.h>
#import <shell/shared/input/InputDispatcher.h>
#if IGL_BACKEND_METAL
#import <Metal/Metal.h>
#import <igl/metal/HWDevice.h>
#endif
#if IGL_BACKEND_OPENGL
#import <igl/opengl/ios/Context.h>
#import <igl/opengl/ios/Device.h>
#import <igl/opengl/ios/HWDevice.h>
#endif
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
#include <memory>
#include <shell/shared/platform/ios/PlatformIos.h>
#include <shell/shared/renderSession/IRenderSessionFactory.h>
#include <shell/shared/renderSession/RenderSession.h>
#include <shell/shared/renderSession/RenderSessionConfig.h>
@interface RenderSessionController () {
igl::BackendVersion backendVersion_;
CGRect frame_;
CADisplayLink* renderTimer_;
std::unique_ptr<igl::shell::RenderSession> session_;
std::shared_ptr<igl::shell::Platform> platform_;
IglShellPlatformAdapter platformAdapter_;
igl::shell::IRenderSessionFactory* factory_;
id<IglSurfaceTexturesProvider> surfaceTexturesProvider_;
}
- (igl::BackendVersion)toBackendVersion:(BackendVersion*)version;
@end
@implementation RenderSessionController
- (instancetype)initWithBackendVersion:(BackendVersion*)backendVersion
factoryProvider:(RenderSessionFactoryProvider*)factoryProvider
surfaceProvider:(id<IglSurfaceTexturesProvider>)provider {
if (self = [super init]) {
backendVersion_ = [self toBackendVersion:backendVersion];
factory_ = [factoryProvider adapter]->factory;
frame_ = CGRectMake(0, 0, 1024, 768); // choose some default
// @fb-only
// @fb-only
surfaceTexturesProvider_ = provider;
}
return self;
}
- (void)initializeDevice {
igl::HWDeviceQueryDesc queryDesc(igl::HWDeviceType::DiscreteGpu);
std::unique_ptr<igl::IDevice> device;
switch (backendVersion_.flavor) {
case igl::BackendFlavor::Metal: {
#if IGL_BACKEND_METAL
igl::metal::HWDevice hwDevice;
auto hwDevices = hwDevice.queryDevices(queryDesc, nullptr);
device = hwDevice.create(hwDevices[0], nullptr);
#endif
break;
}
case igl::BackendFlavor::OpenGL_ES: {
#if IGL_BACKEND_OPENGL
auto hwDevices = igl::opengl::ios::HWDevice().queryDevices(queryDesc, nullptr);
const auto renderingApi = backendVersion_.majorVersion == 2 ? igl::opengl::RenderingAPI::GLES2
: igl::opengl::RenderingAPI::GLES3;
device = igl::opengl::ios::HWDevice().create(hwDevices[0], renderingApi, nullptr);
#endif
break;
}
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
// @fb-only
default:
IGL_DEBUG_ABORT("IGL Samples not set up for backend(%d)", (int)backendVersion_.flavor);
break;
}
platform_ = std::make_shared<igl::shell::PlatformIos>(std::move(device));
platformAdapter_.platform = platform_.get();
session_ = factory_->createRenderSession(platform_);
IGL_DEBUG_ASSERT(session_, "createDefaultRenderSession() must return a valid session");
session_->initialize();
}
// @protocol IglShellPlatformAdapter
- (IglShellPlatformAdapterPtr)adapter {
return &platformAdapter_;
}
- (void)start {
if (backendVersion_.flavor != igl::BackendFlavor::Metal) {
// Render at 60hz
renderTimer_ = [CADisplayLink displayLinkWithTarget:self selector:@selector(tick)];
[renderTimer_ addToRunLoop:[NSRunLoop currentRunLoop] forMode:NSDefaultRunLoopMode];
}
}
- (void)stop {
[renderTimer_ removeFromRunLoop:[NSRunLoop currentRunLoop] forMode:NSDefaultRunLoopMode];
renderTimer_ = nullptr;
}
- (void)tick {
igl::DeviceScope scope(platform_->getDevice());
// @fb-only
// @fb-only
IglSurfaceTexturesAdapter* adapter = [surfaceTexturesProvider_ createSurfaceTextures];
// @fb-only
// @fb-only
// process user input
platform_->getInputDispatcher().processEvents();
// draw
if (backendVersion_.flavor == igl::BackendFlavor::Metal) {
session_->setPixelsPerPoint((float)[UIScreen mainScreen].scale);
} else if (backendVersion_.flavor == igl::BackendFlavor::OpenGL) {
session_->setPixelsPerPoint(1.0f);
}
session_->update(adapter ? std::move(adapter->surfaceTextures) : igl::SurfaceTextures{});
}
- (void)releaseSessionFrameBuffer {
if (session_) {
session_->releaseFramebuffer();
}
}
- (void)setFrame:(CGRect)frame {
frame_ = frame;
}
- (igl::BackendVersion)toBackendVersion:(BackendVersion*)version {
return {.flavor = static_cast<igl::BackendFlavor>(version.flavor),
.majorVersion = version.majorVersion,
.minorVersion = version.minorVersion};
}
@end