dev-python/agate: Bump to 1.6.3

Signed-off-by: Michał Górny <[email protected]>

dev-python/agate/Manifest

@@ -1 +1,2 @@
 DIST agate-1.6.2.tar.gz 191216 BLAKE2B 63e89f6815a36dea956e8a919aeb926291eaf1f4d5eaac7f96dab97c6958dfee4788e18a4c1325a5b8cebf15df27b32e75409ddeab1289c1e8e548088fdc0ea7 SHA512 34d9e45d162bce69d28ad0ec07f5b410b2cdac831e5bd986ca8cb8902fd0ca1ec67663b2f956f42acaf18b8ca0fa169d5236aa4cee7457765e4e86d837e7794e
+DIST agate-1.6.3.tar.gz 202102 BLAKE2B b1a5624b4744b8f3ed266470da580cef2f2e1cf6159e1b33fcd461e4abd235c5e3fe0da35408a42c92fd4abf14a1f841a1ab9eb6cd31545d826a5223e85b4904 SHA512 e83a03c5a3e4b7fa9997030ce0d33e7b59b397e2ae07ee6a723eb7fb708a7fa8b8c4322dd034f42bf664bf2911d89731fd060e4ff33a237f83114a83312ac5ed

dev-python/agate/agate-1.6.3.ebuild

@@ -0,0 +1,44 @@
+# Copyright 2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="A Python data analysis library that is optimized for humans instead of machines"
+HOMEPAGE="https://github.com/wireservice/agate https://pypi.org/project/agate/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+xml"
+
+# Other packages have BDEPEND="test? ( dev-python/agate[xml] )"
+LEATHER_VERSION_DEP=">=dev-python/leather-0.3.3-r2"
+TEST_AGAINST_RDEPEND="xml? ( ${LEATHER_VERSION_DEP}[xml,${PYTHON_USEDEP}] )"
+RDEPEND="
+ >=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+ >=dev-python/pytimeparse-1.1.5[${PYTHON_USEDEP}]
+ >=dev-python/parsedatetime-2.1[${PYTHON_USEDEP}]
+ >=dev-python/Babel-2.0[${PYTHON_USEDEP}]
+ >=dev-python/isodate-0.5.4[${PYTHON_USEDEP}]
+ >=dev-python/pyicu-2.4.2[${PYTHON_USEDEP}]
+ >=dev-python/python-slugify-1.2.1[${PYTHON_USEDEP}]
+ ${LEATHER_VERSION_DEP}[${PYTHON_USEDEP}]
+
+ ${TEST_AGAINST_RDEPEND}
+"
+BDEPEND="test? ( ${LEATHER_VERSION_DEP}[xml,${PYTHON_USEDEP}] )"
+
+distutils_enable_tests pytest
+
+python_test() {
+ local deselect=(
+ # require specific locales
+ tests/test_data_types.py::TestDate::test_cast_format_locale
+ tests/test_data_types.py::TestDateTime::test_cast_format_locale
+ )
+ epytest ${deselect[@]/#/--deselect }
+}