@zpm-get-plugin-file-path

#!/usr/bin/env zsh

local Plugin="${1}"
local Plugin_path="${2}"
local Plugin_basename="${3}"

# Workaround for zsh-syntax-highlighting
if [[ "$Plugin" == 'zsh-users/zsh-syntax-highlighting' ]]; then
  echo "${Plugin_path}/zsh-syntax-highlighting.zsh"
  return 0
fi

# Workaround for zsh-history-substring-search
if [[ "$Plugin" == 'zsh-users/zsh-history-substring-search' ]]; then
  echo "${Plugin_path}/zsh-history-substring-search.zsh"
  return 0
fi

local Plugin_basename_clean=$Plugin_basename
Plugin_basename_clean=${Plugin_basename_clean##oh-my-zsh-}
Plugin_basename_clean=${Plugin_basename_clean##zsh-}
Plugin_basename_clean=${Plugin_basename_clean%%.plugin}
Plugin_basename_clean=${Plugin_basename_clean%%-plugin}
Plugin_basename_clean=${Plugin_basename_clean%%.zsh}
Plugin_basename_clean=${Plugin_basename_clean%%-zsh}
Plugin_basename_clean=${Plugin_basename_clean%%.plugin}
Plugin_basename_clean=${Plugin_basename_clean%%-plugin}

if [[ "$Plugin"  == *",source:"* ]]; then
  local Plugin_sourcefile="${${Plugin##*,source:}%%,*}"
  if [[ -n "${Plugin_sourcefile}" && -e "${Plugin_path}/${Plugin_sourcefile}" ]]; then
    echo "${Plugin_path}/${Plugin_sourcefile}"
    return 0
  else
    return -1
  fi
elif [[ -e "${Plugin_path}/${Plugin_basename_clean}.zsh" ]]; then
  echo "${Plugin_path}/${Plugin_basename_clean}.zsh"
elif [[ -e "${Plugin_path}/zsh-${Plugin_basename_clean}.zsh" ]]; then
  echo "${Plugin_path}/zsh-${Plugin_basename_clean}.zsh"
elif [[ -e "${Plugin_path}/${Plugin_basename_clean}.plugin.zsh" ]]; then
  echo "${Plugin_path}/${Plugin_basename_clean}.plugin.zsh"
elif [[ -e "${Plugin_path}/zsh-${Plugin_basename_clean}.plugin.zsh" ]]; then
  echo "${Plugin_path}/zsh-${Plugin_basename_clean}.plugin.zsh"
elif [[ -e "${Plugin_path}/${Plugin_basename_clean}.zsh-theme" ]]; then
  echo "${Plugin_path}/${Plugin_basename_clean}.zsh-theme"
elif [[ -e "${Plugin_path}/init.zsh" ]]; then
  echo "${Plugin_path}/init.zsh"
else
  return -1
fi