settings.gradle

pluginManagement {
    repositories {
        maven {
            url 'https://a8c-libs.s3.amazonaws.com/android'
            content {
                includeGroup "com.automattic.android"
                includeGroup "com.automattic.android.measure-builds"
            }
        }
        gradlePluginPortal()
        google()
    }
}

plugins {
    id "com.gradle.develocity" version "3.18.1"
}

gradle.ext.isCi = System.getenv('CI')?.toBoolean() ?: false

dependencyResolutionManagement {
    repositoriesMode.set(RepositoriesMode.FAIL_ON_PROJECT_REPOS)
    repositories {
        google()
        mavenCentral()
        maven {
            url "https://a8c-libs.s3.amazonaws.com/android"
            content {
                includeGroup "org.wordpress"
                includeGroup "org.wordpress.aztec"
                includeGroup "org.wordpress.wellsql"
                includeGroup "org.wordpress.gutenberg-mobile"
                includeGroup "org.wordpress.gutenbergkit"
                includeGroupByRegex "org.wordpress.react-native-libraries.*"
                includeGroup "com.automattic"
                includeGroup "com.automattic.tracks"
                includeGroup "com.gravatar"
                includeGroup "rs.wordpress.api"
            }
        }
        maven {
            url "https://a8c-libs.s3.amazonaws.com/android/react-native-mirror"
            content {
                includeGroup "com.facebook.react"
            }
        }
        maven {
            url 'https://zendesk.jfrog.io/zendesk/repo'
            content {
                includeGroup "com.zendesk"
                includeGroup "com.zendesk.belvedere2"
            }
        }
        maven {
            url "https://a8c-libs.s3.amazonaws.com/android/jcenter-mirror"
            content {
                includeVersion "com.automattic", "rest", "1.0.8"
                includeVersion "org.wordpress", "persistentedittext", "1.0.2"
            }
        }
        maven { url "https://www.jitpack.io" }
    }
}

rootProject.name = 'WPAndroid'

include ':WordPress'

include ':libs:image-editor'
include ':libs:networking'
include ':libs:analytics'
include ':libs:editor'
include ':libs:processors'
include ':libs:annotations'

include ':libs:mocks'

include ':libs:fluxc', ':libs:fluxc-annotations', ':libs:fluxc-processor'
include ':libs:login'

apply from: './config/gradle/included_builds.gradle'
apply from: './config/gradle/gradle_build_cache.gradle'
apply from: './config/gradle/gradle_build_scan.gradle'