media-video/mediainfo: version bump to 19.07

Signed-off-by: Tim Harder <[email protected]>

media-video/mediainfo/Manifest

@@ -1 +1,2 @@
 DIST mediainfo_19.04.tar.xz 1732860 BLAKE2B d4bded273b8dce2be2c578d263f2d442ad5b4a37f5d8b292d34dd80ed7fe83fbacce69a4ce740f9527f2fdb9a304b6dd91c96bfe747c023ce0dddac2244eb7f4 SHA512 cb6cb3c4bc3a037267684bd850babe3ca5998954f93e86d5b25aad7c4641918546a012cf7c6df4ef8d6017c85ab159dc5ae0b18f166385f8c5cc940a6fb0b3ce
+DIST mediainfo_19.07.tar.xz 1903620 BLAKE2B 68487713e0c540022d2a5ee8416cb8e1c87ed2a4479f8d7c247d75137a62d3ae2994d02cd8853080837a23d582ce4acab497646bf2307a0b2b4d398635738baa SHA512 ef543b2b3fa61347adaa510fc3b051ff148e24ef6461e25b9f1d158f3c4b57ce96826d0c0e8ae46996092e0eb84e99308ba87d95dd0392b99f05b704438c5983

media-video/mediainfo/mediainfo-19.07.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+WX_GTK_VER="3.0"
+
+inherit gnome2-utils xdg-utils autotools wxwidgets
+
+DESCRIPTION="MediaInfo supplies technical and tag information about media files"
+HOMEPAGE="https://mediaarea.net/mediainfo/ https://github.com/MediaArea/MediaInfo"
+SRC_URI="https://mediaarea.net/download/source/${PN}/${PV}/${P/-/_}.tar.xz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="curl mms wxwidgets"
+
+RDEPEND="sys-libs/zlib
+	>=media-libs/libzen-0.4.37
+	~media-libs/lib${P}[curl=,mms=]
+	wxwidgets? ( x11-libs/wxGTK:${WX_GTK_VER}[X] )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+S=${WORKDIR}/MediaInfo
+
+pkg_setup() {
+	TARGETS="CLI"
+	if use wxwidgets; then
+		TARGETS+=" GUI"
+		setup-wxwidgets
+	fi
+}
+
+src_prepare() {
+	default
+
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target} || die
+		sed -i -e "s:-O2::" configure.ac || die
+		eautoreconf
+	done
+}
+
+src_configure() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target} || die
+		local args=""
+		[[ ${target} == "GUI" ]] && args="--with-wxwidgets --with-wx-gui"
+		econf ${args}
+	done
+}
+
+src_compile() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target} || die
+		default
+	done
+}
+src_install() {
+	local target
+	for target in ${TARGETS}; do
+		cd "${S}"/Project/GNU/${target} || die
+		default
+		dodoc "${S}"/History_${target}.txt
+	done
+}
+
+pkg_postinst() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	gnome2_icon_cache_update
+	xdg_desktop_database_update
+}