forked from emu-russia/bomberman-nes
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathBMAN.NAS
6103 lines (5243 loc) · 147 KB
/
BMAN.NAS
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
PROCESSOR 6502
ORG $C000
INCLUDE "NESREGS.NAS"
INCLUDE "VARS.NAS"
RESET
SEI ; Reset PPU. Disable NMI, turn off background and sprites.
LDA #0
STA PPU_CTRL_REG2
STA PPU_CTRL_REG1
CLD ; The NES 6502 CPU has no BCD mode, reset the flag just in case.
LDX #$FF ; Set the stack pointer to the initial position
TXS
WAIT_VBLANK1 ; Wait for 2 VBlank's, to stabilize the PPU.
LDA PPU_STATUS
BPL WAIT_VBLANK1
WAIT_VBLANK2
LDA PPU_STATUS
BPL WAIT_VBLANK2
JMP START
; ---------------------------------------------------------------------------
NMI
PHA
TXA
PHA
TYA
PHA
LDX #0
STX FRAMEDONE ; Cancel frame start wait
STX PPU_SPR_ADDR
LDA STAGE_STARTED
BEQ SEND_SPRITES
LDA #25 ; Draw a small `1` on the top-right side of the screen
STA SPR_TAB ; Apparently used for debugging (forgot to remove)
LDA #$EC
STA SPR_TAB+1
LDA #0
STA SPR_TAB+2
LDA #248
STA SPR_TAB+3
SEND_SPRITES
LDA #7
STA PPU_SPR_DMA
LDX #9 ; Draw tiles from the circular buffer
STX TILE_CNT
BNE DRAW_NEXT_TILE
DRAW_TILES
LDA TILE_TAB+2,Y ; Draw new tiles until the end of the buffer, but no more than TILE_CNT tiles.
ORA TILE_TAB,Y
PHA
STA PPU_ADDRESS
LDX TILE_TAB+1,Y
STX PPU_ADDRESS
LDX TILE_TAB+3,Y
LDA TILE_MAP,X
STA PPU_DATA
LDA TILE_MAP+1,X
STA PPU_DATA
PLA
STA PPU_ADDRESS
LDA TILE_TAB+1,Y
CLC
ADC #32
STA PPU_ADDRESS
LDA TILE_MAP+2,X
STA PPU_DATA
LDA TILE_MAP+3,X
STA PPU_DATA
LDA #$23 ; '#'
ORA TILE_TAB,Y
PHA
STA PPU_ADDRESS
LDA TILE_TAB+4,Y
STA PPU_ADDRESS
TAX
LDA PPU_DATA
LDA PPU_DATA
AND TILE_TAB+6,Y
ORA TILE_TAB+7,Y
TAY
PLA
STA PPU_ADDRESS
STX PPU_ADDRESS
STY PPU_DATA
LDA #8
CLC
ADC TILE_CUR
STA TILE_CUR
DEC TILE_CNT
BEQ DRAW_MENU_ARROW
DRAW_NEXT_TILE:
LDY TILE_CUR
CPY TILE_PTR
BNE DRAW_TILES ; Draw new tiles until the end of the buffer, but no more than TILE_CNT tiles.
DRAW_MENU_ARROW:
LDA INMENU
BEQ DRAW_ARROW_SKIP
LDA #$22 ; '"'
LDX #$68 ; 'h'
JSR VRAMADDR
LDY #$B0 ; '-'
LDA CURSOR
BNE DRAW_ARROW_START
LDY #$40 ; '@'
DRAW_ARROW_START:
STY PPU_DATA
LDA #$22 ; '"'
LDX #$70 ; 'p'
JSR VRAMADDR
LDY #$B0 ; '-'
LDA CURSOR
BEQ DRAW_ARROW_CONT
LDY #$40 ; '@'
DRAW_ARROW_CONT:
STY PPU_DATA
JMP UPDATE_FPS
; ---------------------------------------------------------------------------
DRAW_ARROW_SKIP:
LDA STAGE_STARTED
BEQ UPDATE_FPS
LDA TILE_CNT
CMP #4
BCC UPDATE_FPS
LDA #$20 ; ' '
LDX #$4B ; 'K'
JSR VRAMADDR ; Y=2, X=11
LDX #0
DRAW_SCORE_BLANK:
LDA SCORE,X ; Skip leading zeros
BNE DRAW_SCORE_NUM
LDA #$3A ; ':' ; Blank character instead of zero
STA PPU_DATA
INX
CPX #7
BNE DRAW_SCORE_BLANK ; Skip leading zeros
BEQ DRAW_TIMER
DRAW_SCORE_NUM:
LDA SCORE,X
CLC
ADC #$30 ; '0' ; The number is 0...9
STA PPU_DATA
INX
CPX #7
BNE DRAW_SCORE_NUM
DRAW_TIMER:
LDA #$20 ; ' '
LDX #$46 ; 'F' ; Y=2, X=6
JSR VRAMADDR
LDA TIMELEFT
CMP #255
BNE TIME_OVERFLOW
LDA #0
TIME_OVERFLOW:
JSR DRAW_TIME
UPDATE_FPS:
LDA PPU_STATUS
JSR PPU_RESTORE
INC FRAME_CNT
LDA IS_SECOND_PASSED
BEQ TICK_FPS
INC FPS
LDA FPS
CMP #60
BCC TICK_FPS
LDA #0
STA IS_SECOND_PASSED
TICK_FPS:
STA FPS
JSR PAD_READ
JSR APU_PLAY_MELODY ; Play a tune
JSR APU_PLAY_SOUND ; Play the sound
LDA BOOM_SOUND
BEQ SET_SCROLL_REG
LDA DEMOPLAY
BNE SET_SCROLL_REG
LDA #$E
STA APU_DELTA_REG
LDA #0
STA BOOM_SOUND
LDA #$C0 ; 'L'
STA APU_DELTA_REG+2
LDA #$FF
STA APU_DELTA_REG+3
LDA #$F
STA APU_MASTERCTRL_REG
LDA #$1F
STA APU_MASTERCTRL_REG
SET_SCROLL_REG:
LDA STAGE_STARTED
BEQ LEAVE_NMI
WAIT_SPR0_HIT:
LDA PPU_STATUS
AND #$40 ; '@'
BNE WAIT_SPR0_HIT
WAIT_SPR0_MISS:
LDA PPU_STATUS
AND #$40 ; '@'
BEQ WAIT_SPR0_MISS
LDA H_SCROLL
STA PPU_SCROLL_REG
LDA V_SCROLL
STA PPU_SCROLL_REG
LEAVE_NMI:
LDA #5
EOR SPR_TAB_TOGGLE
STA SPR_TAB_TOGGLE
PLA
TAY
PLA
TAX
PLA
RTI
; =============== S U B R O U T I N E =======================================
VRAMADDR
STA PPU_ADDRESS
STX PPU_ADDRESS
RTS
; =============== S U B R O U T I N E =======================================
PAD_READ
JSR PAD_STROBE
LDA JOYPAD1
STA PAD1_TEST
LDA JOYPAD2
STA PAD2_TEST
JSR PAD_STROBE
LDA JOYPAD1
CMP PAD1_TEST
BNE PAD_DRE
LDA JOYPAD2
CMP PAD2_TEST
BNE PAD_DRE
RTS
; ---------------------------------------------------------------------------
PAD_DRE
LDA #0
STA JOYPAD1
STA JOYPAD2
RTS
; =============== S U B R O U T I N E =======================================
PAD_STROBE
LDA #1
STA JOYPAD_PORT1
LDA #0
STA JOYPAD_PORT1
TAX
LDY #8
JOY1:
TXA
ASL
TAX
LDA JOYPAD_PORT1
JSR IS_PRESSED
BNE JOY1
STX JOYPAD1
LDX #0
LDY #8
JOY2:
TXA
ASL
TAX
LDA JOYPAD_PORT2
JSR IS_PRESSED
BNE JOY2
STX JOYPAD2
RTS
; =============== S U B R O U T I N E =======================================
IS_PRESSED
AND #3
BEQ NOT_PRESSED
INX
NOT_PRESSED:
DEY
RTS
; =============== S U B R O U T I N E =======================================
PPU_RESET
JSR PPUD
JSR VBLD
LDA #$10
STA LAST_2000
STA PPU_CTRL_REG1
LDA #0
STA H_SCROLL
STA TILE_CUR
STA TILE_PTR
STA V_SCROLL
JSR SPRD ; Hide Sprites
JSR PPUD
JSR WAITVBL
JSR PAL_RESET
; =============== S U B R O U T I N E =======================================
CLS
LDA #$20 ; ' '
LDX #0
JSR VRAMADDR
LDY #8
LDA #$B0 ; '-'
CLEAR_NT
STA PPU_DATA
DEX
BNE CLEAR_NT
DEY
BNE CLEAR_NT
LDA #$23
LDX #$C0
JSR VRAMADDR
LDX #$40 ; '@'
LDA #0
CLEAR_AT:
STA PPU_DATA
DEX
BNE CLEAR_AT
RTS
; =============== S U B R O U T I N E =======================================
PPUE
JSR VBLD
JSR WAITVBL
LDA #$E
JSR WRITE2001
JSR SENDSPR
JMP VBLE
; =============== S U B R O U T I N E =======================================
; How sprites are rendered.
; There can be up to 16 sprite images in total (10 monsters, bomberman and bonus points)
; The sprite image consists of 4 sprites and is 16x16 in size.
; The sprite table is conventionally divided into two parts: for even and odd frames.
; Apparently this is done to reduce the flicker of sprites.
; The sprite image is rendered in halves (first the left 8x16, then the right) because they are symmetrical.
; The special variable SPR_TAB_TOGGLE takes values 0 -> 5 -> 0 every frame ...
; and thereby selects which half of the SPR_TAB to use for rendering.
; In general, the offset in SPR_TAB for the current sprite image is calculated as follows:
; TEMP = SPR_TAB_INDEX++ + SPR_TAB_TOGGLE <-- The index begins with 1.
; TEMP = TEMP >= 12 ? TEMP - 10 : TEMP <-- Limit the index to 12
; Y = 16 * TEMP <-- *16 because the image is made up of 4 sprites
; Which is a little strange, but what to take, as they did so.
; For example, there is a bomber and 10 monsters on the screen. The TEMP value will be as follows-
; For even frames: 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11
; For odd frames: 6, 7, 8, 9, 10, 11, 2, 3, 4, 5, 6
; (For odd frames bomber sprites will be overwritten by monster sprites and as a result
; the bomber picture will blink when there are many sprites on the screen).
SENDSPR
LDA #0
STA PPU_SPR_ADDR
LDA #7
STA PPU_SPR_DMA
RTS
; =============== S U B R O U T I N E =======================================
PPUD
JSR WAITVBL
LDA #0
; =============== S U B R O U T I N E =======================================
WRITE2001:
STA PPU_CTRL_REG2
WRITE2001_2:
STA LAST_2001
RTS
; =============== S U B R O U T I N E =======================================
SPRE:
LDA LAST_2001
ORA #$10
BNE WRITE2001_2
; =============== S U B R O U T I N E =======================================
; Hide Sprites
SPRD
LDY #$1C
LDA #248
SETATTR:
STA SPR_TAB,Y
STA SPR_TAB+$20,Y
STA SPR_TAB+$40,Y
STA SPR_TAB+$60,Y
STA SPR_TAB+$80,Y
STA SPR_TAB+$A0,Y
STA SPR_TAB+$C0,Y
STA SPR_TAB+$E0,Y
DEY
DEY
DEY
DEY
BPL SETATTR
RTS
; =============== S U B R O U T I N E =======================================
WAITVBL
LDA PPU_STATUS
BMI WAITVBL
WAITVBL2:
LDA PPU_STATUS
BPL WAITVBL2
RTS
; =============== S U B R O U T I N E =======================================
PPU_RESTORE
LDA LAST_2001
STA PPU_CTRL_REG2
LDA #0
LDX #0
JSR VRAMADDR
LDA #0
STA PPU_SCROLL_REG
STA PPU_SCROLL_REG
LDA LAST_2000
STA PPU_CTRL_REG1
RTS
; =============== S U B R O U T I N E =======================================
VBLE
JSR WAITVBL
LDA LAST_2000
ORA #$80
BNE WRITE2000
; =============== S U B R O U T I N E =======================================
VBLD
LDA LAST_2000
AND #$7F
WRITE2000:
STA LAST_2000
STA PPU_CTRL_REG1
RTS
; =============== S U B R O U T I N E =======================================
PAL_RESET:
LDA #$3F ; '?'
LDX #0
JSR VRAMADDR
LDY #32
PAL_RESET_LOOP:
LDA STARTPAL,X
STA PPU_DATA
INX
DEY
BNE PAL_RESET_LOOP
; =============== S U B R O U T I N E =======================================
VRAMADDRZ
LDA #$3F ; '?'
STA PPU_ADDRESS
LDA #0
STA PPU_ADDRESS
STA PPU_ADDRESS
STA PPU_ADDRESS
RTS
; ---------------------------------------------------------------------------
STARTPAL: .BYTE $19, $F,$10,$30,$19,$16,$26,$36,$19, $F,$18,$28,$19, $F,$17, 7
.BYTE $19,$30,$21,$26,$19, $F,$26,$30,$19, $F,$15,$30,$19, $F,$21,$30
; =============== S U B R O U T I N E =======================================
; Wait for the button to release
WAITUNPRESS
LDA JOYPAD1
BNE WAITUNPRESS ; Wait for the button to release
RTS
; =============== S U B R O U T I N E =======================================
START
LDY #0
STY TEMP_ADDR
INY
STY TEMP_ADDR+1
DEY
TYA
LDX #7
CLEAR_WRAM:
STA (TEMP_ADDR),Y
INY
BNE CLEAR_WRAM
INC TEMP_ADDR+1
DEX
BNE CLEAR_WRAM
LDX #0
LDY SOFT_RESET_FLAG
CPY #$93
BNE CLEAR_ZP
LDY CLEAR_TOPSCORE1
BNE CLEAR_ZP
LDY CLEAR_TOPSCORE2
BNE CLEAR_ZP
LDX #8
CLEAR_ZP
STA 0,X
INX
BNE CLEAR_ZP
LDA #$93
STA SOFT_RESET_FLAG
RESET_GAME
JSR PPU_RESET
LDA #0
STA SPR_TAB_TOGGLE
JSR APU_RESET ; Reset APU state
LDA #1
STA APU_MUSIC
GAME_MENU:
LDX #$FF
TXS
LDA #$F
STA APU_MASTERCTRL_REG
LDA #0
STA BOOM_SOUND
STA DEMOPLAY
STA APU_DISABLE
STA STAGE_STARTED
STA DEMO_WAIT_HI
JSR DRAWMENU
JSR VBLE
LDA #1
STA INMENU
WAIT_RELEASE:
LDA JOYPAD1
BNE WAIT_RELEASE
ADVANCE_FRAME:
LDA #8
STA DEMO_WAIT_HI
DEMO_WAIT_LOOP:
JSR NEXTFRAME
LDA JOYPAD1
AND #$10
BNE START_PRESSED ; If START is pressed
LDA JOYPAD1
AND #$20 ; ' '
BEQ UPDATE_RAND ; Update the random number generator
LDA CURSOR
EOR #1
STA CURSOR
JSR WAITUNPRESS ; Wait for the button to release
JMP ADVANCE_FRAME
; ---------------------------------------------------------------------------
UPDATE_RAND:
JSR RAND ; Update the random number generator
DEC DEMO_WAIT_LO
BNE DEMO_WAIT_LOOP
DEC DEMO_WAIT_HI
BNE DEMO_WAIT_LOOP
INC DEMOPLAY ; If the counter has expired, start the demonstration
START_PRESSED:
LDA DEMOPLAY
BNE loc_C3A3
LDA CURSOR
BEQ loc_C3A3
JSR sub_DA8E
loc_C3A3:
LDA #0
STA INMENU
JSR WAITUNPRESS ; Wait for the button to release
LDA #2
STA LIFELEFT
LDA DEMOPLAY
BNE loc_C3B6
LDA CURSOR
BNE loc_C40A
loc_C3B6:
LDA #1
STA STAGE
LDA DEMOPLAY
BNE loc_C3C7
LDX #6
LDA #0
CLEAR_SCORE_LOOP:
STA SCORE,X
DEX
BPL CLEAR_SCORE_LOOP
loc_C3C7:
LDA #$10
STA BONUS_POWER
LDA #0
STA BONUS_BOMBS
STA BONUS_REMOTE
STA BONUS_SPEED
STA BONUS_NOCLIP
STA BONUS_FIRESUIT
STA byte_94
LDA DEMOPLAY
BEQ loc_C40A
LDA #9
STA BONUS_BOMBS
LDA #$40 ; '@'
STA BONUS_POWER
LDA #1
STA BONUS_REMOTE
LDA #0
STA APU_MASTERCTRL_REG
STA SEED
STA SEED+1
STA SEED+2
STA SEED+3
STA FRAME_CNT
LDA #$F4
STA DEMOKEY_DATA
LDA #$ED
STA DEMOKEY_DATA+1
LDA DEMO_KEYDATA
STA DEMOKEY_TIMEOUT
LDA DEMO_KEYDATA+1
STA DEMOKEY_PAD1
loc_C40A:
LDA #0
STA BONUS_BOMBWALK
STA INVUL_UNK1
START_STAGE:
LDA #0
STA byte_B1
STA byte_A8
STA STAGE_STARTED
STA byte_9E
STA byte_9F
STA byte_9C
STA byte_A0
STA byte_A1
STA byte_A2
STA byte_A3
STA byte_A4
STA byte_A5
STA byte_A6
STA byte_A7
JSR STAGE_SCREEN
LDA #2
STA APU_MUSIC
JSR WAITTUNE ; Wait for the end of the current tune
LDA #3
STA APU_MUSIC
JSR VBLD
JSR BUILD_MAP ; Generate a level map with bricks
JSR SPAWN ; Create monsters and bomberman
JSR sub_E4AF
JSR PICTURE_ON ; Turn on the screen and sprites
LDA #200
STA TIMELEFT
STAGE_LOOP:
JSR PAUSED ; Check if the pause is pressed (and if it is, wait for it to release)
JSR SPRD ; Hide Sprites
JSR sub_CC36 ; Button handling
JSR BOMB_TICK ; Bomb timer processing and detonation initiation
JSR DRAW_BOMBERMAN ; Draw the bomberman (update the sprite)
JSR THINK ; Monsters.
JSR BOMB_ANIMATE ; Draw a bomb animation
JSR STAGE_TIMER ; Reduce time by 1 second (normal level)
JSR sub_E399
LDA byte_5D
BNE loc_C481
LDA byte_5E
BNE loc_C4BF
LDA FRAME_CNT
AND #3 ; Explosions are only updated in 1 frame out of 4
BNE STAGE_LOOP
JSR sub_C79D ; Drawing explosions (?)
JSR sub_C66C ; Explosion tracing to find the victim
JMP STAGE_LOOP
; ---------------------------------------------------------------------------
loc_C481:
LDA DEMOPLAY
BNE loc_C4C3
LDA #0
STA BONUS_NOCLIP
STA BONUS_BOMBWALK
STA BONUS_REMOTE
STA BONUS_FIRESUIT
STA INVUL_UNK1
LDA #8
STA APU_MUSIC
JSR WAITTUNE ; Wait for the end of the current tune
DEC LIFELEFT
BMI GAME_OVER
JMP START_STAGE
; ---------------------------------------------------------------------------
GAME_OVER:
LDA #0
STA STAGE_STARTED
JSR GAME_OVER_SCREEN
LDA #9
STA APU_MUSIC
GAME_OVER_WAIT:
LDA JOYPAD1
AND #$10
BNE GAME_OVER_END
LDA APU_MUSIC
BNE GAME_OVER_WAIT
GAME_OVER_END:
LDA #0
STA APU_MUSIC
WAIT_PRESS:
LDA JOYPAD1
BEQ WAIT_PRESS
JMP GAME_MENU
; ---------------------------------------------------------------------------
loc_C4BF:
LDA DEMOPLAY
BEQ NEXT_STAGE
loc_C4C3:
LDA #0
STA APU_MUSIC
INC byte_B0
LDA byte_B0
AND #3
BEQ loc_C4D2
JMP GAME_MENU
; ---------------------------------------------------------------------------
loc_C4D2:
JMP RESET_GAME
; ---------------------------------------------------------------------------
NEXT_STAGE:
LDA #10
STA APU_MUSIC
JSR WAITTUNE ; Wait for the end of the current tune
INC LIFELEFT
INC STAGE
LDY #0
LDA STAGE
CMP #51
BNE SELECT_BONUS_MONSTER ; Choose the type of monster for the bonus level
JMP END_GAME
; ---------------------------------------------------------------------------
SELECT_BONUS_MONSTER:
INY ; Choose the type of monster for the bonus level
SEC
SBC #5
BCS SELECT_BONUS_MONSTER ; Choose the type of monster for the bonus level
DEY
CPY #8
BCC SELECT_STAGE_TYPE
LDY #8 ; Monster type is limited to 1...8
SELECT_STAGE_TYPE:
STY BONUS_ENEMY_TYPE
ADC #5
CMP #1
BEQ START_BONUS_STAGE
JMP START_STAGE
; ---------------------------------------------------------------------------
START_BONUS_STAGE:
LDA #0
STA STAGE_STARTED
JSR BONUS_STAGE_SCREEN
LDA #2
STA APU_MUSIC
JSR WAITTUNE ; Wait for the end of the current tune
JSR VBLD
JSR BUILD_CONCRET_WALLS ; Build concrete walls
JSR SPAWN ; Create monsters and bomberman
JSR PICTURE_ON ; Turn on the screen and sprites
JSR STAGE_CLEANUP
LDA #6
STA APU_MUSIC
LDA #1
STA INVUL_UNK1
STA INVUL_UNK2
LDA #30 ; Set 30 seconds
STA TIMELEFT
BONUS_STAGE_LOOP:
JSR PAUSED ; Check if the pause is pressed (and if it is, wait for it to release)
LDA TIMELEFT
BEQ BONUS_STAGE_END ; If time runs out then exit the bonus level
JSR SPRD ; Hide Sprites
JSR RESPAWN_BONUS_ENEMY ; If the number of monsters in the bonus level is less than 10, then add more
JSR sub_CC36 ; Button handling
JSR BOMB_TICK ; Bomb timer processing and detonation initiation
JSR DRAW_BOMBERMAN ; Draw the bomberman (update the sprite)
JSR THINK ; Monsters.
JSR BOMB_ANIMATE ; Draw a bomb animation
JSR BONUS_STAGE_TIMER ; Reduce time by 1 second (bonus level)
LDA FRAME_CNT
AND #1 ; Explosions are not updated every frame, but every other frame
BNE BONUS_STAGE_LOOP
JSR sub_C79D ; Drawing explosions (?)
JSR sub_C66C ; Explosion tracing to find the victim
JMP BONUS_STAGE_LOOP
; ---------------------------------------------------------------------------
BONUS_STAGE_END:
LDA #10
STA APU_MUSIC
JSR WAITTUNE ; Wait for the end of the current tune
LDA #0
STA INVUL_UNK2
STA INVUL_UNK1
JMP START_STAGE
; ---------------------------------------------------------------------------
END_GAME:
JSR PPU_RESET
JSR sub_DBF9
JSR BUILD_CONCRET_WALLS ; Build concrete walls
LDA #8
STA BOMBMAN_U
STA BOMBMAN_V
LDA #0
STA STAGE_STARTED
STA BOMBMAN_X
LDA #9
STA BOMBMAN_Y
LDA #7
STA APU_MUSIC
JSR SPRE
JSR VBLE
loc_C58F:
JSR NEXTFRAME
LDA #1
STA SPR_TAB_INDEX
JSR SPRD ; Hide Sprites
JSR DRAW_BOMBERMAN ; Draw the bomberman (update the sprite)
LDA FRAME_CNT
ROR
BCS loc_C5A4
JSR sub_CDD4
loc_C5A4:
LDA BOMBMAN_X
CMP #8
BNE loc_C58F
WAIT_END_MELODY:
JSR NEXTFRAME
LDA #1
STA SPR_TAB_INDEX
JSR SPRD ; Hide Sprites
JSR sub_CEA7
LDA FRAME_CNT
ROR
BCS loc_C5BF
JSR sub_CDD4
loc_C5BF:
LDA APU_MUSIC
BNE WAIT_END_MELODY
WAIT_BUTTON:
LDA JOYPAD1
BEQ WAIT_BUTTON
LDA #1
STA STAGE
JMP START_STAGE
; =============== S U B R O U T I N E =======================================
; Create monsters and bomberman
SPAWN:
LDA #1
STA BOMBMAN_X
STA BOMBMAN_Y
LDA #8
STA BOMBMAN_U
STA BOMBMAN_V
LDA #0
STA BOMBMAN_FRAME
STA byte_5D
STA byte_5C
STA byte_5E
JSR STAGE_CLEANUP
JSR SPAWN_MONSTERS
JSR sub_CB06
JSR WAITVBL
JSR PAL_RESET
LDX STAGE
LDA EXIT_ENEMY_TAB-1,X ; This table contains the type of monster that comes out of the door after an explosion
STA EXIT_ENEMY_TYPE
LDA #1
STA STAGE_STARTED
RTS
; =============== S U B R O U T I N E =======================================
; Turn on the screen and sprites
PICTURE_ON:
JSR SPRD ; Hide Sprites