Split more things into libraries

CMake/functions/devilutionx_library.cmake

@@ -1,5 +1,6 @@
 include(functions/genex)
 include(functions/set_relative_file_macro)
+include(functions/object_libraries)
 
 # This function is equivalent to `add_library` but applies DevilutionX-specific
 # compilation flags to it.
@@ -68,12 +69,7 @@ function(add_devilutionx_library NAME)
   set_relative_file_macro(${NAME})
 endfunction()
 
-# Same as add_devilutionx_library(${NAME} OBJECT) with an additional
-# workaround for https://gitlab.kitware.com/cmake/cmake/-/issues/18090,
-# allowing this object library to be "linked" to other object libraries.
+# Same as add_devilutionx_library(${NAME} OBJECT).
 function(add_devilutionx_object_library NAME)
   add_devilutionx_library(${NAME} OBJECT ${ARGN})
-
-  # See https://gitlab.kitware.com/cmake/cmake/-/issues/18090
-  target_sources(${NAME} INTERFACE $<TARGET_OBJECTS:${NAME}>)
 endfunction()

CMake/functions/object_libraries.cmake

@@ -0,0 +1,47 @@
+# CMake has limited support for object libraries.
+#
+# The main limitation of CMake object libraries is the lack
+# of transitive dependency support.
+# The functions here provide a workaround for that.
+#
+# Use `target_link_dependencies` instead of `target_link_libraries`
+#
+# https://gitlab.kitware.com/cmake/cmake/-/issues/18090#note_861617
+
+# Behaves like target_link_libraries, but propagates OBJECT libraries' objects
+#   up to the first non-object library.
+function(target_link_dependencies TARGET)
+  set(MODES PUBLIC PRIVATE INTERFACE)
+  set(MODE PUBLIC)
+  foreach(ARG ${ARGN})
+    if(ARG IN_LIST MODES)
+      set(MODE ${ARG})
+      continue()
+    endif()
+
+    if(TARGET "${ARG}")
+      # When linking two OBJECT libraries together, record the input library objects in
+      #   a custom target property "LINKED_OBJECTS" together with any other existing ones
+      #   from the input library's LINKED_OBJECTS property.
+      # Accumulate LINKED_OBJECTS until reaching a non-object target, and add them as
+      #   extra sources - this will de-duplicate the list and link it into the target.
+      set(LIBRARY "${ARG}")
+      get_target_property(TARGET_TYPE ${TARGET} TYPE)
+      get_target_property(LIBRARY_TYPE ${LIBRARY} TYPE)
+
+      if(LIBRARY_TYPE STREQUAL "OBJECT_LIBRARY")
+        if(TARGET_TYPE STREQUAL "INTERFACE_LIBRARY")
+          message(FATAL_ERROR "OBJECT to INTERFACE library linking is not supported.")
+        endif()
+        get_target_property(LIBRARY_LINKED_OBJECTS ${LIBRARY} LINKED_OBJECTS)
+        if(TARGET_TYPE STREQUAL "OBJECT_LIBRARY")
+          set_property(TARGET ${TARGET} APPEND PROPERTY LINKED_OBJECTS $<TARGET_OBJECTS:${LIBRARY}>)
+        elseif(NOT LIBRARY_LINKED_OBJECTS STREQUAL "LIBRARY_LINKED_OBJECTS-NOTFOUND")
+          target_sources(${TARGET} PRIVATE ${LIBRARY_LINKED_OBJECTS})
+        endif()
+      endif()
+    endif()
+
+    target_link_libraries(${TARGET} ${MODE} "${ARG}")
+  endforeach()
+endfunction()

CMake/platforms/uwp_lib.cmake

@@ -25,3 +25,8 @@ set(DEVILUTIONX_STATIC_ZLIB ON)
 
 # not really necessary but a good measure for SDL related stuff
 set(WINDOWS_STORE ON)
+
+add_library(uwp_defs INTERFACE)
+target_compile_definitions(uwp_defs INTERFACE __UWP__=1)
+set(DEVILUTIONX_PLATFORM_INIT_LINK_LIBRARIES uwp_defs)
+set(DEVILUTIONX_PLATFORM_LINK_LIBRARIES uwp_defs)

CMake/platforms/windows.cmake

@@ -2,6 +2,9 @@ set(ASAN OFF)
 set(UBSAN OFF)
 set(DIST ON)
 
+set(DEVILUTIONX_PLATFORM_FILE_UTIL_LINK_LIBRARIES shlwapi)
+set(DEVILUTIONX_PLATFORM_INIT_LINK_LIBRARIES find_steam_game)
+
 list(APPEND DEVILUTIONX_PLATFORM_LINK_LIBRARIES
   find_steam_game
   shlwapi

CMake/platforms/windows9x.cmake

@@ -19,6 +19,7 @@ set(DEVILUTIONX_WINDOWS_NO_WCHAR ON)
 # MinGW force-defines `_WIN32_WINNT=0xa00` if it isn't defined, so define it as 0.
 add_definitions(-DWINVER=0x0500 -D_WIN32_WINDOWS=0x0500 -D_WIN32_WINNT=0)
 
+set(DEVILUTIONX_PLATFORM_FILE_UTIL_LINK_LIBRARIES shlwapi)
 list(APPEND DEVILUTIONX_PLATFORM_LINK_LIBRARIES
   shlwapi
   wsock32

CMakeLists.txt

@@ -335,7 +335,9 @@ endif()
 if(ANDROID)
   add_library(${BIN_TARGET} SHARED Source/main.cpp)
 elseif(UWP_LIB)
-  add_custom_target(${BIN_TARGET})  # we only need libdevilutionx
+  get_target_property(_linked_objects libdevilutionx LINKED_OBJECTS)
+  target_sources(libdevilutionx PRIVATE ${_linked_objects})
+  set(BIN_TARGET libdevilutionx)
 else()
   add_executable(${BIN_TARGET}
     WIN32
@@ -355,7 +357,7 @@ else()
 endif()
 
 if(NOT UWP_LIB)
-  target_link_libraries(${BIN_TARGET} PRIVATE libdevilutionx)
+  target_link_dependencies(${BIN_TARGET} PRIVATE libdevilutionx)
 endif()
 
 if(GPERF)
@@ -393,9 +395,9 @@ if(APPLE)
     set(MACOSX_BUNDLE_REQUIRED_PLATFORM IPhoneOS)
     set_target_properties(${BIN_TARGET} PROPERTIES XCODE_ATTRIBUTE_TARGETED_DEVICE_FAMILY "1,2")
     set(CMAKE_OSX_DEPLOYMENT_TARGET "9.0")
-  elseif(DARWIN_MAJOR_VERSION GREATER_EQUAL 16)
+  elseif(DARWIN_MAJOR_VERSION GREATER_EQUAL 17)
     set(MACOSX_BUNDLE_REQUIRED_PLATFORM Carbon)
-    set(CMAKE_OSX_DEPLOYMENT_TARGET "10.12.0")
+    set(CMAKE_OSX_DEPLOYMENT_TARGET "10.13.0")
   endif()
   if(DARWIN_MAJOR_VERSION VERSION_LESS 9)
     # Finder on OSX Tiger can only handle icns files with up to 128x128 icons.
@@ -506,10 +508,6 @@ if(NINTENDO_3DS)
   add_cia_target(${BIN_TARGET} ${APP_RSF} ${APP_BANNER} ${APP_AUDIO})
 endif()
 
-if(UWP_LIB)
-  target_compile_definitions(libdevilutionx PRIVATE __UWP__=1)
-endif()
-
 if(NXDK)
   target_link_libraries(${BIN_TARGET} PRIVATE "${NXDK_DIR}/lib/libnxdk_automount_d.lib")
   target_link_options(${BIN_TARGET} PRIVATE "-include:_automount_d_drive")