SConstruct

import os
import platform

import awtk_config as awtk

DefaultEnvironment(
  CCFLAGS = awtk.CCFLAGS, 
  CFLAGS = awtk.CFLAGS,
  CC=awtk.TOOLS_PREFIX+'gcc',
  CXX=awtk.TOOLS_PREFIX+'g++',
  LD=awtk.TOOLS_PREFIX+'g++',
  AR=awtk.TOOLS_PREFIX+'ar',
  STRIP=awtk.TOOLS_PREFIX+'strip',
  LIBS = awtk.LIBS,
  LIBPATH = awtk.LIBPATH,
  CPPPATH = awtk.CPPPATH,
  LINKFLAGS = awtk.LINKFLAGS,
  OS_SUBSYSTEM_CONSOLE=awtk.OS_SUBSYSTEM_CONSOLE,
  OS_SUBSYSTEM_WINDOWS=awtk.OS_SUBSYSTEM_WINDOWS,
  OBJSUFFIX  = ".o",
  PROGSUFFIX = "",
  TARGET_ARCH = "arm",
  ENV = {'PATH' : os.environ['PATH']}
)

APP_ROOT=ARGUMENTS.get('APP', '')
TK_ROOT_VAR = awtk.joinPath(awtk.VAR_DIR, 'awtk')
VariantDir(TK_ROOT_VAR, awtk.TK_ROOT)

if APP_ROOT == '':
  APP_PROJ_VAR = [awtk.joinPath(TK_ROOT_VAR, 'demos/SConscript')]
else:
  (APP_PATH, APP_NAME) = os.path.split(APP_ROOT)
  APP_ROOT_VAR = awtk.joinPath(awtk.VAR_DIR, APP_NAME)
  APP_PROJ_VAR = [awtk.joinPath(APP_ROOT_VAR, 'src/SConscript')]
  VariantDir(APP_ROOT_VAR, APP_ROOT)

SConscriptFiles=[
  awtk.joinPath(TK_ROOT_VAR, '3rd/glad/SConscript'),
  awtk.joinPath(TK_ROOT_VAR, '3rd/nanovg/SConscript'),
  awtk.joinPath(TK_ROOT_VAR, '3rd/gpinyin/SConscript'), 
  awtk.joinPath(TK_ROOT_VAR, '3rd/libunibreak/SConscript'),
  awtk.joinPath(TK_ROOT_VAR, 'src/SConscript'),
  awtk.joinPath(TK_ROOT_VAR, 'tools/common/SConscript'), 
  awtk.joinPath(TK_ROOT_VAR, 'tools/ui_gen/xml_to_ui/SConscript'),
  'gl/src/SConscript',
  ] + APP_PROJ_VAR;

SConscript(SConscriptFiles)