-
Notifications
You must be signed in to change notification settings - Fork 11
/
Copy pathoverlook.cmake
594 lines (533 loc) · 22.3 KB
/
overlook.cmake
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
#################################################
# overlook: the missing linter for C/C++
#
# author: ChrisZZ
# email: [email protected]
# license: MIT
#################################################
#################################################
#
# Useful funtions
#
#################################################
cmake_minimum_required(VERSION 3.1)
# --[ correctly show folder structure in Visual Studio
function(assign_source_group)
foreach(_source IN ITEMS ${ARGN})
if (IS_ABSOLUTE "${_source}")
file(RELATIVE_PATH _source_rel "${CMAKE_CURRENT_SOURCE_DIR}" "${_source}")
else()
set(_source_rel "${_source}")
endif()
get_filename_component(_source_path "${_source_rel}" PATH)
string(REPLACE "/" "\\" _source_path_msvc "${_source_path}")
source_group("${_source_path_msvc}" FILES "${_source}")
endforeach()
endfunction(assign_source_group)
function(overlook_add_executable)
if (CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Darwin")
foreach(_source IN ITEMS ${ARGN})
assign_source_group(${_source})
endforeach()
#message("${ARGV}\n")
endif ()
add_executable(${ARGV})
endfunction(overlook_add_executable)
function(overlook_cuda_add_executable)
if (CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Darwin")
foreach(_source IN ITEMS ${ARGN})
assign_source_group(${_source})
endforeach()
#message("${ARGV}\n")
endif ()
cuda_add_executable(${ARGV})
endfunction(overlook_cuda_add_executable)
function(overlook_add_library)
if (CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Darwin")
foreach(_source IN ITEMS ${ARGN})
assign_source_group(${_source})
endforeach()
#message("${ARGV}\n")
endif ()
add_library(${ARGV})
endfunction(overlook_add_library)
function(overlook_cuda_add_library)
if (CMAKE_SYSTEM_NAME MATCHES "Windows" OR CMAKE_SYSTEM_NAME MATCHES "Darwin")
foreach(_source IN ITEMS ${ARGN})
assign_source_group(${_source})
endforeach()
#message("${ARGV}\n")
endif ()
cuda_add_library(${ARGV})
endfunction(overlook_cuda_add_library)
# append element to list with space as seperator
function(overlook_list_append __string __element)
# set(__list ${${__string}})
# set(__list "${__list} ${__element}")
# set(${__string} ${__list} PARENT_SCOPE)
#set(__list ${${__string}})
set(${__string} "${${__string}} ${__element}" PARENT_SCOPE)
endfunction()
option(USE_OVERLOOK_FLAGS "use safe compilation flags?" ON)
option(OVERLOOK_STRICT_FLAGS "strict c/c++ flags checking?" OFF)
option(USE_CPPCHECK "use cppcheck for static checkingg?" OFF)
option(OVERLOOK_VERBOSE "verbose output?" ON)
#################################################
#
# Important CFLAGS/CXXFLAGS
#
#################################################
set(OVERLOOK_C_FLAGS "")
set(OVERLOOK_CXX_FLAGS "")
# 0. 检查编译器版本。同一编译器的不同版本，编译选项的支持情况可能不同。
if(CMAKE_CXX_COMPILER_ID MATCHES "Clang" AND CLANG_VERSION_STRING)
message(STATUS "--- CLANG_VERSION_MAJOR is: ${CLANG_VERSION_MAJOR}")
message(STATUS "--- CLANG_VERSION_MINOR is: ${CLANG_VERSION_MINOR}")
message(STATUS "--- CLANG_VERSION_PATCHLEVEL is: ${CLANG_VERSION_PATCHLEVEL}")
message(STATUS "--- CLANG_VERSION_STRING is: ${CLANG_VERSION_STRING}")
endif()
if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
message(STATUS "--- CMAKE_CXX_COMPILER_VERSION is: ${CMAKE_CXX_COMPILER_VERSION}")
# if(CMAKE_CXX_COMPILER_VERSION GREATER 9.1) # when >= 9.2, not support this option
# message(STATUS "---- DEBUG INFO HERE !!!")
# endif()
endif()
# 1. 函数没有声明就使用
# 解决bug：地址截断；内存泄漏
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4013)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4013)
elseif(CMAKE_C_COMPILER_ID MATCHES "GNU" AND CMAKE_C_COMPILER_VERSION LESS 9.2)
overlook_list_append(OVERLOOK_C_FLAGS -Werror=implicit-function-declaration)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=implicit-function-declaration)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=implicit-function-declaration)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=implicit-function-declaration)
endif()
# 2. 函数虽然有声明，但是声明不完整，没有写出返回值类型
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4431)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4431)
elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
if(CMAKE_CXX_COMPILER_VERSION LESS 9.3) # gcc/g++ < 9.3 required
overlook_list_append(OVERLOOK_C_FLAGS -Werror=implicit-int)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=implicit-int)
endif()
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=implicit-int)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=implicit-int)
endif()
# 3. 指针类型不兼容
# 解决bug：crash或结果异常
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4133)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4133)
elseif(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
if(CMAKE_CXX_COMPILER_VERSION GREATER 4.8 AND CMAKE_CXX_COMPILER_VERSION LESS 9.2) # gcc/g++ <= 9.1 required, gcc/g++ 4.8.3 not ok
overlook_list_append(OVERLOOK_C_FLAGS -Werror=incompatible-pointer-types)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=incompatible-pointer-types)
endif()
elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=incompatible-pointer-types)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=incompatible-pointer-types)
endif()
# 4. 函数应该有返回值但没有return返回值;或不是所有路径都有返回值
# 解决bug：lane detect; vpdt for循环无法跳出(android输出trap)
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4716 /we4715)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4716 /we4715)
else()
overlook_list_append(OVERLOOK_C_FLAGS -Werror=return-type)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=return-type)
endif()
# 5. 避免使用影子(shadow)变量
# 有时候会误伤，例如eigen等开源项目，可以手动关掉
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we6244 /we6246 /we4457 /we4456)
overlook_list_append(OVERLOOK_CXX_FLAGS /we6244 /we6246 /we4457 /we4456)
else()
overlook_list_append(OVERLOOK_C_FLAGS -Werror=shadow)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=shadow)
endif()
# 6. 函数不应该返回局部变量的地址
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4172)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4172)
elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=return-local-addr)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=return-local-addr)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=return-stack-address)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=return-stack-address)
endif()
# 7. 变量没初始化就使用，要避免
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS "/we4700 /we26495")
overlook_list_append(OVERLOOK_CXX_FLAGS "/we4700 /we26495")
else()
overlook_list_append(OVERLOOK_C_FLAGS -Werror=uninitialized)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=uninitialized)
endif()
# 8. printf等语句中的格式串和实参类型不匹配，要避免
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4477)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4477)
else()
overlook_list_append(OVERLOOK_C_FLAGS -Werror=format)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=format)
endif()
# 9. 避免把unsigned int和int直接比较
# 通常会误伤，例如for循环中。可以考虑关掉
if(OVERLOOK_STRICT_FLAGS)
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4018)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4018)
elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=sign-compare)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=sign-compare)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=sign-compare)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=sign-compare)
endif()
endif()
# 10. 避免把int指针赋值给int类型变量
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4047)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4047)
elseif(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
if(CMAKE_CXX_COMPILER_VERSION GREATER 4.8 AND CMAKE_CXX_COMPILER_VERSION LESS 9.2) # gcc/g++ <= 9.1 required
overlook_list_append(OVERLOOK_C_FLAGS -Werror=int-conversion)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=int-conversion)
endif()
elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=int-conversion)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=int-conversion)
endif()
# 11. 检查数组下标越界访问
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS "/we6201 /we6386 /we4789")
overlook_list_append(OVERLOOK_CXX_FLAGS "/we6201 /we6386 /we4789")
else()
overlook_list_append(OVERLOOK_C_FLAGS -Werror=array-bounds)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=array-bounds)
endif()
# 12. 函数声明中的参数列表和定义中不一样。在MSVC C下为警告，Linux Clang下报错
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4029)
endif()
# 13. 实参太多，比函数定义或声明中的要多。只在纯MSVC C下为警告，Linux Clang下报错
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4020)
endif()
# 14. 避免void*类型的指针参参与算术运算
# MSVC C/C++默认会报错，Linux gcc不报warning和error，Linux g++只报warning
# Linux下 Clang开-Wpedentric才报warning，Clang++报error
if(CMAKE_C_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=pointer-arith)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=pointer-arith)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=pointer-arith)
endif()
# 15. 避免符号重复定义（变量对应的强弱符号）。只在纯C下出现。
# 暂时没找到MSVC的对应编译选项
if(CMAKE_C_COMPILER_ID MATCHES "GNU" OR CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -fno-common)
endif()
# 16. Windows下，源码已经是UTF-8编码，但输出中文到stdout时
# 要么编译报错，要么乱码。解决办法是编译输出为GBK格式
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS "/source-charset:utf-8 /execution-charset:gbk")
overlook_list_append(OVERLOOK_CXX_FLAGS "/source-charset:utf-8 /execution-charset:gbk")
endif()
# 17. 释放非堆内存
# TODO: 检查MSVC
# Linux Clang8.0无法检测到
if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=free-nonheap-object)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=free-nonheap-object)
endif()
# 18. 形参与声明不同。场景：静态库(.h/.c)，集成时换库但没换头文件，且函数形参有变化（类型或数量）
# 只报warning不报error。仅VS出现
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4028)
endif()
# 19. 宏定义重复
# gcc5~gcc9无法检查
if (0)
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4005)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4005)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=macro-redefined)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=macro-redefined)
endif()
endif()
# 20. pragma init_seg指定了非法（不能识别的）section名字
# VC++特有。Linux下的gcc/clang没有
if(CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_CXX_FLAGS /we4075)
endif()
# 21. size_t类型被转为更窄类型
# VC/VC++特有。Linux下的gcc/clang没有
# 有点过于严格了
if (OVERLOOK_STRICT_FLAGS)
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4267)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4267)
endif()
endif()
# 22. “类型强制转换”: 例如从“int”转换到更大的“void *”
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4312)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4312)
elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=int-to-pointer-cast)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=int-to-pointer-cast)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=int-to-pointer-cast)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=int-to-pointer-cast)
endif()
# 23. 不可识别的字符转义序列
# GCC5.4能显示warning但无别名，因而无法视为error
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4129)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4129)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=unknown-escape-sequence)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=unknown-escape-sequence)
endif()
# 24. 类函数宏的调用 参数过多
# VC/VC++报警告。Linux下的GCC/Clang报error
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4002)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4002)
endif()
# 25. 类函数宏的调用 参数不足
# VC/VC++同时会报error C2059
# Linux GCC/Clang直接报错
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4003)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4003)
endif()
# 26. #undef没有跟一个标识符
# Linux GCC/Clang直接报错
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4006)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4006)
endif()
# 27. 单行注释包含行继续符
# 可能会导致下一行代码报错，而问题根源在包含继续符的这行注释
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4006)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4006)
elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=comment)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=comment)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=comment)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=comment)
endif()
# 28. 没有使用到表达式结果（无用代码行，应删除）
# 感觉容易被误伤，可以考虑关掉
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS "/we4552 /we4555")
overlook_list_append(OVERLOOK_CXX_FLAGS "/we4552 /we4555")
elseif(CMAKE_C_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=unused-value)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=unused-value)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=unused-value)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=unused-value)
endif()
# 29. “==”: 未使用表达式结果；是否打算使用“=”?
# Linux GCC 没有对应的编译选项
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4553)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4553)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=unused-comparison)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=unused-comparison)
endif()
# 30. C++中，禁止把字符串常量赋值给char*变量
# VS2019开启/Wall后也查不到
if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=write-strings)
elseif(CMAKE_CXX_COMPILER_ID MATCHES "Clang")
# Linux Clang 和 AppleClang 不太一样
if (CMAKE_SYSTEM_NAME MATCHES "Linux")
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=writable-strings)
elseif(CMAKE_SYSTEM_NAME MATCHES "Darwin")
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=c++11-compat-deprecated-writable-strings)
endif()
endif()
# 31. 所有的控件路径(if/else)必须都有返回值
# NDK21 Clang / Linux Clang/GCC/G++ 默认都报 error
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
overlook_list_append(OVERLOOK_C_FLAGS /we4715)
overlook_list_append(OVERLOOK_CXX_FLAGS /we4715)
endif()
# 32. multi-char constant
# MSVC 没有对应的选项
if(CMAKE_C_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=multichar)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=multichar)
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang")
overlook_list_append(OVERLOOK_C_FLAGS -Werror=multichar)
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=multichar)
endif()
# 33. 用 memset 等 C 函数设置 非POD class 对象
# linux下，GCC9.3能发现此问题，但clang10不能发现
if(CMAKE_CXX_COMPILER_ID MATCHES "GNU")
overlook_list_append(OVERLOOK_CXX_FLAGS -Werror=class-memaccess)
endif()
# 将上述定制的FLAGS追加到CMAKE默认的编译选项中
# 为什么是添加而不是直接设定呢？因为toolchain（比如android的）会加料
if (USE_OVERLOOK_FLAGS)
overlook_list_append(CMAKE_C_FLAGS "${OVERLOOK_C_FLAGS}")
overlook_list_append(CMAKE_CXX_FLAGS "${OVERLOOK_CXX_FLAGS}")
overlook_list_append(CMAKE_C_FLAGS_DEBUG "${OVERLOOK_C_FLAGS}")
overlook_list_append(CMAKE_CXX_FLAGS_DEBUG "${OVERLOOK_CXX_FLAGS}")
overlook_list_append(CMAKE_C_FLAGS_RELEASE "${OVERLOOK_C_FLAGS}")
overlook_list_append(CMAKE_CXX_FLAGS_RELEASE "${OVERLOOK_CXX_FLAGS}")
overlook_list_append(CMAKE_C_FLAGS_MINSIZEREL "${OVERLOOK_C_FLAGS}")
overlook_list_append(CMAKE_CXX_FLAGS_MINSIZEREL "${OVERLOOK_CXX_FLAGS}")
overlook_list_append(CMAKE_C_FLAGS_RELWITHDEBINFO "${OVERLOOK_C_FLAGS}")
overlook_list_append(CMAKE_CXX_FLAGS_RELWITHDEBINFO "${OVERLOOK_CXX_FLAGS}")
endif()
if (OVERLOOK_VERBOSE)
message(STATUS "--- OVERLOOK_C_FLAGS are: ${OVERLOOK_C_FLAGS}")
message(STATUS "--- OVERLOOK_CXX_FLAGS are: ${OVERLOOK_CXX_FLAGS}")
endif()
#################################################
#
# Add whole archive when build static library
#
#################################################
function (overlook_add_whole_archive_flag lib output_var)
#message(FATAL_ERROR "=== linker is: ${ANDROID_LD}")
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
message(STATUS "not supported yet")
elseif(CMAKE_C_COMPILER_ID MATCHES "Clang" AND NOT ANDROID)
set(${output_var} -Wl,-force_load ${lib} PARENT_SCOPE)
else()
#即使是NDK21并且手动传入ANDROID_LD=lld，依然要用ld的查重复符号的链接选项
set(${output_var} -Wl,--whole-archive ${lib} -Wl,--no-whole-archive PARENT_SCOPE)
endif()
endfunction()
#################################################
#
# cppcheck，开启静态代码检查，主要是检查编译器检测不到的UB
# 注：目前只有终端下能看到对应输出，其中NDK下仅第一次输出
#
#################################################
if(USE_CPPCHECK)
find_program(CMAKE_CXX_CPPCHECK NAMES cppcheck)
if (CMAKE_CXX_CPPCHECK)
message(STATUS "cppcheck found")
list(APPEND CMAKE_CXX_CPPCHECK
"--enable=warning"
"--inconclusive"
"--force"
"--inline-suppr"
)
else()
message(STATUS "cppcheck not found. ignore it")
endif()
endif()
#################################################
#
# Platform determinations
#
#################################################
if (CMAKE_SYSTEM_NAME MATCHES "Windows")
set(OVERLOOK_SYSTEM "Windows")
elseif (ANDROID)
set(OVERLOOK_SYSTEM "Android")
elseif (CMAKE_SYSTEM_NAME MATCHES "Linux")
set(OVERLOOK_SYSTEM "Linux")
elseif (CMAKE_SYSTEM_NAME MATCHES "Darwin")
set(OVERLOOK_SYSTEM "MacOS")
else ()
message(FATAL_ERROR "un-configured system: ${CMAKE_SYSTEM_NAME}")
endif()
if (OVERLOOK_VERBOSE)
message(STATUS "----- OVERLOOK_SYSTEM: ${OVERLOOK_SYSTEM}")
endif()
#################################################
#
# Architecture determinations
#
#################################################
if((IOS AND CMAKE_OSX_ARCHITECTURES MATCHES "arm") #没匹配ARM
OR (CMAKE_SYSTEM_PROCESSOR MATCHES "^(arm|Arm|ARM|aarch64|AAarch64|AARCH64)"))
set(OVERLOOK_ARCH arm)
elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(mips|Mips|MIPS)")
set(OVERLOOK_ARCH mips)
elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(riscv|Riscv|RISCV)")
set(OVERLOOK_ARCH riscv)
elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^(powerpc|PowerPC|POWERPC)")
set(OVERLOOK_ARCH powerpc)
else()
set(OVERLOOK_ARCH x86)
#if(CMAKE_SYSTEM_NAME STREQUAL "Emscripten") #wasm
#endif()
endif()
if (OVERLOOK_VERBOSE)
message(STATUS "----- OVERLOOK_ARCH: ${OVERLOOK_ARCH}")
endif()
#################################################
#
# ABI determinations
#
#################################################
if (ANDROID)
set(OVERLOOK_ABI ${ANDROID_ABI})
elseif (OVERLOOK_ARCH STREQUAL x86)
if(CMAKE_SIZEOF_VOID_P EQUAL 8)
set(OVERLOOK_ABI "x64")
else()
set(OVERLOOK_ABI "x86")
endif()
elseif (OVERLOOK_ARCH STREQUAL arm)
# determine ARCH from compiler name. Note: we can't use MATCHES for c++ compiler, since `++` failed for regular expression
if(CMAKE_C_COMPILER MATCHES "aarch64-linux-gnu-gcc")
set(OVERLOOK_ABI "aarch64")
elseif(CMAKE_C_COMPILER MATCHES "arm-linux-gnueabihf-gcc")
set(OVERLOOK_ABI "arm-eabihf")
elseif(CMAKE_C_COMPILER MATCHES "aarch64-none-linux-gnu-gcc")
set(OVERLOOK_ABI "aarch64")
else()
message(FATAL_ERROR "un-assigned ABI, please add it now")
endif()
else()
message(FATAL_ERROR "un-assigned ABI, please add it now")
endif()
if (OVERLOOK_VERBOSE)
message(STATUS "----- OVERLOOK_ABI: ${OVERLOOK_ABI}")
endif()
#################################################
#
# Visual Studio stuffs: vs_version, vc_version
#
#################################################
if(CMAKE_C_COMPILER_ID STREQUAL "MSVC")
if(MSVC_VERSION EQUAL 1600)
set(vs_version vs2010)
set(vc_version vc10)
elseif(MSVC_VERSION EQUAL 1700)
set(vs_version vs2012)
set(vc_version vc11)
elseif(MSVC_VERSION EQUAL 1800)
set(vs_version vs2013)
set(vc_version vc12)
elseif(MSVC_VERSION EQUAL 1900)
set(vs_version vs2015)
set(vc_version vc14)
elseif(MSVC_VERSION GREATER_EQUAL 1910 AND MSVC_VERSION LESS_EQUAL 1920)
set(vs_version vs2017)
set(vc_version vc15)
elseif(MSVC_VERSION GREATER_EQUAL 1920)
set(vs_version vs2019)
set(vc_version vc16)
endif()
endif()