games-emulation/stella: add 6.7

Signed-off-by: Ionen Wolkens <[email protected]>

games-emulation/stella/Manifest

@@ -1 +1,2 @@
 DIST stella-6.6-src.tar.xz 10035924 BLAKE2B bb1b6a5d7ea9ada8aac24084f508692472f78a6e04528f57a88ca7ac76d23f0dfe1050a1f013103463b2ee2d7b842a9b30e1b36b2aefc183ce1a39682eb867fa SHA512 89aea0cec9c2f22f276c1c4b36b76deb1ef9fb913c959f93f8cbcac300acdb23d2e3e66981d3263ea1ccfd72aaab1aa47218136b82b5e12aa8fbf352959743ab
+DIST stella-6.7-src.tar.xz 10280224 BLAKE2B da2920384b6b254edd8f615c665ea1eef79030afffdf1b442f490f026c6f577ba4f7329531159767ba720207aeeb14388b5970bdd3e250b0db54e12d5f791396 SHA512 c20a2e9d98e1330f151e5f7d0e7cf15b2279b0d5f1175269f4084bf4964337b998118800615ae62eabf9d0f8abe0bb9cd02bddd1ee827121a49131888b4946ff

games-emulation/stella/stella-6.7.ebuild

@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs xdg
+
+DESCRIPTION="Multi-platform Atari 2600 VCS Emulator"
+HOMEPAGE="https://stella-emu.github.io/"
+SRC_URI="https://github.com/stella-emu/stella/releases/download/${PV}/${P}-src.tar.xz"
+
+LICENSE="GPL-2+ BSD MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+joystick png zlib"
+REQUIRED_USE="png? ( zlib )"
+
+RDEPEND="
+	dev-db/sqlite:3
+	media-libs/libsdl2[joystick?,opengl,sound,video]
+	png? ( media-libs/libpng:= )
+	zlib? ( sys-libs/zlib:= )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+src_prepare() {
+	default
+
+	sed -i 's/pkg-config/${PKG_CONFIG}/' configure || die
+	sed -i '/CXXFLAGS+=/s/-fomit-frame-pointer//' Makefile || die
+}
+
+src_configure() {
+	tc-export CC CXX PKG_CONFIG
+
+	# not autotools-based
+	local configure=(
+		./configure
+		--host=${CHOST}
+		--prefix="${EPREFIX}"/usr
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}/html
+		--use-system-sqlite
+		$(use_enable joystick)
+		$(use_enable png)
+		$(use_enable zlib zip)
+		${EXTRA_ECONF}
+	)
+
+	echo ${configure[*]}
+	"${configure[@]}" || die
+}
+
+src_install() {
+	local DOCS=(
+		Announce.txt Changes.txt README-SDL.txt
+		Readme.txt docs/R77_readme.txt Todo.txt
+	)
+
+	default
+
+	rm "${ED}"/usr/share/doc/${PF}/html/*.txt || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if [[ ${REPLACING_VERSIONS} ]] && ver_test ${REPLACING_VERSIONS} -lt 6.7; then
+		elog "With version >=6.7, because of fixes to JSON handling, all remappings"
+		elog "will be reset to defaults. If you had custom mappings, they will need"
+		elog "to be re-entered again."
+		elog
+		elog "Furthermore, because of internal changes, all old state files are invalid."
+	fi
+}