dev-libs/libclsync: version bump

Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Andrew Savchenko <[email protected]>

dev-libs/libclsync/Manifest

@@ -1 +1,2 @@
 DIST clsync-0.4.2.tar.gz 256042 BLAKE2B 28474fc66341b93705a502fcff390e3affcd89a9e1eb272dce9b28be709562e09c03e9c300cfeb5371e2e618a2239468a58c46212a39d751fbbfddeaab12bcf6 SHA512 d14a2efc4bf58d9d5c7a3fe5634cacdd182cd7cd814b0e9ebd99024a7282b056d1f7ceeec6903666391c3572d599a18e205af818b098ed7768d5c0e0f4cd1200
+DIST clsync-0.4.4.tar.gz 268276 BLAKE2B 0027760cfdee5c4410c4cea45aae2def6498d812d2f50038993c39a33c6029722ec2dd2cfff20815a3ffd8834eb8c439059e5f1d2cc3d2cf98ecb22ed22f2322 SHA512 cdafbf43fdeafe9cb53c08e0514ef356fb5b4bbd8da2226263180e7441d222c76e6c73f847f484b3688a8672e4a85df0346c0236d8d0ed4506d209189af02dcd

dev-libs/libclsync/libclsync-0.4.4.ebuild

@@ -0,0 +1,73 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_PN=${PN#lib}
+MY_P="${MY_PN}-${PV}"
+
+inherit autotools
+
+DESCRIPTION="Control and monitoring library for clsync"
+HOMEPAGE="http://ut.mephi.ru/oss/clsync https://github.com/clsync/clsync"
+SRC_URI="https://github.com/clsync/${MY_PN}/archive/v${PV}.tar.gz -> ${MY_P}.tar.gz"
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug extra-debug extra-hardened hardened static-libs"
+S="${WORKDIR}/${MY_P}"
+
+REQUIRED_USE="
+ extra-debug? ( debug )
+ extra-hardened? ( hardened )
+"
+
+BDEPEND="virtual/pkgconfig"
+RDEPEND="=app-doc/clsync-docs-0.4*"
+
+src_prepare() {
+ eapply_user
+ eautoreconf
+}
+
+src_configure() {
+ local harden_level=0
+ use hardened && harden_level=1
+ use extra-hardened && harden_level=2
+
+ local debug_level=0
+ use debug && debug_level=1
+ use extra-debug && debug_level=2
+
+ econf \
+ --enable-socket-library \
+ --disable-clsync \
+ --enable-debug=${debug_level} \
+ --enable-paranoid=${harden_level} \
+ --without-bsm \
+ --without-kqueue \
+ --disable-capabilities \
+ --disable-cluster \
+ --enable-socket \
+ --disable-highload-locks \
+ --disable-unshare \
+ --disable-seccomp \
+ --without-libcgroup \
+ --without-gio \
+ --with-inotify=native \
+ --without-mhash
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+ find "${ED}" -name "*.la" -delete
+ use static-libs || find "${ED}" -name "*.a" -delete || die "failed to remove static libs"
+
+ # docs go into clsync-docs
+ rm -rf "${ED}/usr/share/doc" || die
+}
+
+pkg_postinst() {
+ einfo "clsync instances you are going to use _must_ be compiled"
+ einfo "with control-socket support"
+}

dev-libs/libclsync/metadata.xml

@@ -14,6 +14,6 @@
  <flag name="extra-hardened">Enable extra security checks. This may hurt performance.</flag>
  </use>
  <upstream>
- <remote-id type="github">xaionaro/clsync</remote-id>
+ <remote-id type="github">clsync/clsync</remote-id>
  </upstream>
 </pkgmetadata>