Initialize Context from JSON-encoded ENV variables

spec/raven/context_spec.cr

@@ -0,0 +1,38 @@
+require "../spec_helper"
+
+describe Raven::Context do
+  {% for key in %i(user extra tags) %}
+    {% env_key = "SENTRY_CONTEXT_#{key.upcase.id}" %}
+
+    context %(with ENV["{{ env_key.id }}"]?) do
+      it "initializes from valid JSON-encoded string" do
+        with_clean_env do
+          ENV[{{ env_key }}] = {foo: :bar}.to_json
+
+          context = Raven::Context.new
+          context.{{ key.id }}.should eq({"foo" => "bar"})
+        end
+      end
+
+      it "raises when JSON-encoded string is not a Hash" do
+        with_clean_env do
+          ENV[{{ env_key }}] = (0..3).to_a.to_json
+
+          expect_raises(Raven::Error, {{ env_key }}) do
+            Raven::Context.new
+          end
+        end
+      end
+
+      it "raises on invalid JSON-encoded string" do
+        with_clean_env do
+          ENV[{{ env_key }}] = "foo"
+
+          expect_raises(Raven::Error, {{ env_key }}) do
+            Raven::Context.new
+          end
+        end
+      end
+    end
+  {% end %}
+end

src/raven/context.cr

@@ -36,10 +36,29 @@ module Raven
     any_json_property :contexts, :extra, :tags, :user
 
     def initialize
-      @contexts = {
+      self.contexts = {
         os:      self.class.os_context,
         runtime: self.class.runtime_context,
-      }.to_any_json
+      }
+      initialize_from_env
+    end
+
+    protected def initialize_from_env
+      {% for key in %i(user extra tags) %}
+        {% env_key = "SENTRY_CONTEXT_#{key.upcase.id}" %}
+
+        if %context = ENV[{{ env_key }}]?.presence
+          begin
+            if %json = JSON.parse(%context).as_h?
+              self.{{ key.id }}.merge!(%json)
+            else
+              raise Raven::Error.new("`{{ env_key.id }}` must contain a JSON-encoded hash")
+            end
+          rescue %e : JSON::ParseException
+            raise Raven::Error.new("Invalid JSON string in `{{ env_key.id }}`", cause: %e)
+          end
+        end
+      {% end %}
     end
   end
 end