dev-python/pyvirtualdisplay: Python wrapper for Xvfb, Xephyr and Xvnc

Package-Manager: Portage-3.0.2, Repoman-2.3.23
Signed-off-by: Andrew Ammerlaan <[email protected]>
Signed-off-by: Joonas Niilola <[email protected]>

dev-python/pyvirtualdisplay/Manifest

@@ -0,0 +1 @@
+DIST pyvirtualdisplay-1.3.2.tar.gz 38532 BLAKE2B 2c0cb3af426abc58dc895667c5fecb40ee9aa870dbb08a51ac32fbd5bd3620b97498b3dfc6e7026362604c82f67b60885370f0704a1349a65668628d9a21e80c SHA512 422e1530bb740fc77cc0b7abb73cb8e7326689c80c5f49b58be70b262e8a2c28274d3b83a0ec7753adfbf78b780047f61cf7b18fb14f935d483a5e3d04953210

dev-python/pyvirtualdisplay/metadata.xml

@@ -0,0 +1,12 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+ <maintainer type="person">
+ <email>[email protected]</email>
+ <name>Andrew Ammerlaan</name>
+ </maintainer>
+ <maintainer type="project">
+ <email>[email protected]</email>
+ <name>Proxy Maintainers</name>
+ </maintainer>
+</pkgmetadata>

dev-python/pyvirtualdisplay/pyvirtualdisplay-1.3.2.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7,8} )
+
+inherit distutils-r1
+
+DESCRIPTION="Python wrapper for Xvfb, Xephyr and Xvnc"
+HOMEPAGE="https://github.com/ponty/PyVirtualDisplay"
+SRC_URI="https://github.com/ponty/PyVirtualDisplay/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+BDEPEND="test? (
+ dev-python/backports[${PYTHON_USEDEP}]
+ dev-python/backports-tempfile[${PYTHON_USEDEP}]
+ dev-python/entrypoint2[${PYTHON_USEDEP}]
+ dev-python/path-py[${PYTHON_USEDEP}]
+ dev-python/pillow[${PYTHON_USEDEP}]
+ dev-python/pyscreenshot[${PYTHON_USEDEP}]
+ ~dev-python/vncdotool-0.13.0[${PYTHON_USEDEP}]
+ x11-base/xorg-server[xvfb,xephyr]
+ x11-misc/x11vnc
+)"
+
+DEPEND="dev-python/easyprocess[${PYTHON_USEDEP}]"
+
+S="${WORKDIR}/PyVirtualDisplay-${PV}"
+
+distutils_enable_tests pytest
+
+python_prepare_all() {
+ # all of this fails: AssertionError
+ rm tests/test_examples.py || die
+
+ # Assertion error No such file or directory: 'Xvnc': 'Xvnc'
+ sed -i -e 's:test_race_10_xvnc:_&:' \
+ tests/test_race.py || die
+
+ # No such file or directory: 'Xvnc': 'Xvnc'
+ sed -i -e 's:test_slowshot:_&:' \
+ -e 's:test_slowshot_with:_&:' \
+ tests/test_smart.py || die
+
+ # No such file or directory: 'Xvnc': 'Xvnc'
+ sed -i -e 's:test_double:_&:' \
+ tests/test_smart2.py || die
+
+ distutils-r1_python_prepare_all
+}