games-roguelike/angband: version bump (bug #573604)

Package-Manager: portage-2.2.26

games-roguelike/angband/Manifest

@@ -1 +1,2 @@
 DIST angband-4.0.3.tar.gz 19884304 SHA256 1752d22a164bb073b9a7be322a2b607b06a4c919c073d012c010a61578081ce8 SHA512 c900648b6972e27ab30aaac776bbad34aee2196b5b80c4574762ff21c7c42a42061f76379ec4c0c2aefdfd1647aa76f2bd9fdd0286a7bc762616d97799e51a24 WHIRLPOOL 45c6eb4b71bf51bf2d41d270a8bb699d924137ccce605df867bf098f8545067c405a4ea851fe25e37304c908a13dd4e41229bf653bb87632f2fedb64323f2363
+DIST angband-4.0.4.tar.gz 19888293 SHA256 93f95444304d5178d23569dbd3dbe1eb29747201d353c676206f26b5bec4667c SHA512 73dbf0782f042dbc5ee9fe42430041f447a58ec14076280d2d6a44ec2b338dd4a7c220dc36f1b214380852283fb0d6e56fb338c2da95911b450714fb7f71e680 WHIRLPOOL aafa1fb9f0a54f8a39cb194e86fc4df43f0d773da58703b401cda0856ef2f99db7f351f444a3e0405b140a6130dd2da6fb318fde0e66f143ad38c51b7b91fa73

games-roguelike/angband/angband-4.0.4.ebuild

@@ -0,0 +1,117 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit autotools eutils gnome2-utils versionator games
+
+MAJOR_PV=$(get_version_component_range 1-2)
+
+DESCRIPTION="A roguelike dungeon exploration game based on the books of J.R.R. Tolkien"
+HOMEPAGE="http://rephial.org/"
+SRC_URI="http://rephial.org/downloads/${MAJOR_PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="ncurses sdl +sound X"
+
+RDEPEND="X? ( x11-libs/libX11 )
+ !ncurses? ( !X? ( !sdl? ( sys-libs/ncurses:0=[unicode] ) ) )
+ ncurses? ( sys-libs/ncurses:0=[unicode] )
+ sdl? ( media-libs/libsdl[video,X]
+ media-libs/sdl-ttf
+ media-libs/sdl-image
+ sound? ( media-libs/sdl-mixer[mp3]
+ media-libs/libsdl[sound] ) )"
+DEPEND="${RDEPEND}
+ dev-python/docutils
+ virtual/pkgconfig"
+
+src_prepare() {
+
+ sed -i -e '/libpath/s#datarootdir#datadir#' configure.ac || die
+ sed -i -e "/^.SILENT/d" mk/buildsys.mk.in || die
+ sed -i -e '/^DOC =/s/=.*/=/' doc/Makefile || die
+
+ if use !sound ; then
+ sed -i -e 's/sounds//' lib/Makefile || die
+ fi
+
+ # Game constant files are now system config files in Angband, but
+ # users will be hidden from applying updates by default
+ {
+ echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/customize/\""
+ echo "CONFIG_PROTECT_MASK=\"${GAMES_SYSCONFDIR}/${PN}/gamedata/\""
+ } > "${T}"/99${PN} || die
+
+ eautoreconf
+}
+
+src_configure() {
+ local myconf
+
+ if use sdl; then
+ myconf="$(use_enable sound sdl-mixer)"
+ else
+ myconf="--disable-sdl-mixer"
+ fi
+
+ ac_cv_path_NCURSES_CONFIG="pkg-config ncursesw" \
+ egamesconf \
+ --bindir="${GAMES_BINDIR}" \
+ --with-private-dirs \
+ $(use_enable X x11) \
+ $(use_enable sdl) \
+ $(use_enable ncurses curses) \
+ $(use !sdl && use !ncurses && use !X && \
+ echo --enable-curses) \
+ ${myconf}
+}
+
+src_install() {
+ DOCS="changes.txt faq.txt readme.txt thanks.txt" \
+ default
+
+ dohtml doc/manual.html
+ doenvd "${T}"/99${PN}
+
+ if use X || use sdl ; then
+ if use X; then
+ make_desktop_entry "angband -mx11" "Angband (X11)" "${PN}"
+ fi
+
+ if use sdl; then
+ make_desktop_entry "angband -msdl" "Angband (SDL)" "${PN}"
+ fi
+
+ local s
+ for s in 16 32 128 256 512
+ do
+ newicon -s ${s} lib/icons/att-${s}.png "${PN}.png"
+ done
+ newicon -s scalable lib/icons/att.svg "${PN}.svg"
+ fi
+
+ prepgamesdirs
+}
+
+pkg_preinst() {
+ games_pkg_preinst
+ if use X || use sdl ; then
+ gnome2_icon_savelist
+ fi
+}
+
+pkg_postinst() {
+ echo
+ elog "Angband now uses private savefiles instead of system-wide ones."
+ elog "This version of Angband is not compatible with the save files"
+ elog "of previous versions."
+ echo
+
+ games_pkg_postinst
+ if use X || use sdl ; then
+ gnome2_icon_cache_update
+ fi
+}