build.gradle

buildscript {
    ext {
        kotlinVersion = "1.4.10"
        detektVersion = "1.12.0-RC1"
    }
    repositories {
        jcenter()
        gradlePluginPortal()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:${kotlinVersion}"
        classpath "com.jfrog.bintray.gradle:gradle-bintray-plugin:1.8.4"
        classpath "io.gitlab.arturbosch.detekt:detekt-gradle-plugin:${detektVersion}"
    }
}

allprojects {
    group = "me.liuwj.ktorm"
    version = "3.1.0"
}

subprojects { project ->
    apply plugin: "kotlin"
    apply plugin: "maven-publish"
    apply plugin: "com.jfrog.bintray"
    apply plugin: "io.gitlab.arturbosch.detekt"
    apply from: "${project.rootDir}/check-source-header.gradle"

    repositories {
        jcenter()
    }

    dependencies {
        api "org.jetbrains.kotlin:kotlin-stdlib:${kotlinVersion}"
        api "org.jetbrains.kotlin:kotlin-reflect:${kotlinVersion}"
        testImplementation "junit:junit:4.12"
        detektPlugins "io.gitlab.arturbosch.detekt:detekt-formatting:${detektVersion}"
    }

    compileKotlin {
        kotlinOptions.jvmTarget = "1.6"
        kotlinOptions.allWarningsAsErrors = true
        kotlinOptions.freeCompilerArgs = [
            "-Xexplicit-api=strict",
            "-Xopt-in=kotlin.RequiresOptIn"
        ]
    }

    task generateSourcesJar(type: Jar) {
        archiveClassifier = "sources"
        from sourceSets.main.allSource
    }

    task generateJavadoc(type: Jar) {
        archiveClassifier = "javadoc"
    }

    detekt {
        toolVersion = detektVersion
        config = files("${project.rootDir}/detekt.yml")
        reports {
            xml.enabled = false
            html.enabled = false
        }
    }

    publishing {
        publications {
            bintray(MavenPublication) {
                from components.java
                artifact generateSourcesJar
                artifact generateJavadoc

                groupId project.group
                artifactId project.name
                version project.version

                pom {
                    name = project.name
                    description = "A lightweight ORM Framework for Kotlin with strong typed SQL DSL and sequence APIs."
                    url = "https://github.com/kotlin-orm/ktorm"
                    licenses {
                        license {
                            name = "The Apache Software License, Version 2.0"
                            url = "http://www.apache.org/licenses/LICENSE-2.0.txt"
                        }
                    }
                    developers {
                        developer {
                            id = "vincentlauvlwj"
                            name = "vince"
                            email = "me@liuwj.me"
                        }
                        developer {
                            id = "waluo"
                            name = "waluo"
                            email = "1b79349b@gmail.com"
                        }
                        developer {
                            id = "clydebarrow"
                            name = "Clyde"
                            email = "clyde@control-j.com"
                        }
                        developer {
                            id = "Ray-Eldath"
                            name = "Ray Eldath"
                            email = "ray.eldath@outlook.com"
                        }
                        developer {
                            id = "hangingman"
                            name = "hiroyuki.nagata"
                            email = "idiotpanzer@gmail.com"
                        }
                        developer {
                            id = "onXoot"
                            name = "beetlerx"
                            email = "beetlerx@gmail.com"
                        }
                        developer {
                            id = "arustleund"
                            name = "Andrew Rustleund"
                            email = "andrew@rustleund.com"
                        }
                        developer {
                            id = "afezeria"
                            name = "afezeria"
                            email = "zodal@outlook.com"
                        }
                        developer {
                            id = "scorsi"
                            name = "Sylvain Corsini"
                            email = "sylvain.corsini@protonmail.com"
                        }
                        developer {
                            id = "lyndsysimon"
                            name = "Lyndsy Simon"
                            email = "lyndsy@lyndsysimon.com"
                        }
                        developer {
                            id = "antonydenyer"
                            name = "Antony Denyer"
                            email = "git@antonydenyer.co.uk"
                        }
                    }
                    scm {
                        url = "https://github.com/kotlin-orm/ktorm.git"
                    }
                }
            }
        }
    }

    bintray {
        user = System.getenv("BINTRAY_USER")
        key = System.getenv("BINTRAY_KEY")
        publications = ["bintray"]
        publish = true

        pkg {
            repo = "maven"
            name = project.name
            licenses = ["Apache-2.0"]
            vcsUrl = "https://github.com/kotlin-orm/ktorm.git"
            labels = ["Kotlin", "ORM", "SQL"]

            version {
                name = project.version
                released = new Date()
                vcsTag = project.version

                mavenCentralSync {
                    sync = false
                    user = System.getenv("OSSRH_USER")
                    password = System.getenv("OSSRH_PASSWORD")
                }
            }
        }
    }
}

task printClasspath() {
    doLast {
        def jars = subprojects.collect { it.configurations.compileClasspath.getFiles() }.flatten().toSet()
        jars.removeIf { it.name.contains("ktorm") }

        println("Project classpath: ")
        jars.each { println(it.name) }

        def file = file("build/ktorm.classpath")
        file.parentFile.mkdirs()
        file.write(jars.collect { it.absolutePath }.join(File.pathSeparator))
        println("Classpath written to build/ktorm.classpath")
    }
}