kde-base/kdeplasma-addons: Add use flag eigen

Gentoo-bug: 576986 Reported-by: Alexander Stein <[email protected]> Package-Manager: portage-2.2.28
hanetzer · Mar 26, 2016 · 0d6524f · 0d6524f
1 parent 416725d
commit 0d6524f
Show file tree

Hide file tree

Showing 2 changed files with 64 additions and 0 deletions.
diff --git a/kde-base/kdeplasma-addons/kdeplasma-addons-4.14.3-r1.ebuild b/kde-base/kdeplasma-addons/kdeplasma-addons-4.14.3-r1.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit flag-o-matic kde4-base
+
+DESCRIPTION="Extra Plasma applets and engines"
+LICENSE="GPL-2 LGPL-2"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="attica debug desktopglobe eigen exif fcitx ibus json +kdepim oauth
+qalculate qwt scim"
+
+RESTRICT=test
+# tests hang
+
+# krunner is only needed to generate dbus interface for lancelot
+COMMON_DEPEND="
+	app-crypt/qca:2[qt4(+)]
+	$(add_kdebase_dep krunner '' 4.11)
+	$(add_kdebase_dep plasma-workspace '' 4.11)
+	x11-misc/shared-mime-info
+	attica? ( dev-libs/libattica )
+	desktopglobe? ( $(add_kdeapps_dep marble) )
+	exif? ( $(add_kdeapps_dep libkexiv2) )
+	fcitx? ( app-i18n/fcitx[dbus(+)] )
+	ibus? ( app-i18n/ibus )
+	json? ( dev-libs/qjson )
+	kdepim? ( $(add_kdeapps_dep kdepimlibs) )
+	oauth? ( dev-libs/qoauth:0 )
+	qalculate? ( sci-libs/libqalculate )
+	qwt? ( x11-libs/qwt:5 )
+	scim? ( app-i18n/scim )
+"
+DEPEND="${COMMON_DEPEND}
+	eigen? ( dev-cpp/eigen:2 )
+"
+RDEPEND="${COMMON_DEPEND}
+	app-crypt/qca:2[openssl]
+"
+
+src_configure() {
+	# bug 560884
+	use ppc64 && append-flags -mno-altivec
+	local mycmakeargs=(
+		-DDBUS_INTERFACES_INSTALL_DIR="${EPREFIX}/usr/share/dbus-1/interfaces/"
+		-DWITH_Nepomuk=OFF
+		$(cmake-utils_use_with attica LibAttica)
+		$(cmake-utils_use_with desktopglobe Marble)
+		$(cmake-utils_use_find_package eigen Eigen2)
+		$(cmake-utils_use_with exif Kexiv2)
+		$(cmake-utils_use_build ibus)
+		$(cmake-utils_use_with json QJSON)
+		$(cmake-utils_use_with kdepim KdepimLibs)
+		$(cmake-utils_use_with oauth QtOAuth)
+		$(cmake-utils_use_with qalculate)
+		$(cmake-utils_use_with qwt)
+		$(cmake-utils_use_build scim)
+	)
+
+	kde4-base_src_configure
+}
diff --git a/kde-base/kdeplasma-addons/metadata.xml b/kde-base/kdeplasma-addons/metadata.xml
@@ -9,6 +9,7 @@
 		<flag name="attica">Enable support for <pkg>dev-libs/libattica</pkg></flag>
 		<flag name="ibus">Use ibus input method via <pkg>app-i18n/ibus</pkg></flag>
 		<flag name="desktopglobe">Enable Desktop Globe wallpaper using <pkg>kde-base/marble</pkg></flag>
+		<flag name="eigen">Build Mandelbrot wallpaper plugin using <pkg>dev-cpp/eigen:2</pkg></flag>
 		<flag name="fcitx">Use fcitx input method via <pkg>app-i18n/fcitx</pkg></flag>
 		<flag name="json">Enable JSON support via <pkg>dev-libs/qjson</pkg></flag>
 		<flag name="kdepim">KDE PIM integration via <pkg>kde-apps/kdepimlibs</pkg></flag>