app-misc/filebus: Bump to version 0.3.4

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Zac Medico <[email protected]>

app-misc/filebus/Manifest

@@ -1 +1,2 @@
 DIST filebus-0.3.2.tar.gz 17310 BLAKE2B 0f30aabcd316f52ea12d12b136befe643085dff5e283f65edf2a459b127cd3e2d48c472ae0dd8f302bb7211e4da5541a6fc7ac274573631ab03fc246bc8b566f SHA512 88ce3cd2d8aec7afd30d16315a6a8a37dee1b21d882571ef87c7dca56251e737d6500a5fad0124c62aea6383aae5ec30abd8abf86c2fac5d582f8fe96049eaa6
+DIST filebus-0.3.4.tar.gz 17404 BLAKE2B cf6a3fef2e7f3d69fb73df3f9134666e5d1d09d02cc94cd73c2818b1fc92132fafeb8b3b6f904316ab57a3aab4fa01ba00e0e5bfabf9a9c5194de3d6a8666417 SHA512 0619eda926ca77730558600d29a1b7811972b411b86d6c5374f1ccbcd0a4901f70eb87df7577690d72bb7eec4a4191f3b7b4bca237317352bdc0f0ce0f36f120

app-misc/filebus/filebus-0.3.4.ebuild

@@ -0,0 +1,68 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+DISTUTILS_OPTIONAL=1
+DISTUTILS_USE_SETUPTOOLS=manual
+PYTHON_COMPAT=( python3_{7,8,9,10} )
+
+inherit distutils-r1
+
+DESCRIPTION="A user space multicast named pipe implementation backed by a regular file"
+HOMEPAGE="https://github.com/pipebus/filebus"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+KEYWORDS="~amd64"
+SLOT="0"
+IUSE="+inotify python test"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RDEPEND="
+	python? (
+		${PYTHON_DEPS}
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-python/filelock[${PYTHON_USEDEP}]
+		inotify? ( dev-python/watchdog[${PYTHON_USEDEP}] )
+	)"
+BDEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+	if use python; then
+		distutils-r1_src_prepare
+	fi
+}
+
+src_compile() {
+	if use python; then
+		distutils-r1_src_compile
+	fi
+}
+
+src_test() {
+	"${BASH}" ./lib/bash/filebus-test.bash test || die
+
+	if use python; then
+		distutils-r1_src_test
+	fi
+}
+
+python_test() {
+	python test/test_filebus.py || die "tests failed for ${EPYTHON}"
+}
+
+src_install() {
+	if use python; then
+		distutils-r1_src_install
+	else
+		insinto /usr/libexec/filebus
+		doins lib/bash/*.bash
+		cat <<-EOF > "${T}/filebus"
+		#!/bin/sh
+		exec bash "${EPREFIX}/usr/libexec/filebus/filebus.bash" "\$@"
+		EOF
+		dobin "${T}/filebus"
+		dosym filebus /usr/bin/pipebus
+	fi
+}