Switch to gradle build

build.gradle

@@ -0,0 +1,44 @@
+plugins {
+    id  "com.github.johnrengelman.shadow" version "2.0.4"
+    id  'java'
+    id  'maven'
+    id  'maven-publish'
+}
+
+allprojects  {
+  repositories {
+     mavenCentral()
+     mavenLocal()
+     maven { url "https://oss.sonatype.org/content/repositories/releases" }
+     maven { url "http://repo.mikeprimm.com" }
+     maven { url "http://repo.maven.apache.org/maven2" }
+     maven { url "https://hub.spigotmc.org/nexus/content/repositories/snapshots/" }
+     maven { url "http://repo.bstats.org/content/repositories/releases/" }
+  }
+
+  apply plugin: 'java'
+
+  group = 'us.dynmap'
+  version = '3.0-SNAPSHOT'
+
+}
+
+class Globals {
+  String buildNumber =  System.getenv().BUILD_NUMBER ?: "Dev"
+}
+ext {
+  globals = new Globals()
+}
+
+subprojects {  
+  apply plugin: "com.github.johnrengelman.shadow"
+  apply plugin: 'java'
+  apply plugin: 'maven'
+  apply plugin: 'maven-publish'
+
+  sourceCompatibility = 1.8
+  targetCompatibility = 1.8
+  tasks.withType(JavaCompile) {
+  	options.encoding = 'UTF-8'
+  }
+}

bukkit/.gitignore

@@ -1,2 +1,3 @@
 /target/
 /dependency-reduced-pom.xml
+/build/

bukkit/build.gradle

@@ -0,0 +1,53 @@
+
+description = 'dynmap'
+
+dependencies {
+  compile group: 'org.bukkit', name: 'bukkit', version:'1.7.10-R0.1-SNAPSHOT'
+    compile 'com.nijikokun.bukkit:Permissions:3.1.6'
+    compile "us.dynmap:dynmap-api:${project.version}"
+    compile "us.dynmap:DynmapCore:${project.version}"
+    compile group: 'ru.tehkode', name: 'PermissionsEx', version:'1.19.1'
+    compile group: 'de.bananaco', name: 'bPermissions', version:'2.9.1'
+    compile group: 'com.platymuus.bukkit.permissions', name: 'PermissionsBukkit', version:'1.6'
+    compile group: 'org.anjocaido', name: 'EssentialsGroupManager', version:'2.10.1'
+    compile group: 'org.bstats', name: 'bstats-bukkit', version:'1.1'
+    compile group: 'com.googlecode.json-simple', name: 'json-simple', version:'1.1.1'
+    compile group: 'com.google.code.gson', name: 'gson', version:'2.8.2'
+    compile project(':dynmap-helper')
+    implementation(project(':dynmap-helper-113')) { 
+        transitive = false
+    }
+}
+
+processResources {
+    // replace stuff in mcmod.info, nothing else
+	from('src/main/resources') {
+	    include "plugin.yml"
+        // replace version and mcversion
+        expand(
+                buildnumber: project.parent.ext.globals.buildNumber,
+                version: project.version
+        )
+    }
+}
+
+jar {
+   classifier = 'unshaded'
+}
+
+shadowJar {
+    dependencies {
+        include(dependency('org.bstats::'))
+		include(dependency('us.dynmap:dynmap-api:'))
+		include(dependency('us.dynmap:DynmapCore:'))
+        include(dependency(':dynmap-helper'))
+        include(dependency(':dynmap-helper-113'))
+	}
+	relocate('org.bstats', 'org.dynmap.bstats')
+    destinationDir = file '../target'
+    classifier = ''
+}
+
+artifacts {
+    archives shadowJar
+}