games-roguelike/wrogue: remove deprecated games eclass

Also update to EAPI 6

Gentoo-Bug: https://bugs.gentoo.org/574082

Package-Manager: portage-2.3.0

games-roguelike/wrogue/files/wrogue-0.8.0b-ldflags.patch

@@ -1,5 +1,5 @@
---- src/linux.mak.old	2010-10-14 11:07:22.000000000 +0200
-+++ src/linux.mak	2010-10-14 11:08:00.000000000 +0200
+--- a/src/linux.mak	2010-10-14 11:07:22.000000000 +0200
++++ b/src/linux.mak	2010-10-14 11:08:00.000000000 +0200
 @@ -19,7 +19,7 @@
  # common compiler/linker flags
  #

games-roguelike/wrogue/wrogue-0.8.0b-r1.ebuild

@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit eutils
+
+DESCRIPTION="Gothic science fantasy roguelike game"
+HOMEPAGE="https://freecode.com/projects/wrogue"
+SRC_URI="mirror://gentoo/${P}.zip"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND="media-libs/libsdl[video]"
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-ldflags.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e "/AppData\[0\]/ s:AppData.*:strcpy(AppData, \"/usr/share/${PN}/\");:" \
+		src/lib/appdir.c \
+		|| die "sed failed"
+}
+
+src_compile() {
+	local myCPPFLAGS="-std=c99 -Iinclude -Ilib -Iui -Igenerate"
+	local myCFLAGS="$(sdl-config --cflags) ${CFLAGS}"
+	emake -C src -f linux.mak STRIP_BINARY=NO \
+		CFLAGS="${myCPPFLAGS} ${myCFLAGS}" release
+}
+
+src_install() {
+	dobin ${PN}
+	insinto /usr/share/${PN}
+	doins -r data
+	dodoc changes.txt
+
+	newicon data/ui/icon.bmp ${PN}.bmp
+	make_desktop_entry ${PN} "Warp Rogue" /usr/share/pixmaps/${PN}.bmp
+}